Quetion simple.

[zeltron24]

Bonjour le forum,

Est ce qu'il existe une formule plus simple pour ce type de calcul ?
=SI(A14=1;1;SI(A14=2;1;SI(A14=3;1;SI(A14=4;1;SI(A14=5;1;SI(A14=6;2;SI(A14=7;3;0)))))))

Cela parait tout simple mais je ne maitrise pas assez excel pour imbriquer des formules avec OU - ET - NON
Merci pour votre aide
zeltron24

 

[job75]

Re : Quetion simple.

Bonjour,

Par exemple :

=CHOISIR(MIN(A14;8);1;1;1;1;1;2;3;0)

Edit : ou mieux :

=CHOISIR(MIN(MAX(A14;5)-4;4);1;2;3;0)

J'ai tatonné un peu...

Si A14 peut prendre des valeurs négatives, à la place de A14 on peut mettre ABS(A14) ou alors écrire :

=CHOISIR(MIN(MAX(A14;5)-4;4);1;2;3;0)*(A14>0)

et si de plus on veut 0 pour les valeurs non entières :

=CHOISIR(MIN(MAX(A14;5)-4;4);1;2;3;0)*(A14=ENT(A14))

A+

 

[kjin]

Re : Quetion simple.

Bonjour,

=SI(OU(A14={1;2;3;4;5});1;SI(A14=6;2;SI(A14=7;3;0)))

Edit : Hello Job 🙂
Re-edit : Hello Brigitte 🙂
A+
kjin

 

[Brigitte]

Re : Quetion simple.

Bonjour,

Autre possibilité avec les ou :

=si(ou(A14=1;A14=2;A14=3;A14=4;A14=5);1;si(A14=6;2;si(A14=7;3;0)))

ou encore

=SI(A14<=5;1;SI(A14=6;2;SI(A14=7;3;0)))

Voir fichier joint.

 

[zeltron24]

Re : Quetion simple.

Merci à vous tous pour vos réponses

Je suis occupé à créer un fichier afin d'inscrire mes heures de travail, je souhaiterai le transmettre sur le site mais je ne parvient pas à trouver la solution.
Cela pourrait me permettre d'avoir quelqu'un qui pourrait le modifier afin d'alléger les formules. Le fichier pèse très lourd 1,44Mo

 

[Brigitte]

Re : Quetion simple.

Re,

Et une fois zippé, il fait combien ?

 

[jeanpierre]

Re : Quetion simple.

Bonsoir zeltron24, Brigitte (coucou), job, kjin,

1.4 Mo en Xls doit faire entre 180 et 250 Ko une fois zippé (s'il n'y a pas de VBA et d'USF), au besoin retirer quelques données.

Pour zipper avec Windows, clic droit sur le fichier dans l'explorateur et Envoyer vers/Dossier compressé.

Bonne soirée et bises à Brigitte.

Jean-Pierre

 

[zeltron24]

Re : Quetion simple.

Bonsoir jean-pierre Brigitte,
Pour répondre à la question il fait encore 875Ko il y a du VBA avec UserForm et tout et tout....

 

[jeanpierre]

Re : Quetion simple.

Re,

Deux solutions :

1) Le réduire à la simple question posée, donc supprimer ce qui n'a pas de lien.

2) Déposer sur le site cijoint.fr et nous communiquer le lien du fichier.

Jean-Pierre

 

[hoerwind]

Re : Quetion simple.

Bonjour, salut aux autres,

Pour la question initiale il y a aussi :
=(A14<8)*(1+(A14>5)+(A14>6))

 

[job75]

Re : Quetion simple.

Salut Brigitte, jeanpierre, kjin, hoerwind,

Autre solution en adaptant la solution de kjin 🙂 (les SI prennent pas mal d'octets) :

=OU(A14={1;2;3;4;5})+2*(A14=6)+3*(A14=7)

A+

 

[Brigitte]

Re : Quetion simple.

Ouahou, les gars...

Dommage que le titre soit mal approprié, sinon on garderait ce fil en mémoire pour toutes les solutions apportées.

Bravo et bisous à tous, pour compenser la froidure, et la morsure de la pluie.

 

[zeltron24]

Re : Quetion simple.

Bonsoir à vous tous et merci pour votre aide.

Ceux ou celles qui désirent voir le fichier afin d'y apporter d'éventuelles modifications pour le rendre plus dynamyque le trouverons en cliquant sur ce lien.
Cijoint.fr - Service gratuit de dépôt de fichiers

 

[job75]

Re : Quetion simple.

Re zeltron24,

Perso je commencerais déjà à mettre en B14 la formule :

=DATE(ANNEE(T1);MOIS(T1);1)

pour une raison simple, EOMONTH ne fonctionne pas chez moi...

A+