Prendre en compte le 0 dans la fonction DROITE ou autre?

[Pixel_pix]

Bonjour à tous,

J'ai besoin de vos lumières!

Je recherche à récupérer le dernier chiffre d'un nombre.

J'ai une liste de nombre à deux chiffres après la virgule.

Je souhaite récupérer le dernier chiffre (donc le 2e après la virgule).

Aucun soucis avec la fonction DROITE(A1;1)... Sauf pour les nombres qui termine en 0.

Ex :
4,31 > DROITE(A1;1) = 1
4,30 > DROITE(A1;1) = 3

Comment faire pour prendre en compte le 0 comme un chiffre à part entière ?

Merci de votre aide !

 

[JHA]

Bonjour à tous,

A essayer

=SI(NBCAR(STXT(D22;CHERCHE(",";D22)+1;2))=2;STXT(D22;CHERCHE(",";D22)+1;2);STXT(D22;CHERCHE(",";D22)+1;2)&0)

JHA

 

[djidji59430]

Bonjour à tous,

a essayer :
=--DROITE(TEXTE(F17;"0,00");1)

Crdlmt

 

[JHA]

Bonjour à tous,
Bonjour @djidji59430

Eh ben, je me suis mis la tête à l'envers sur ce poste.
une autre proposition

=(A1-ENT(A1))*100

JHA

 

[Dranreb]

Bonjour.
Moi je dirais :

=MOD(ENT(A1*100+0,5);10)

 

[JHA]

Bonjour à tous,
Bonjour @Dranreb

Désolé, mauvaise lecture de ma part, je pensais qu'il fallait retourner les deux chiffres après la virgule.

=STXT((A1-ENT(A1))*100;2;1)

JHA

 

[Pixel_pix]

Merci pour vos réponses !

La solution de Dranreb semble fonctionner, je vais tester à plus grande échelle.

Pour les autres, les formules donnent les deux chiffres après la virgules, pas juste le dernier ^^

 

[djidji59430]

Re
ça serait étonnant, avec droite(xxx,1) que tu aies 2 chiffres !

 

[job75]

Bonjour à tous,

La formule de Dranreb ne va pas si le nombre est négatif, il faut ajouter ABS :

=MOD(ENT(ABS(A1)*100+1/2);10)

La formule de djidji59430 va bien mais il faut l'adapter si le séparateur décimal est le point :

=--DROITE(TEXTE(A1;GAUCHE(1/1000;4)))

Pour la dernière de JHA il faut plutôt écrire :

=--STXT(MOD(ABS(A1);1)*100;2;1)

Mais elle renvoie une erreur si le nombre est entier.

La 1ère prend 28 octets en mémoire, la 2ème 27 octets, la 3ème 28 octets.

A+

 

[Pixel_pix]

Bonjour à tous,

La formule de Dranreb ne va pas si le nombre est négatif, il faut ajouter ABS :

=MOD(ENT(ABS(A1)*100+1/2);10)

La formule de djidji59430 va bien mais il faut l'adapter si le séparateur décimal est le point :

=--DROITE(TEXTE(A1;GAUCHE(1/1000;4)))

Pour la dernière de JHA il faut plutôt écrire :

=--STXT(MOD(ABS(A1);1)*100;2;1)

Mais elle renvoie une erreur si le nombre est entier.

La 1ère prend 28 octets en mémoire, la 2ème 27 octets, la 3ème 28 octets.

A+

Rien à rajouter ! Merci à toi !