Problème dans extraction de deuxième mot d'une cellule

[libellule85]

Bonjour tout le monde,

Voici mon problème j'ai crée une formule pour extraire le deuxième mot d'une cellule
=droite(A1;NBCAR(A1)-CHERCHE(" ";A1)) qui fonctionne très bien, mais par contre
quand il n'y a pas de deuxième mot dans la cellule il me met le message #valeur! or
je voudrais que la cellule soit vide...
Merci beaucoup pour votre aide

 

[JNP]

Re : Problème dans extraction de deuxième mot d'une cellule

Bonjour Libellule85 🙂,

=DROITE(A1;NBCAR(A1)-SIERREUR(CHERCHE(" ";A1);NBCAR(A1)))

Attention, ne fonctionne qu'en 2007 et + 🙄...
Bonne soirée 😎

 

[libellule85]

Re : Problème dans extraction de deuxième mot d'une cellule

Bonjour JNP,
merci beaucoup pour ta réponse, cela fonctionne à merveille
Bonne soirée

 

[Hippolite]

Re : Problème dans extraction de deuxième mot d'une cellule

Bonjour,
Pour les vieilles versions d'Excel

=SI(ESTERREUR(CHERCHE(" ";A1));"";DROITE(A1;NBCAR(A1)-CHERCHE(" ";A1)))

 

[libellule85]

Re : Problème dans extraction de deuxième mot d'une cellule

Bonsoir Hippolite,
Merci beaucoup pour ta réponse, c'est super...
Bonne soirée

 

[ROGER2327]

Re : Problème dans extraction de deuxième mot d'une cellule

Bonsoir à tous

En Français,

(…) extraire le deuxième mot d'une cellule (…)

signifie que, d'une cellule contenant "toto tata titi", on extrait "tata"…

=STXT(A1&" ";TROUVE(" ";A1&" ")+1;TROUVE(" ";A1&"  ";TROUVE(" ";A1&" ")+1)-TROUVE(" ";A1&" ")-1)

​

ROGER2327
#4969

Samedi 28 Gueules 138 (Sainte Hylactor et Pamphagus, SQ)
4 Ventôse An CCXIX
2011-W08-2T23:14:46Z

 

[libellule85]

Re : Problème dans extraction de deuxième mot d'une cellule

Bonjour Roger2327,
Je te remercie beaucoup pour ta réponse.
Bonne journée

 

[Sofia32]

Re : Problème dans extraction de deuxième mot d'une cellule

Bonsoir à tous

En Français,signifie que, d'une cellule contenant "toto tata titi", on extrait "tata"…

=STXT(A1&" ";TROUVE(" ";A1&" ")+1;TROUVE(" ";A1&"  ";TROUVE(" ";A1&" ")+1)-TROUVE(" ";A1&" ")-1)

​

ROGER2327
#4969

Samedi 28 Gueules 138 (Sainte Hylactor et Pamphagus, SQ)
4 Ventôse An CCXIX
2011-W08-2T23:14:46Z

Bonjour ROGER2327,
Ta formule fonctionne très bien pour extraire le 2ème mot d'une cellule, quelle est la formule pour extraire le 3ème mot stp?

 

[mapomme]

Bonjour et bienvenu @Sofia32 🙂,

Formule en B2 à copier vers la droite jusqu'à n'avoir que des cellules vides :

=SIERREUR(SUPPRESPACE(DROITE(SUBSTITUE(GAUCHE(SUPPRESPACE($A2);CHERCHE(CAR(177);SUBSTITUE(SUPPRESPACE($A2);" ";CAR(177);COLONNES($A:A)))-1);" ";REPT(" ";255));255));"")

C'est le terme COLONNES($A:A) qui permet de trouver le Nième mot.
Le terme COLONNES($A:A) prend successivement les valeurs 1, 2, 3, 4, ... qquand on le tire à droite à partir de B2.

 

[job75]

Bonjour Sofia32, mapomme, le fil,

Il est toujours surprenant de voir qu'il faut des formules Excel kilométriques pour ce problème.

Alors qu'en VBA c'est d'une simplicité absolue :

Function Extract$(x$, sep$, n)
Extract = Split(x, sep)(n - 1)
End Function

A+

 

[mapomme]

Il est toujours surprenant de voir qu'il faut des formules Excel kilométriques pour ce problème

Avec O360, ça devient plus facile mais Krosoft en aura mis du temps !
Nième mot de A1 avec le séparateur sep : =INDEX(FRACTIONNER.TEXTE(A1;sep;;VRAI);N)