Problème de SI (trop nombreux)

[etti]

Bonjour,

J'ai un problème avec une imbrication de fonctions SI (qui était parfaite avant mais qui ne fonctionne plus maintenant a cause de l'augmentation du nombreux d'imbrication dû a un agrandissement du tableau...)

En résumé, j'utilise une fonction SI pour affiché le nom en référence a une valeur minimale calculé avec MIN en dessous du tableau de données. Mais maintenant qu'il y a plus de 9 éléments dans le tableau, mon imbrication ne passe plus et je ne peux plus affiché le nom...
Le tout est utilisé dans un tableau dynamique mais ce n'est pas cela qui pose problème ici.

(J'aimerai également évité d'utiliser le VBA... a moins d'un solution vraiment élégante)

Pour plus de détails, voir le tableau attaché.


Merci d'avance ! 🙂

 

[C@thy]

Re : Problème de SI (trop nombreux)

Je ne suis pas la spécialiste ès formules, mais personnellement je fais un truc de ce style :

'=SI(C2<=6;SI(C2=1;"Janvier";SI(C2=2;"Février";SI(C2=3;"Mars";SI(C2=4;"Avril";SI(C2=5;"Mai";SI(C2=6;"Juin"))))));SI(C2=7;"Juillet";SI(C2=8;"Août";SI(C2=9;"Septembre";SI(C2=10;"Octobre";SI(C2=11;"Novembre";SI(C2=12;"Décembre")))))))

c'est un exemple totalement bidon car dans ce cas la fonction CHOISIR est bien plus adaptée.

En ce qui concerne ton problème je ferais ceci : (en J7 et tu recopies vers le bas)

=RECHERCHEV(I7;$D$7:$E$22;2;0)

ça générera une erreur si la valeur n'est pas trouvée (#/NA)

pour l'éviter tu peux tester l'erreur comme ceci :

=SI(ESTNA(RECHERCHEV(I7;$D$7:$E$22;2;0));"non trouvé";RECHERCHEV(I7;$D$7:$E$22;2;0))

C@thy

 

[etti]

Re : Problème de SI (trop nombreux)

Je ne sais pas si ça répond exactement a mon problème mais je vais regardé un peu votre formule.

Merci et si d'autres personnes ont des propositions n'hésitez pas 😀

 

[CISCO]

Re : Problème de SI (trop nombreux)

Bonjour

Encore et toujours avec sommeprod

@ plus

 

[bcharef]

Re : Problème de SI (trop nombreux)

Bonjour etti & C@thy,
Bonjour à toutes et à tous.

Bienvenue parmi nous.

Si, j'ai bien compris votre problème, je vous propose une solution dans l'espoir qu'elle vous conviendra.

A vous lire et bon courage.

Cordialement.

Bcharef.

Edit: Salut CISCO.

 

[etti]

Re : Problème de SI (trop nombreux)

Merci à vous trois !!

CISCO et bcharef, vos solutions ne sont pas exactement les mêmes mais elles fonctionnent toutes les 2 😎

Je vais voir laquelle utiliser 😉

Merci beaucoup. Super forum ! (et hop un petit clic sur les pubs 😛)

 

[C@thy]

Re : Problème de SI (trop nombreux)

Oups! je mé trompé!

=INDEX($I$7:$J$17;EQUIV(J24;$J$7:$J$17;0);1)

C@thy

 

[WILFRIED]

Re : Problème de SI (trop nombreux)

Salut à tous et toutes,

Cisco, peut tu me donné quelque explication sur ta formule :

=INDEX(I7:I17;SOMMEPROD((J7:J17=J24)*LIGNE(J7:J17))-6)

I7:I17 : est la colonne contenant tes donnée à renvoyer

(J7:J17=J24) : tu recherche si dans J7:J17 il y as la valeur de J24

mais pourquoi : *LIGNE(J7:J17))-6

Merci

 

[bcharef]

Re : Problème de SI (trop nombreux)

Re bonjour etti, C@thy, CISCO & WILFRIED,
Re bonjour à toutes et à tous.

Quelques améliorations ont été portées sur le fichier, vous pouviez insérer vos données et les résultats s'afficheront automatiquement.

A vous lire et bon courage.

Cordialement.

Bcharef.

 

[etti]

Re : Problème de SI (trop nombreux)

Merci pour cette modification, mais le tout portant sur un tableau croisée dynamique, apparemment la MAJ s'effectue automatiquement avec la première formule 🙂


Merci encore pour cette belle utilisation d'INDEX + EQUIV (2 formules qui m'étaient inconnu il y a encore 10 minutes 😉)

 

[bcharef]

Re : Problème de SI (trop nombreux)

Re bonjour etti, C@thy, CISCO & WILFRIED,
Re bonjour à toutes et à tous.

Merci pour cette modification, mais le tout portant sur un tableau croisée dynamique, apparemment la MAJ s'effectue automatiquement avec la première formule 🙂

J'ai mal saisi votre intervention en matière de TCD.

Comme, il est utile de porter à votre connaissance, que j'ai défini des noms tel que :

ELEMENTS

=DECALER(Feuil1!$D$9;;;NBVAL(Feuil1!$D$9:$D$65536);)

VALEURS

=DECALER(Feuil1!$E$9;;;NBVAL(Feuil1!$E$9:$E$65536);)

Ces deux noms sont insérés sur les deux formules comme suit :

+INDEX([COLOR=RoyalBlue]ELEMENTS[/COLOR];EQUIV($E$2;[COLOR=DarkRed]VALEURS[/COLOR];0))

=PETITE.VALEUR([COLOR=DarkRed]VALEURS[/COLOR];1)

Et, en cas de difficulté pour le TCD, n'hésitez pas.

A vous lire et bon courage.

Cordialement.

Bcharef.

 

[CISCO]

Re : Problème de SI (trop nombreux)

Bonjour à tous, bonjour WILFRIED

=INDEX(I7:I17;SOMMEPROD((J7:J17=J24)*LIGNE(J7:J17))-6)

I7:I17 : est la colonne contenant tes donnée à renvoyer

(J7:J17=J24) : tu recherche si dans J7:J17 il y a la valeur de J24

mais pourquoi : *LIGNE(J7:J17))-6

Merci

INDEX comporte trois arguments :
*la plage (ici I7:I17) où se trouve la valeur à écrire dans la cellule

*le numéro de la ligne dans cette plage (et non pas le numéro de la ligne dans la feuille) où ce trouve cette valeur, par rapport à cette plage.
Ici, j'ai besoin de savoir quel est le numéro de cette ligne, d'où le test SOMMEPROD((J7:J17=J24)*LIGNE(J7:J17))-6), J7:J17=24 ne donnant 1 que lorsque Jx=J24.
Excel teste l'égalité J7=J24, fausse, donc 0 * LIGNE(J7) =0,
puis teste J8=J24, fausse, donc 0 * LIGNE(J8) = 0,
puis...
Jx = J24, vrai, donc 1 * LIGNE(Jx)=x.
Ne reste plus qu'à faire -6 car la première ligne du tableau I7:I17 est la ligne 7 de la feuille.

*le numéro de la colonne dans cette plage (et non...). Par défaut 1 si il n'est pas précisé.

@ plus

 

[WILFRIED]

Re : Problème de SI (trop nombreux)

Re,

Merci pour ces explications.

A+