Problème petite formule

[Phenix7884]

Bonjour à tous,

En ce qui me concerne j'ai besoin d'un petit coup de main, le problème est assez basique cependant je n'arrive pas à le résoudre, avis aux expérimentés!

J'ai deux colonnes une de temps l'autre de dossard, a chaque temps correspond un dossard et un dossard peut faire plusieur tours donc avoir plusieur temps.
Mon but d'ecrire un numéro de dossard dans une cellule et que la cellule à coté me résistue le temps le plus important du dossard.
Avec la fonction rechercheV je n'arrive qu'a récuperer la première valeur de temps saisie pour un dossard donné...et moi je veux la plus grande :-( y a til une fonction Max qui traine? je joins un exemple de mon fichier en copie. Merci d'votre aide. [file name=Dossard&temps_20050416175421.zip size=1822]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/Dossard&temps_20050416175421.zip[/file]

 

[Monique]

Bonjour,

=INDEX(B2:B10;EQUIV(MAX(SI(A2:A10=D6;B2:B10));B2:B10;0))
ou bien
=INDEX(B2:B10;EQUIV(GRANDE.VALEUR(SI(A2:A10=D6;B2:B10);1);B2:B10;0))

Formules matricielles, à valider par ctrl, maj et entrée

 

[Phenix7884]

Re😛roblème dossard temps

Merci beaucoup !! ça marche à merveille je vais appronfondir cette histoire de matrice et de crtl maj entré je ne connaissais pas.
Bonne fin de week end 🙂

 

[JeanMarie]

Re😛roblème dossard temps

Bonsoir

Autre solution, toujours à valider par Ctrl+Shift+Entrer

=GRANDE.VALEUR((A2:A10=D6)*B2:B10;1)

@+Jean-Marie

 

[Monique]

Re😛roblème dossard temps

Bonjour,

Mais oui, bien sûr !

Un peu plus court :
=MAX(SI(A2:A10=D6;B2:B10))
ou bien
=MAX((A2:A10=D6)*B2:B10)

(à valider par ctrl, maj et entrée)

 

[andré]

Re😛roblème dossard temps

Salut à vous tous,

Je viens d'essayer la formule matricielle de Jean-Marie en remplaçant l'argument '1' par 'ligne()'.
Cela marche à merveille pour établir un tableau trié des résultats.

Mais j'ai essayé la même chose avec la fonction PETITE.VALEUR, mais là cela ne fonctionne plus (du moins, moi je n'y parviens pas)!

Quelqu'un en connait la raison ?
La petite pièce jointe vous aiudera à trouver mon erreur.

Bon dimanche.
Ândré
[file name=petite_valeur_mat.zip size=2509]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/petite_valeur_mat.zip[/file]

 

[JeanMarie]

Re😛roblème dossard temps

Bonjour André

Dans la partie ($C$6:$C$14=G$5)*$D$6:$D$14, qui retournera une matrice de valeur à PETITE.VALEUR.

Si je prends 'Jean' comme comparateur le résultat dans la matrice sera
{FAUX*D6;VRAI*D7;FAUX*D8;FAUX*D9;VRAI*D10;FAUX*D11;FAUX*D12;FAUX*13;VRAI*D14}

FAUX valant 0 et VRAI valant 1, Donc{0;2;0;0;5;0;0;0;9}

Pour ta formule, il faut donc savoir combien de personnes sont différentes du comparateur NB.SI($C$6:$C$14;'<>'&'Jean')

Il faut aussi avoir une gestion d'erreur pour éviter l'affichage de #NOMBRE, qui est provoquer par le dépassement du nombre de valeur.

=SI(NB.SI($C$6:$C$14;G$5)<LIGNES(G$12:G12);'';PETITE.VALEUR(($C$6:$C$14=G$5)*$D$6:$D$14;LIGNE()-11+NB.SI($C$6:$C$14;'<>'&G$5)))

Bon week-end André

@+Jean-Marie

 

[andré]

Re😛roblème dossard temps

Salut Jean-Marie,

Merci pour ta réponse, et ce que tu dis est surement excat, mais comme c'est l'heure de l'apéro, j'ai eu quelques difficultés à la comprendre en première lecture.

N'empêche que j'ai bien fait de me lever ce matin (pour la formule, aussi un peu pour l'apéro), j'ai à nouveau appris quelque chose de plus.

Je te souhaite une bonne fin de dimanche.
Ândré.

 

[Monique]

Re😛roblème dossard temps

Re,

A mon humble avis, le plus simple et le moins compliqué, c'est d'utiliser Min(Si()) et Petite.Valeur(Si())
Si(etc ;'';Petite.Valeur(Si(condition nom;Si(condition nombre;plage));1))
Si(etc ;'';Petite.Valeur(Si(condition nom;plage);n°)))
Si(etc ;'';Min(Si(condition nom;Si(condition nombre;plage))))

[file name=petite_valeur_matV1.zip size=3767]http://www.excel-downloads.com/components/com_simpleboard/uploaded/files/petite_valeur_matV1.zip[/file]