XL 2021 Probleme avec mon fichier combi4

[fab5152]

Bonjour j'ai un dernier soucis avec mon fichier combi4
j'ai le même soucis que pour l'autre

je voudrais savoir combien de fois ma combinaisons B,B2,B3,B4 sors ensemble dans n'importe quel ordre dans mon tableau en C4 à F373
est pourtant il me marque nom dans ma formule
je voulais savoir ce que j'oublie
merci pour votre aide par avance

j'ai xl 2021 soi Microsoft office 365 mais en 32 bits est que c'est ça qui pose un problème pour ma formule

 

[sylvanu]

Bonjour Fab,
Même solution que précédemment.
Une colonne G avec :

="-"&C4&"-"&D4&"-"&E4&"-"&F4&"-"

Un comptage avec :

=NB.SI.ENS(G:G;"*-"&J4&"-*";G:G;"*-"&K4&"-*";G:G;"*-"&L4&"-*";G:G;"*-"&M4&"-*")

 

[job75]

Bonjour fab5152, [Edit] salut sylvanu,

Voyez le fichier joint et cette fonction VBA dans Module1 :

Public d As Object 'mémorise la variable

Function Compte(plage As Range, ref As Range)
Dim a, i&, b
If d Is Nothing Then 'évite le calcul à chaque fois
    Set d = CreateObject("Scripting.Dictionary")
    Set plage = plage.Parent.Range(plage.Rows(1), plage(plage.Rows.Count, 1).End(xlUp))
    For i = 1 To plage.Rows.Count
        a = Application.Transpose(Application.Transpose(plage.Rows(i)))
        tri a, 1, 4
        a = Join(a)
        d(a) = d(a) + 1
    Next
End If
a = Application.Transpose(Application.Transpose(ref))
tri a, 1, 4
a = Join(a)
Compte = d(a)
End Function

Sub tri(a, gauc, droi) ' Quick sort
Dim ref, g, d, temp
ref = a((gauc + droi) \ 2)
g = gauc: d = droi
Do
    Do While a(g) < ref: g = g + 1: Loop
    Do While ref < a(d): d = d - 1: Loop
    If g <= d Then
      temp = a(g): a(g) = a(d): a(d) = temp
      g = g + 1: d = d - 1
    End If
Loop While g <= d
If g < droi Then Call tri(a, g, droi)
If gauc < d Then Call tri(a, gauc, d)
End Sub

Pour gagner du temps le Dictionary n'est calculé que la 1ère fois.

Mais il est recalculé chaque fois qu'on valide ou modifie des cellules dans la feuille de calcul :

Private Sub Worksheet_Change(ByVal Target As Range)
Set d = Nothing 'force le recalcul de d
End Sub

A+

 

[job75]

Notez que chez moi, quand on modifie une cellule du tableau C4:F33 :

- les formules du post #2 se recalculent en 0,92 seconde

- les formules du post #3 se recalculent en 0,04 seconde.