XL 2019 position du dernier caractère numérique d'une chaine de caractère

[philppe27]

Bonjour à tous,
Existe-t-il une formule excel qui permet de trouver la position du dernier caractère numérique dans une chaine de caractère ?

Merci d'avance pour votre aide

 

[Victor21]

Bonjour, Philippe27.

La chaîne en A1, essayez
=SIERREUR(TROUVE(DROITE(1*STXT(A1;EQUIV(1;1*ESTNUM(1*STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1));0);SOMME(1*ESTNUM(1*STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1)))));A1);"")
A valider en matriciel (Ctrl+Maj+Entrée les accolades apparaissent en début : { et en fin de formule : }


Limite gênante : les chiffres doivent impérativement être uniques (pas de 11, de 202 ou de 566)

 

[job75]

Bonjour philppe27, Patrick,

Voyez le fichier joint et cette formule matricielle en B1, à valider par Ctrl+Maj+Entrée :

=STXT(A1;MAX(SI(ESTNUM(-STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1));LIGNE(INDIRECT("1:"&NBCAR(A1)))));1)

A+

 

[Staple1600]

Bonsoir le fil, philippe27, Victor21, job75

Une autre formule qui renvoie la position du dernier caractère numérique en partant de la gauche
Si en A1, on a : abc12e
Et en B1 cette formule =AGREGAT(14;6;TROUVE({1;2;3;4;5;6;7;8;9;0};A1;LIGNE(INDIRECT("1:"&NBCAR(A1))));1) renvoie 5.
NB: L'inconvénient c'est qu'elle ne fonctionnera qu'à partir de Excel 2010.

 

[job75]

Salut JM,

Ah oui pardon c'est la dernière position qui est demandée donc fichier (2) avec la formule matricielle en B1 :

=MAX(SI(ESTNUM(-STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1));LIGNE(INDIRECT("1:"&NBCAR(A1)))))

A+

 

[BOISGONTIER]

Bonsoir,

Il suffit de chercher à partir de la droite.

=NBCAR(A1)-EQUIV(VRAI;ESTNUM(CNUM(STXT(A1;NBCAR(A1)-LIGNE($1:$255);1)));0)
Valider avec maj+ctrl+entrée

abcdx56xxxx donne 7

Boisgontier

 

[Staple1600]

Re

J'ai oublié de préciser que la formule du message#4 n'est pas matricielle
(Donc validation classique avec ENTER)

 

[job75]

Bonsoir JB,

Tu m'as mis la puce à l'oreille, c'est en effet très simple avec EQUIV, toujours en matriciel :

=EQUIV(9;-STXT(A1;LIGNE(INDIRECT("1:"&NBCAR(A1)));1))

Fichier (3)

A+

 

[philppe27]

Merci à tous. C'est vrai que c'est moins contraignant lorsque ce n'est pas matriciel

 

[philppe27]

Staple 1600 je viens d'essayer ta formule, il y a un problème quand devant l'avant dernier chiffre est le même que le dernier. La position renvoyée est celle de l'avant dernier chiffre

 

[Staple1600]

Re

Ce n'est pas grave 😉
Il suffit de taquiner deux touches de plus pour éviter le souci 😉

 

[Staple1600]

Re

=>philippe27
Autre formule (mais cette fois-ci en partant de la droite 😉)
La position
=EQUIV(1;INDEX(--ESTNUM(--STXT(A1;NBCAR(A1)+1-LIGNE(INDIRECT("1:"&NBCAR(A1)));1));0);0)
Et pour se compliquer la tâche et si vraiment tu ne veux pas de matriciel
=NBCAR(A1)+1-EQUIV(1;INDEX(--ESTNUM(--STXT(A1;NBCAR(A1)+1-LIGNE(INDIRECT("1:"&NBCAR(A1)));1));0);0)
Avec en A1: abc12efg333hi, cette dernière formule renvoie 11
(comme la dernière proposée par job75 qui est quand même beaucoup plus simple à saisir non ? (je parle en nombre de caractères) )

 

[philppe27]

Merci Stapple tout y est c'est super