Ceci est une page optimisée pour les mobiles. Cliquez sur ce texte pour afficher la vraie page.

XL 2016 passer d'une liste avec coordonnées à une version tableau et vice versa

B

bolem

XLDnaute Nouveau
Bonjour


Je vous présente mes deux problèmes réciproques:
- j'ai une liste dans laquelle il y a les données X, Y et la valeur sur ce point. J'aimerai pouvoir voir les valeurs sur un tableau qui aurait pour coordonnée (X,Y)

- J'ai un tableau qui donne les valeurs en (X,Y) , j'aimerai pouvoir récupérer la liste des valeurs avec par ligne, X, Y et la valeur associée.



Pour tout vous dire , c'est vrai qu'on pourrait rapprocher ce problème à celui- ci : j'ai les données mensuelles de vente depuis 10 ans et j'aimerai avoir un tableau avec comme entete de colonne les années et comme entete de ligne les mois...
Mais mon souci est que ce sont en vrai des coordonnées et à la fin je peux avoir un tableau de 200 par 200 cases.... ça commence à faire long de mettre les liens à la main ;-(
Avez-vous une idée pour simplifier la création des liens dans un sens ou dans l'autre (voir le fichier joint , il y a deux onglets)
Merci par avance
 

Pièces jointes

  • test valeur X-Y.xlsx
    18.7 KB · Affichages: 6
Trier par date Trier par votes

Cousinhub

XLDnaute Barbatruc
Inactif
Bonjour,
Ce qu'on peut faire avec Power Query (en natif dans ta version...)
Clic droit dans une des requêtes, "Actualiser", pour mettre à jour
 

Pièces jointes

  • PQ_Bolem.xlsx
    31.8 KB · Affichages: 3
Vote positif 0 Vote négatif

Gégé-45550

XLDnaute Accro
Bonsoir,
Une proposition sans PQ, avec des formules matricielles (sauf pour Excel 365) à valider par CTRL+MAJ+ENTRÉE
Cordialement,
 

Pièces jointes

  • PQ_Bolem_GG.xlsx
    38.8 KB · Affichages: 6
Vote positif 0 Vote négatif

cp4

XLDnaute Barbatruc
Bonjour @bolem , @Cousinhub , @Gégé-45550 ,

En VBA
VB: 
Option Explicit

Sub Liste_Dessin()
   Dim f As Worksheet, TblBD(), CelDepart As Range, d1 As Object, d2 As Object, i As Integer
   Dim clé1, clé2, lig As Long, col As Integer
   Set f = ThisWorkbook.Sheets("liste vers dessin")
   TblBD = f.Range("b4:d" & f.Range("b" & Rows.Count).End(xlUp).Row).Value
   Set CelDepart = f.Range("h13")                        ' Adresse résultat
   Set d1 = CreateObject("Scripting.Dictionary")
   Set d2 = CreateObject("Scripting.Dictionary")
   Dim TblRes(1 To 100, 1 To 100)
   For i = LBound(TblBD) To UBound(TblBD)
      clé1 = TblBD(i, 1): If d1.exists(clé1) Then lig = d1(clé1) Else d1(clé1) = d1.Count + 1: lig = d1.Count
      clé2 = TblBD(i, 2): If d2.exists(clé2) Then col = d2(clé2) Else d2(clé2) = d2.Count + 1: col = d2.Count
      TblRes(lig, col) = TblBD(i, 3)
   Next i
   CelDepart.Offset(1).Resize(d1.Count, 1) = Application.Transpose(d1.keys)   ' titre lignes
   CelDepart.Offset(, 1).Resize(1, d2.Count) = d2.keys             ' titres colonnes
   CelDepart.Offset(1, 1).Resize(d1.Count, d2.Count) = TblRes  ' résultat

   Set CelDepart = Nothing
   Set d1 = Nothing
   Set d2 = Nothing
End Sub

Sub Dessin_Liste()
   Dim f As Worksheet, CelDepart As Range, TblE, n As Long, ligne As Long, col As Integer
   Set f = Sheets("dessin vers liste")
   Set CelDepart = f.Range("b4")
   TblE = f.[i3].CurrentRegion
   Dim TblS(): ReDim TblS(1 To UBound(TblE) * UBound(TblE, 2), 1 To 3)
   n = 0
   For ligne = 2 To UBound(TblE, 1)
      For col = 2 To UBound(TblE, 2)
         If TblE(ligne, col) <> "" Then
            n = n + 1
            TblS(n, 1) = TblE(ligne, 1)
            TblS(n, 2) = TblE(1, col)
            TblS(n, 3) = TblE(ligne, col)
         End If
      Next col
   Next ligne

   f.Range("b4:d" & f.Range("b" & Rows.Count).End(xlUp).Row).ClearContents
   CelDepart.Resize(n, 3) = TblS
End Sub
NB: Tout le mérite est pour le regretté JB (ici)

Bonne journée.
 
Vote positif 0 Vote négatif

Gégé-45550

XLDnaute Accro
bolem à dit:
Bonjour
Merci pour votre message, j'ai bien vu le passage dans l'onglet liste vers dessin mais je n'ai pas vu dans l'onglet dessin vers liste...
merci
Cliquez pour agrandir...
Bonjour,
Pardon, je n'avais pas compris qu'il fallait aussi écrire les formules dans l'onglet 'Dessin vers Liste'.
Voilà qui répare cette inattention.
Cordialement,
 

Pièces jointes

  • PQ_Bolem_GG.xlsx
    41 KB · Affichages: 2
Vote positif 0 Vote négatif
Identifiez-vous ou inscrivez-vous pour participer.

Discussions similaires

M
  • Question
XL 2021 Vérification correspondance 2 tableaux
Réponses
12
Affichages
421
job75
  • Résolu(e)
XL 2013 Faire ressortir des valeurs par rapport à une valeur donnée
Réponses
13
Affichages
566
Phil69970
D
  • Résolu(e)
XL 2021 Créer feuilles automatiquement dans un classeur a partir d'une liste et lien hypertexte
Réponses
6
Affichages
475
Phil69970
C
  • Résolu(e)
XL 2019 Meilleure option suivant les valeurs
Réponses
7
Affichages
423
cotignac
C
D
  • Question
XL 2016 Une Zone de Liste pour plusieurs cellules.
Réponses
7
Affichages
191
duduche62
D
J
  • Résolu(e)
Autres Créer des liens hypertexte automatiques et dans plusieurs colonnes dans un tableau excel
Réponses
8
Affichages
237
JMC
J
G
  • Question
XL 2019 Tableaux Croisé Dynamique avec plusieurs filtres
Réponses
1
Affichages
387
chris
  • Question
XL 2021 [Résolu] : Récupérer les coordonnées d'une cellule sur une feuille créée dynamiquement
Réponses
3
Affichages
518
Zdz16
J
  • Question
Microsoft 365 fonction decale et recherche V
Réponses
2
Affichages
169
JVOS
J
S
  • Question
XL 2016 Afficher les bornes min et max dans lequel se trouve une valeur
Réponses
5
Affichages
392
stuka
S
Menu
Connexion
S'inscrire
Les cookies sont requis pour utiliser ce site. Vous devez les accepter pour continuer à utiliser le site. En savoir plus…