Problème avec référence circulaire

[tchoupiben]

Bonjour à tous.

Voilà j'ai simplement un calcul à faire du genre A=A+B j'ai activé les formules itératives.
Lorsque j'encode des valeurs dans la première ligne du tableau, il y a aucun souci, le calcul se fait correctement. Seulement dès que je tape quelque chose d'autre dans une cellule quelconque il augmente la valeur de A tout seul. Mêmesi j'écris rien, je tape simplement sur une touche comme delete quelque part dans mon tableau il augmente la valeur de A également.

J'espère que j'ai été clair car c'est pas évident à expliquer.
J'espère également que vos lumières vont pouvoirm'éclairer.
Bonne soirée

 

[jmd2]

Re : Problème avec référence circulaire

hello

peux-tu joindre ton fichier, et nous dire à quoi sert le A=A+B ?

*****

 

[abcd]

Re : Problème avec référence circulaire

Bonjour,

Une solution est de travailler avec une troisième cellule servant de condition.

Exemple :
A1 : =SI(C1="";A1;A1+B1)

Tant que la cellule C1 est vide, le calcul ne se fait pas et la valeur de A1 est figée.
Pour que le calcul se fasse, saisir quelque chose en C1, par exemple une espace, et le calcul se fera à chaque calcul de la feuille.
Pour arrêter ce calcul, effacer l'espace en C1

abcd

 

[JeanMarie]

Re : Problème avec référence circulaire

Bonjour tchoupiben, jmd, abcd

Une solution serait de tester si la partie B vient d'être modifiée.

En utilisant =CELLULE("address") excel retourne la référence de la cellule venant d'être modifiée, Excel retourne cette référence sous forme absolue.

A noter :
° Si la cellule fait partie d'une autre feuille voir d'un autre classeur, la référence retournée intégrera le nom de la feuille et du classeur.
° Attention au temps de calcul de ta feuille, une modification d'une cellule n'ayant aucune dépendance dans une formule, lancera le calcul de la feuille.

Pour Intégrer cette fonction dans ta formule.
A1=SI(CELLULE("address")="$B$1";A1+B1;A1)

Si je peux te donner un autre conseil, pour la cellule B1 tu as tout intérêt à forcer le type de son contenu à saisir, par l'option dans le menu données/validation...

@+Jean-Marie

 

[tchoupiben]

Re : Problème avec référence circulaire

Voci le fichier,
Introduisez une valeur dans Quantité mois, les différentes valeures introduites se cumulent dans la colonne cumul réalisé. Aucun problème si on se limte à la première ligne, le calcul se déroule correctement. Après cela tapez n'importe quoi dans n'importe quelle autre cellule, remarquez ce qui se passe alors à la première ligne dans la colonne cumul réalisé elle augmente sans que je m'occupe de cette ligne là.
Je vous remercie pour votre vitesse de réponse c'est super ce forum.
Je vous remercie également du temps conscré à ma demande.
bonne soirée

 

[abcd]

Re : Problème avec référence circulaire

Re,

H6 : = SI(L6="";H6;H6+G6)

Saisir une espace (ou autre chose) en L6 et le calcul est bloqué.
Effacer cette saisie et le calcul se fait.

abcd

 

[JeanMarie]

Re : Problème avec référence circulaire

Re...

Pour adapter ma proposition à ton exemple, à coller dans la cellule H6

=SI(CELLULE("address")=CELLULE("address";G6);SI(G6=0;0;H6+G6);H6)

@+Jean-Marie
un exemple d'utilisation de l'itération

 

[tchoupiben]

Re : Problème avec référence circulaire

Merci à tous celui qui se rapproche le plus d ela meilleure solution est ABCD seulement j'ai un autre souci j'arrive pas à bloquer la colonne Q restante elle continue à bouger mais la colonne cumulée fonctionne avec votre idée, il faudrait maintenant que je puisse également ficher la colonne Q restante.

dans la colonne Q rest. j'ai fais: = si(L6= "1";F6;E6-(H6+G6))
dans la colonne cumul : j'ai fais ce que vous m'avez dit : = si(L6="1";H6;H6+G6).
Dans cumul ça fonctionne bien. Mais pas dans Q rest.
Merci beaucoup:confused

 

[JeanMarie]

Re : Problème avec référence circulaire

RE...

Je me pose des questions sur ce que tu veux obtenir et le but

En reprenant le fichier tu as placé.

1) Dans la cellule G6, je tape la valeur 1, je dois obtenir quelle valeur en G6 et H6 ?
Je retape ensuite la valeur 5 en G6, je dois obtenir quelle valeur en G6 et H6 ?

2) Dans la cellule G6 je tape 0, tu veux obtenir quelle valeur dans les cellules G6 et H6 ?

Merci de me répondre...

@+Jean-Marie

 

[tchoupiben]

Re : Problème avec référence circulaire

re....
SI TU ptapes 1 en G6 je voudrais 1 en G6 et en H6 si après tu tapes 5 en G6 je veux 6 en H6 et 5 en G6.
Si tu mets 0 en G6. je veux que H6 ne change pas (H6+0) et G6 devient 0.
Je voudrais également que quantité restante= quantité totale - cumul réal.
Merci beaucoup.

Je vous explique un peu le but.
Je suis responsable de chantier. C'est un petit programme pour faciliter mon boulot avec les sous traitants.
Si vous vouleztous les mois on paie les sous traitants.
Si le premier mois il réalise 10m² je veux que ça se déduit de la quantité totale à effectuer. Le deuxième moi il réalise 5 m² je veux qu'il y ait une sorte de cumulée qui additionne les différents mois. (10 m²+5m²) Et pour me rendre compte du travail qui reste à effectuer je voudrais également que dans la colonne quantité restante il se passe que c'est égale à la quantité totale - la quantité cumulée réalisé.
J'espère être clair. Si vous avez des questions n'hésitez pas.
Bonne soirée

 

[JeanMarie]

Re : Problème avec référence circulaire

Re...

Merci pour tes explications. J'avais gardé ta formule de départ SI(G6=0;0;H6+G6).
Remplace la formule en H6

=SI(CELLULE("address")=CELLULE("address";G6);H6+G6;H6)

Pour la formule Q. restante

=E6-H6

Que doit-il se passer sur les valeurs "Prix du mois" et le "Prix total" quand le prix unitaire évolue d'un mois à l'autre ?

@+Jean-Marie

PS : je maintiens ma proposition qui fonctionne parfaitement

 

[tchoupiben]

Re : Problème avec référence circulaire

oK ça fonctionne bien, sauf quantité restante.
C'est encore mieux de faire comme tu dis car j'ai pas besoin d'employer une colonne avec un verrou.
Mais peux tu m'expliquer ta formule car je comprends pas cellule " adresse".
J'aimerais aussi pouvoir remettre à 0 la quantité cumulé au cas où il y aurait une erreur de frappe lors de l'utilisation.
Prix du mois =Prix unitaire X quantité du mois
Prix total = Prix unitaire X quantité cumulé.
Un grand merc.
C'est quand même prenant de se casser la tête sur excel. On passerait la nuit dessus pour trouver la solution
😀

 

[JeanMarie]

Re : Problème avec référence circulaire

RE...

Pour la fonction CELLULE fait partie de la catégorie "informations", elle permet de connaître des informations sur la référence de la cellule qui est indiquée en deuxième argument.

Quand le deuxième argument n'est pas spécifié, c'est la référence de la cellule qui vient d'être modifiée qui est utilisée.

Si tu as regardé l'aide en ligne d'Excel, cette fonction retourne différente information en fonction du 1er argument

"adresse" la référence de la première cellule de l'argument référence, sous forme de texte.
"col" le numéro de colonne de la cellule de l'argument référence.
"contenu" la valeur de la cellule supérieure gauche de l'argument référence, non une formule.
"couleur" 1 si la cellule est formatée en couleur pour les valeurs négatives, sinon renvoie 0 (zéro).
"format" la valeur de texte correspondant au format de nombre défini pour la cellule. Les valeurs de texte des différents formats sont répertoriés dans le tableau ci-dessous. Renvoie "-" à la fin de la valeur de texte si la cellule est formatée en couleur pour les valeurs négatives. Renvoie "()" à la fin de la valeur de texte si la cellule est formatée avec des parenthèses pour les valeurs positives ou pour toutes les valeurs.
"largeur" la largeur de colonne de la cellule qui contient une valeur arrondie à un entier. Chaque unité de largeur de colonne est égale à la largeur d'un caractère dans la taille de la police par défaut.
"ligne" le numéro de ligne de la cellule de l'argument référence.
"nom de fichier" le nom de fichier (notamment le chemin d'accès complet) du fichier qui contient une référence, sous forme de texte. Renvoie du texte vide ("") si la feuille de calcul qui contient une référence n'a pas encore été enregistrée.
"parenthèses" 1 si la cellule est formatée avec des parenthèses pour les valeurs positives ou pour toutes les valeurs, sinon renvoie 0.
"préfixe" la valeur de texte correspondant au « préfixe d'étiquette » de la cellule. Renvoie un guillemet droit simple (') si la cellule contient du texte aligné à gauche, un guillemet droit double (") si la cellule contient du texte aligné à droite, le signe insertion (^) si la cellule contient du texte centré, une barre oblique inverse (\) si la cellule contient du texte de remplissage aligné et du texte vide ("") si la cellule contient un autre type d'élément.
"protection" 0 si la cellule n'est pas verrouillée et 1 si la cellule est verrouillée.
"type" la valeur de texte correspondant au type des données de la cellule. Renvoie « i » si la cellule est vide, « l » (pour label (étiquette)) si la cellule contient une constante de texte et « v » (pour valeur) si la cellule contient un autre type d'élément.

et surtout

Référence est la cellule sur laquelle vous voulez des informations. Si vous ne la définissez pas, les informations spécifiées dans type_info sont renvoyées pour la dernière cellule modifiée

Tu as sans doute remarqué que je n'ai pas indiqué "adresse" mais "address" dans la formule proposée. C'est tout simplement que j'utilise le 1er argument sous sa forme anglaise, qui est acceptée sur les versions françaises d'Excel, l'inverse n'est pas vrai.

Pour la remise à Zéro, tu as déjà un exemple

=SI(CELLULE("address")=CELLULE("address";G6);SI(G6="RAZ";0;H6+G6);H6)

Avec cette formule il suffit de mettre RAZ en G6

Pour la quantité restante, je ne sais plus quoi dire.

@+Jean-Marie

 

[tchoupiben]

Re : Problème avec référence circulaire

OK je comprends beaucoup mieux.
Tu es un vrai génie d'excel.
Je vais mettre tout ça en musique durant le weekend.
Merci pour tout.
C'est un réel plaisir d'apprendre sur ce forum.
Bon weekend.

 

[abcd]

Re : Problème avec référence circulaire

Bonjour JeanMarie,

Très intéressé par ta formule, mais ...

Vois le fichier joint.
- la valeur saisie en G6 est multipliée par 100
- la formule ne semble pas fonctionner pour des valeurs négatives

Je n'en trouve pas la raison, aurais-tu une explication ?

abcd