Raccourcie E + S

[jeromeN95]

Bonsoir, comment utiliser les commandes vba dans ce style :


Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
If Intersect(Target, Range("C13:C200")) Is Nothing Then GoTo fin
ActiveCell = Now()
'format du double clique en HH:MM:SS
Cells(Target.Row, 3) = Format(Now, "hh:mm:ss")

'déplacer la cellule vers la droite aprés validation
Selection.End(xlToLeft).Select
fin:
End Sub
' clik droit = Heure dans colone C et P uniquement !
Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
If Intersect(Target, Range("P13😛200")) Is Nothing Then GoTo fin
ActiveCell = Now()
'format du double clique en HH:MM:SS
Cells(Target.Row, 16) = Format(Now, "hh:mm:ss")

'déplacer la cellule vers la droite aprés validation
Selection.End(xlToLeft).Select
fin:
Cancel = True
End Sub


Mais en appuyant uniquement sur E pour l'heure d'entrée a la place du Double Click
Et S pour la soirtie a la place du click droit ...

svp???

Merci.

 

[Robert]

Re : Raccourcie E + S

Bonsoir Jerome, bonsoir le forum,

Essaie comme ça (si j'ai bien compris...) :

Private Sub Worksheet_Change(ByVal Target As Range) 'à l'édition dans une cellule
Dim pl1 As Range 'déclare la variable pl1 (PLage 1)
Dim pl2 As Range 'déclare la variable pl2 (PLage 2)
 
Set pl1 = Range("C13:C200") 'définit la plage 1
Set pl2 = Range("P13:P200") 'définit la plage 2
 
'condition 1 : si l'édition à lieu dans la plage pl1
If Not Application.Intersect(Target, pl1) Is Nothing Then
    'condition 2 : si l'édition est "e" ou "E'
    If UCase(Target.Value) = "E" Then
        Target.Value = Now 'place la date et heure
        Target.Value = Format(Now, "hh:mm:ss") 'met au format
        Target.Offset(0, 1).Select 'déplace vers la droite
    End If 'fin de la condition 2
End If 'fin de la condition 1
 
'condition 1 : si l'édition à lieu dans la plage pl2
If Not Application.Intersect(Target, pl2) Is Nothing Then
    'condition 2 : si l'édition est "s" ou "S'
    If UCase(Target.Value) = "S" Then
        Target.Value = Now 'place la date et heure
        Target.Value = Format(Now, "hh:mm:ss") 'met au format
        Target.Offset(0, 1).Select 'déplace vers la droite
    End If 'fin de la condition 2
End If 'fin de la condition 1
End Sub

 

[jeromeN95]

Re : Raccourcie E + S

Punaise !
Combien j'te doit?
C'est exactement ca...
Merci franchement, ca donne envie....

Super Simpa !!!🙂