Problème avec formule complexe "SI"

Fred-et-ric · 23 Août 2006

Bonjour,

A peine un problème de résolu (merci Ze PoulpeMan) qu une nouvelle énigme se dessine à l horizon... 😛
Je voudrais calculer dans mon fichier excel quand mes investissement sont récupérés par de l argent qui rentre. J ai trouvé une formule pr cela qq part mais elle était établi pr des investissements étalés sur 5ans seulement! Mes investissements et rentrés d argent étant étalés sur 10 ans, j ai essayé d adapter la formule de base pr la faire convenir à mon problème... mais, du coup excel ne veut plus me prendre ma formule! Quand je sélectionne mes cellules, à un moment il arrête de les compter et les affiches sans faire référence à la cellule cible...
Que faire pr que ça fonctionne et quelle est l origine du problème?! 😕
Voici la formule originale:
=SI(Yr1CumCF>0;"N/A"; SI(Yr2CumCF>0;1+ABS(Yr1CumCF)/Yr2NetCF;SI(Yr3CumCF>0;2+ABS(Yr2CumCF)/Yr3NetCF;SI(Yr4CumCF>0;3+ABS(Yr3CumCF)/Yr4NetCF;SI(Yr5CumCF>0;4+ABS(Yr4CumCF)/Yr5NetCF;"N/A")))))
Voici la mienne :
=SI(CFcum2007>0;"N/A"; SI(CFcum2008>0;1+ABS(CFcum2007)/CFnet2008;SI(CFcum2009>0;2+ABS(CFcum2008)/CFnet2009;SI(CFcum2010>0;3+ABS(CFcum2009)/CFnet2010;SI(CFcum2011>0;4+ABS(CFcum2010)/CFnet2011;SI(CFcum2012>0;5+ABS(CFcum2011)/CFnet2012;SI(CFcum2013>0;6+ABS(CFcum2012)/CFnet2013;SI(CFcum2014>0;7+ABS(CFcum2013)/CFnet2014;SI(CFcum2015>0;8+ABS(CFcum2014)/CFnet2015;SI(CFcum2016>0;9+ABS(CFcum2015)/CFnet2016;"N/A"))))))))))
😀
(Bon, les Yr1cum, CFcum2007 c est des nom de cellules, c est dans l explication de la cellule qu ils disaient qu il fallait travailler comme ça, je suppose que c est pr vérifier plus facilement si on a pris les bonnes cellules en compte...)
Si vs voulez plus d explications sur la formule de base, n hésitez pas à me demander, je ne sais pas si ce sera nécessaire à la résolution du problème ou pas.

Merci beaucoup!😉

Tibo · 23 Août 2006

Re : Problème avec formule complexe "SI"

Salut Fred et Ric,

Le problème vient très certainement du fait que le nombre de SI imbriqués est au maximum de 7.

Il est possible de contourner le problème via des formules nommées ou via un tableau de tes données.

Peux-tu joindre le fichier (sans données confidentielles) ?

Ca permettra de mieux comprendre et d'apporter une réponse appropriée.

@+

PascalXLD · 23 Août 2006

Re : Problème avec formule complexe "SI"

Bonjour

Tu ne peux imbriquer que 7 SI et là tu en as plus si je ne me trompe

Fais une recherche sur le forum sur le fait d'imbriquer plus de 7 conditions et tu trouveras ton bonheur

Bonne journée

Fred-et-ric · 23 Août 2006

Re : Problème avec formule complexe "SI"

Ah c est ça le problème alors?! 😕

J vais voir si j arrive à appliquer ce qui est mis ailleurs sur le forum...
Voici le fichier concerné... c est un peu bizarre car tt les chiffres sont à 0 mais c est parce que j ai du enlevé des liens ...

Monique · 23 Août 2006

Re : Problème avec formule complexe "SI"

Bonjour,

Je n'y connais rien dans les histoires de Cash Flow
Un essai quand même

Deux plages nommées :
CfCum = $B$50:$K$50
CfNet = $B$4:$K$4

Une formule matricielle, à valider par ctrl, maj et entrée
=SI($B$50<0;MIN(SI(CfCum>0;COLONNE(CfCum)))-2+ABS(INDEX(CfCum;MIN(SI(CfCum>0;COLONNE(CfCum)))-2))/INDEX(CfNet;MIN(SI(CfCum>0;COLONNE(CfCum)))-1);"N/A")

(Ou bien 3 cellules comportant chacune une petite formule matricielle)
Dans le fichier, tu as les étapes de la construction de la formule

Fred-et-ric · 24 Août 2006

Re : Problème avec formule complexe "SI"

Ouh la la Monique...😛

Autant tu ne dis rien comprendre au cash flow autant, je n ai jamais adhéré au matrices... Faudrait donc qu une tierce personne valide notre cohérence même si ton résultat m a l air tout à fait juste et donc que ta formule doit forcément coïncider avec celle que je voulais appliquer... 😉 Merci beaucoup donc!!!

Si tu veux une brève explication sur les cash flow par contre, ça c est dans mes cordes.... 😀

J ai aussi regardé le problème d imbrication de formules.
Si j ai bien compris, il faut dans la formule faire référence à une autre cellule ou se trouve le reste de la formule?! Cela ne marche pas si on veut faire apparaître du texte si j ai bien compris...
De premier abord je dirais donc que cela devrait être ok pr moi mais j affiche quand même un N/A si jamais le cash flow entrant n est pas suffisant pr récupérer l investissement sur toute la période. Est ce que cela risque de poser problème dans mon imbrication? Merci de donner votre avis avant que je me lance dans l aventure... 😛

Monique · 24 Août 2006

Re : Problème avec formule complexe "SI"

Bonjour,

G95 et F88, c'est la même chose,
sauf que G95 se sert des résultats de E94 E95 et E96

La formule en F88 est découpée en E94 E95 E96
avec une condition en F88 :
Si(B50<0; le calcul; sinon "N/A")

Si on met un chiffre négatif trop bas en B2, on a pour résultat "VALEUR!"
Je n'avais pas vu ça
On peut élargir la condition pour avoir aussi, dans ce cas, un N/A

En G95 :
=SI(OU(CFcum2007>0;MAX(CfCum)<=0);"N/A";E94+ABS(E95)/E96)

En F88 :
=SI(OU($B$50>0;MAX(CfCum)<=0);"N/A";MIN(SI(CfCum>0;COLONNE(CfCum)))-2+ABS(INDEX(CfCum;MIN(SI(CfCum>0;COLONNE(CfCum)))-2))/INDEX(CfNet;MIN(SI(CfCum>0;COLONNE(CfCum)))-1))

"Cela ne marche pas si on veut faire apparaître du texte si j ai bien compris…"
Tu peux faire apparaître du texte, N/A est du texte

N'empêche que je n'ai rien compris.
"si jamais le cash flow entrant n est pas suffisant pr récupérer l investissement sur toute la période".
1 ) "si jamais le cash flow entrant n est pas suffisant"
Il est où, celui-là ? Je n'ai fait que varier B2 pour faire des essais
2 ) "récupérer l investissement sur toute la période".
Si tu es encore en négatif en K50 ?

Dans le fichier joint, tu as une méthode pour imbriquer plusieurs formules en une seule.

Fred-et-ric · 24 Août 2006

Re : Problème avec formule complexe "SI"

Bonjour Monique,

Je donnerai les qq précisions sur le CF par après mais j voulais juste signaler que je n arrive pas à prendre le fichier du dernier post... 😕

Monique · 24 Août 2006

Re : Problème avec formule complexe "SI"

Re,

Le même, non zippé.

Fred-et-ric · 24 Août 2006

Re : Problème avec formule complexe "SI"

Salut Monique,

Merci beaucoup, cette fois je n ai eu aucun problème avec le fichier... A mon habitude, j vais déchiffrer à mon aise mais encore une fois, ton résultat à l air nickel dans les test que j ai effectué...

En fait, le but ici est de regarder la faisabilité d un projet. On va se baser sur le fait de voir s il est rentable ou non...
Pr cela on va comparer deux cas de figures:
- on ne fait pas l investissement
- on fait l investissement
Par rapport à cela, on va regarder ce que cela va générer comme différence dans l entrée et la sortie de l argent (cash flow/drain)! Ceci donne la diff total Production et Investissement. Normalement, la diff de production sera positive car l investissement amène un gain de productivité et la diff d investissement sera au début fortement négative pr s inverser peut-être après un certain temps (car ça nous coute plus au départ si on fait l investissement)

La diff cumulé de CF permet de voir si oui ou non, on arrive à récupérer sur une période donnée l investissement ou pas.(Des qu elle pas en positif) Et la formule si présente permet d affiner le calcul en rendant le temps nécessaire plus précis.

Si c est le cas (rapidement et que d autres calculs et ratios sont positifs également) on peut décider d investir dans le changement... 😉
Donc, si la diff d investissement total est plus grande que la diff totale de production alors, on sait que l investissement est non rentable financièrement...😛 Toutefois, on peut réaliser le projet car il est nécessaire sur le plan humain ou autre mais la je m égare du fil... 😀

Voilà, j espère avoir été clair dans mes explications (et j espère ne pas m être trompé non plus😛 )!

Merci beaucoup pt la formule matricielle Monique, attends toi à des questions de ma part dans les jours qui viennent...

Fred-et-ric · 24 Août 2006

Re : Problème avec formule complexe "SI"

Euh...
😛

J ai déjà une petite question supplémentaire ainsi qu un petit problème...
1) Si je veux faire passer mon 3,08 ans en 3 ans, x mois (et x jours), est-ce possible? Ca ne doit pas être dans la même cellule, comme ça je garde les deux réponses...
2) Quand je vais dans ta cellule pr la copier (F88) je vois qu il y a { au début ainsi qu à la fin de la cellule. Quand je clique dessus, le signe disparaît et après il ne m affiche plus la bonne réponse...😕
Du coup, dans mon fichier original, je n ai pas ça non plus et je ne sais pas si Excel va me donner la bonne réponse quand j introduirai mes données... 🙁

Monique · 24 Août 2006

Re : Problème avec formule complexe "SI"

Re,

Merci pour tes renseignements.

Vite fait, je coupe dans 15 minutes.

Question 2 :
les { et } avant et après la formule apparaissent dans la barre de formule
quand on a validé la formule en appuyant simultanément sur les 3 touches
ctrl, maj et entrée.
C’est Excel qui fait ça, il ne faut pas saisir les crochets au clavier.

Samantha · 24 Août 2006

Re : Problème avec formule complexe "SI"

Bonsoir le Forum, les Gens, le Fil,

Pour ton problème de dates la formule extraite de l'excellent cadeau de Pâques de Michel te convient elle ?

Calculer le temps écoulé entre 2 dates ( en années , mois et jours )
Exemple pour calculer l'age d'une personne dont la date de naissance est saisi dans la cellule A1
=DATEDIF(A1;AUJOURDHUI();'y')&' ans , '&DATEDIF(A1;AUJOURDHUI();'Ym')&' mois et '&DATEDIF(A1;AUJOURDHUI();'Md')&' jours'

A adapter à ton cas bien sûr.

Sam

Fred-et-ric · 25 Août 2006

Re : Problème avec formule complexe "SI"

Monique, merci pr cette astuce! Cela marche nickel maintenant...
Mais, au fait, ça sert à quoi de "valider" une cellule? J avais jamais du faire ça avant... 😛

Petite sorcière, bien-aimée de tous, merci pr l'astuce mais je ne suis pas sur qu elle soit appliquable dans ce cas si malheureusement (mais j me trompe peut être!😉 )
Ici, j ai une cellule (F88 dans le dernier fichier de Monique) qui indique le nombre d années qui ont été nécessaire pr récupérer l investissement. Ce nombre d années contient deux chiffres après la virgule. (3,08 ans par exemple) Le truc ici serait de transformer dans la cellule d à côté ce chiffre en une période plus compréhensible. Donc de dire que cela équivaut à 3 ans, x mois (et x jours)

Possible à faire?!
Oui monsieur, ici rien est impossible!!! 😀

Tibo · 25 Août 2006

Re : Problème avec formule complexe "SI"

Salut Fred et Ric,

Une solution formule :

En F88 : 3,08

=ENT(F88)&" ans "&ENT((F88-ENT(F88))*12)&" mois "&ARRONDI(((F88-ENT(F88))*12-ENT((F88-ENT(F88))*12))*30;0)&" jours"

La formule te donne la durée en années - mois - jours

@+

Problème avec formule complexe "SI"

Fred-et-ric

XLDnaute Nouveau

Tibo

XLDnaute Barbatruc

PascalXLD

XLDnaute Barbatruc

Fred-et-ric

XLDnaute Nouveau

Pièces jointes

Monique

Nous a quitté

Pièces jointes

Fred-et-ric

XLDnaute Nouveau

Monique

Nous a quitté

Pièces jointes

Fred-et-ric

XLDnaute Nouveau

Monique

Nous a quitté

Pièces jointes

Fred-et-ric

XLDnaute Nouveau

Fred-et-ric

XLDnaute Nouveau

Monique

Nous a quitté

Samantha

XLDnaute Accro

Fred-et-ric

XLDnaute Nouveau

Tibo

XLDnaute Barbatruc

Discussions similaires

Problème avec formule complexe "SI"

XLDnaute Nouveau

XLDnaute Barbatruc

XLDnaute Barbatruc

XLDnaute Nouveau

Pièces jointes

Nous a quitté

Pièces jointes

XLDnaute Nouveau

Nous a quitté

Pièces jointes

XLDnaute Nouveau

Nous a quitté

Pièces jointes

XLDnaute Nouveau

XLDnaute Nouveau

Nous a quitté

XLDnaute Accro

XLDnaute Nouveau

XLDnaute Barbatruc

Discussions similaires

Privacy & Transparency

Privacy & Transparency