Rachercher valeurs manquante entre 2 tableaux et le rajouter

[steven45]

Bonjour à tous,

D'habitude je trouve toute les réponse à mes questions sur se forum génial, néanmoins je bloque sur le sujet suivant !

J'ai deux feuilles:
- Feuil1
- Feuil2

Dans la feuil1 j'ai :
A
1 JEROME
2 GABIN
3 ARNAUD
4 FRANCK
5 SEBASTIEN

Dans la feuil2 j'ai :
A
1 JEROME
2 GABIN
3 FRANCK
4 DIDIER
5 CYRIL

Ma question est comment puis-je faire pour que les noms manquants dans la feuil1 par rapport à la feuil2 se rajoute et sans retirer ce manquant dans la feuil2.

Merci d'avance.

Steven

 

[Pierrot93]

Re : Rachercher valeurs manquante entre 2 tableaux et le rajouter

Bonjour,

essaye peut être ceci :

Option Explicit
Sub test()
Dim i As Long, x As Range
With Sheets("Feuil1")
    For i = 1 To Sheets("Feuil2").Range("A65536").End(xlUp).Row
        Set x = .Columns(1).Find(Sheets("Feuil2").Cells(i, 1).Value, , xlValues, xlWhole, , , False)
        If x Is Nothing Then
            .Range("A65536").End(xlUp)(2).Value = Sheets("Feuil2").Cells(i, 1).Value
        End If
    Next i
End With
End Sub

bonne journée
@+

 

[Guest]

Re : Rachercher valeurs manquante entre 2 tableaux et le rajouter

Bonjour,
Hello Pierrot🙂

Autre façon:

Sub CompléterListeNom()
    Dim t As Variant
    Dim i As Long
    With Sheets("Feuil2")
        t = .Range("A1:A" & .Cells(.Rows.Count, 1).End(xlUp).Row).Value
    End With
    With Sheets("Feuil1")
        For i = 1 To UBound(t)
            If IsError(Application.Match(t(i, 1), .Range("A:A"), 0)) Then
                .Range("A" & .Cells(.Rows.Count, 1).End(xlUp).Row).Offset(1) = t(i, 1)
            End If
        Next i
    End With
End Sub

A+