Problème de protection de VB

Sub ReVerrouillerProjet()
    Dim NomFichierModule As String, Temp As Workbook
    Const NomModule As String = "Module1"       'Nom de ce module (à adapter)

On Error GoTo Errh
    With ThisWorkbook                           'Exporte ce module
        NomFichierModule = .Path & "\" & NomModule & ".bas"
        .VBProject.VBComponents(NomModule).Export NomFichierModule
    End With

    With Application                            'Ajoute un classeur temporaire
        .ScreenUpdating = False
        .StatusBar = "Veuillez patienter .."
        .Cursor = xlWait
        .EnableEvents = False
    End With
    Set Temp = Workbooks.Add
    ActiveWindow.Visible = False

    Temp.VBProject.VBComponents.Import NomFichierModule 'Copie ce module dans le classeur temporaire
    Kill NomFichierModule                               'Supprime le fichier .bas
    With ThisWorkbook
        .Save                                                   'Enregistre ce classeur
        Application.Run Temp.Name & "!" & "Pause", .FullName    'Programme la reouverture
        .Close False                                            'Ferme ce classeur
    End With
Exit Sub
Errh:
    MsgBox Err.Description, vbCritical
End Sub

Sub Pause(WbFullName As String)
    Application.OnTime Now + TimeValue("00:00:01"), "'OuvrirClasseur """ & WbFullName & """'"
End Sub
 
Sub OuvrirClasseur(WbFullName As String)
    Workbooks.Open WbFullName   'Ouvre le classeur d'origine
    With Application
        .EnableEvents = True
        .Cursor = xlDefault
        .StatusBar = False
    End With
    ThisWorkbook.Close False    'Ferme le classeur temporaire
End Sub

.InsertLines X + .CountOfLines, Instructions(X)