Microsoft 365 Problème de formule sur diagramme de GANTT

[LAETI-TOINOU]

Bonjour tout le monde, j'espère que vous avez passé un bon week-end.

Je reviens vers vous, cette fois ci, car j'ai un problème avec une formule dans un diagramme de GANT.

En cherchant sur internet, j'ai trouvé un document modèle de document qui pourrait correspondre à ce dont j'ai besoin.
J'ai donc recopié les formules pour mettre en couleur les différentes périodes, mais..... je rencontre deux problèmes. J'avoue avoir recopié les formules, sans comprendre à quoi servait le NON dans la formule.

Le 1er :
Lorsque ma tache commence à un jour J, pour X jours, la surbrillance ne commence qu'à J+1,et ne dure que X-1 jours.

Je n'arrive vraiment pas corriger cette erreur.


Le 2ème :
J'aimerais, dans la mesure du possible, que la durée tienne compte des samedis et dimanches non travaillés.

Est-ce que je peux compter une nouvelle fois sur votre aide ?

Merci d'avance, et bon lundi ensoleillé

 

[Dranreb]

Bonjour.
Curieuse cette formule. J'aurais mis :

=ET(EST.IMPAIR(LIGNE());D$3>=$B4;D$3<=$B4+$C4-1)

 

[LAETI-TOINOU]

Bonjour Dranreb,

Merci beaucoup pour cette formule qui fonctionne nickel et dont j'arrive à comprendre le raisonnement.

Mon 1er point est donc résolu.

Peux-tu également m'aider également sur le 2ème point, à savoir, que les samedis et dimanches ne doivent pas être comptés dans les jours. Une semaine = 5 jours travaillés et non pas 7 ?

Merci d'avance.

 

[Dranreb]

Cherchez une solution en calculant la date de fin avec SERIE.JOUR.OUVRE

 

[LAETI-TOINOU]

Cherchez une solution en calculant la date de fin avec SERIE.JOUR.OUVRE

OK.

Merci, je vais tester avec cette fonction.

 

[AtTheOne]

Bonjour à toutes & à tous, bonjour @LAETI-TOINOU
Je ne sais pas si tu as réussi à intégrer SERIE.JOURS.OUVRES à tes MFC mais en ne commençant la mise en forme qu'à la date réelle du début de tâche (un jour ouvré) cette formule fait l'affaire pour les lignes paires:

=ET(EST.PAIR(LIGNE());
        D$3>=SERIE.JOUR.OUVRE($B4;--(NB.JOURS.OUVRES($B4;$B4;)=0));
        D$3<=SERIE.JOUR.OUVRE($B4;$C4-(NB.JOURS.OUVRES($B4;$B4)>0)))

--(NB.JOURS.OUVRES($B4;$B4;)=0) renvoie +1   si le jour de début n'est pas un jour ouvré, cela permet de se décaler le début au lundi qui suit.
-(NB.JOURS.OUVRES($B4;$B4)>0) renvoie 0 si le jour de début n'est pas un jour ouvré, cela permet de ne pas en tenir compte pour le calcul de la fin

Et pour bien sûr les lignes impaires :

=ET(EST.IMPAIR(LIGNE());
        D$3>=SERIE.JOUR.OUVRE($B4;--(NB.JOURS.OUVRES($B4;$B4;)=0));
        D$3<=SERIE.JOUR.OUVRE($B4;$C4-(NB.JOURS.OUVRES($B4;$B4)>0)))

Amicalement
Alain

 

[LAETI-TOINOU]

Bonjour à toutes & à tous, bonjour @LAETI-TOINOU
Je ne sais pas si tu as réussi à intégrer SERIE.JOURS.OUVRES à tes MFC mais en ne commençant la mise en forme qu'à la date réelle du début de tâche (un jour ouvré) cette formule fait l'affaire pour les lignes paires:

=ET(EST.PAIR(LIGNE());
        D$3>=SERIE.JOUR.OUVRE($B4;--(NB.JOURS.OUVRES($B4;$B4;)=0));
        D$3<=SERIE.JOUR.OUVRE($B4;$C4-(NB.JOURS.OUVRES($B4;$B4)>0)))

--(NB.JOURS.OUVRES($B4;$B4;)=0) renvoie +1   si le jour de début n'est pas un jour ouvré, cela permet de se décaler le début au lundi qui suit.
-(NB.JOURS.OUVRES($B4;$B4)>0) renvoie 0 si le jour de début n'est pas un jour ouvré, cela permet de ne pas en tenir compte pour le calcul de la fin

Et pour bien sûr les lignes impaires :

=ET(EST.IMPAIR(LIGNE());
        D$3>=SERIE.JOUR.OUVRE($B4;--(NB.JOURS.OUVRES($B4;$B4;)=0));
        D$3<=SERIE.JOUR.OUVRE($B4;$C4-(NB.JOURS.OUVRES($B4;$B4)>0)))

Amicalement
Alain

Bonjour tout le monde, bonjour Alain,

Merci beaucoup pour ces formules, car effectivement, je n'arrivais pas à intégrer mes jours ouvrés.

Et merci beaucoup pour tes explications.

Bonne journée.


Laëtitia