Paramètres dans un classeur

[Imy]

Bonjour,

Existe-il une solution pour enregistrer des paramètres dans un classeur à partir de VBA?

Je recherche un moyen de conserver le contenu de certaines de mes variables de manière à pouvoir les relire à la réouverture de mon fichier. Je ne veux pas les inscrire dans mes feuilles de manière à ne pas tout mélanger. Connaîtriez-vous s'il vous plaît, une solution, genre xml, méta-donnée, ou autre?

Merci d'avance.

 

[PascalXLD]

Re : Paramètres dans un classeur

Bonjour

une solution toute simple comme tu le sdis c'est d'enregistrer sur ue feuille bien précise et de la cacher à la fermeture de ton fichier

 

[Imy]

Re : Paramètres dans un classeur

Merci. J'avais pensé à une chose comme cela, mais je n'y aime pas trop : une feuille de plus à gérer, plus de mémoire, et en plus ajouter un index de feuille fait compliquer mon code !
Mais je préférerais des choses plus simples, plus nets, plus franches comme des variables stockées à l'entête du fichier classeur. Je pense que cela doit exister de la part d'excel, ce n'est pas trop compliqué, sinon les variables du classeur n'ont pas de persistance sans recourir au bidouillage de feuille!
Ca m'arrangerais bien un truc du genre application.variable(1).value=true par exemple

 

[MichelXld]

Re : Paramètres dans un classeur

Bonjour Imy, bonjour cher Pascal

ce n'est pas trop compliqué, sinon les variables du classeur n'ont pas de persistance sans recourir au bidouillage de feuille!

une feuille de plus à gérer, plus de mémoire, et en plus ajouter un index de feuille fait compliquer mon code !

La solution de stocker les données dans une feuille sera toujours la plus simple à mettre en oeuvre.


Une autre solution pourrait consister à stocker les informations dans une propriété perosnnalisée :
Lire et modifier les propriétés des classeurs et autres fichiers - Club d'entraide des développeurs francophones
(chapitres II-C à II-F)


bonne journée
michel

 

[MJ13]

Re : Paramètres dans un classeur

Bonjour à tous

Sinon, on peux aussi passer par les noms avec \Insertion \Nom \Définir.
C'est assez facile à gérer avec l'enregistreur de macros et le VBA.

Par exemple, sous ma signature, le lien pour faire ses comptes, les numéros de chêques sont gérés par un nom.

 

[tototiti2008]

Re : Paramètres dans un classeur

Bonjour à tous,

Toujours dans l'idée des propriétés du classeur, 4 petites macros exemple (en retard mais comme je les ai faites) :

Sub CreeProprietes()
    With ThisWorkbook.CustomDocumentProperties
        .Add Name:="Variable1", LinkToContent:=False, Type:=msoPropertyTypeNumber, Value:=5
        .Add Name:="Variable2", LinkToContent:=False, Type:=msoPropertyTypeString, Value:="toto"
        .Add Name:="Variable3", LinkToContent:=False, Type:=msoPropertyTypeDate, Value:=Date
    End With
End Sub
 
Sub ModifProprietes()
    With ThisWorkbook
        .CustomDocumentProperties("Variable1").Value = 6
        .CustomDocumentProperties("Variable2").Value = "titi"
        .CustomDocumentProperties("Variable3").Value = Date - 1
    End With
End Sub
 
Sub LitProprietes()
Dim Var1 As Long, Var2 As String, Var3 As Date
    With ThisWorkbook
        Var1 = .CustomDocumentProperties("Variable1").Value
        Var2 = .CustomDocumentProperties("Variable2").Value
        Var3 = .CustomDocumentProperties("Variable3").Value
    End With
    MsgBox Var1 & " - " & Var2 & " - " & Var3
End Sub
 
Sub SupprProprietes()
    With ThisWorkbook
        .CustomDocumentProperties("Variable1").Delete
        .CustomDocumentProperties("Variable2").Delete
        .CustomDocumentProperties("Variable3").Delete
    End With
End Sub

 

[Imy]

Re : Paramètres dans un classeur

Merci pour ces idées. C'est étonnant qu'avec le xml, ils n'ont pas pensé à introduire ce genre de stockage de variables. Enfin, la solution en utilisant des paramètres de fichiers est intéressante, même s'il s'agit d'un détournement de fonction (encore une!). Ajouté à cela, des propriétés techniques, qui n'ont de sens autrement que dans le code, se retrouvent mélées à des propriétés intelligibles, au regard de l'utilisateur commun... cela fait brouillon, mais bon à défaut...
La solution des noms est intéressante, dans une certaine mesure, si on utilise une feuille ; le nom de cellule permet de faciliter l'appel de la cellule effectivement.