Ouvrir plusieurs fichiers en 1

[Bud.boundy]

Bonjour,

Le problème a déjà été traiter plusieurs fois sur ce forum mais rien n'y fait, je n'arrive pas à appliquer aucune des macros à mes besoins...

En fait, j'aimerais récuperer les données de plus de 300 classeurs afin qu'elles se mettent à la suite les unes des autres dans un même classeur excel... A savoir que les données sont contenues dans des fichiers au format HTML, dans une seule feuille et que les données contenues dans chacun de ces classeurs ne depassent pas la selection A1:H50

Mes fichiers se trouvent à la place suivante :
C:\Documents and Settings\Claude\Bureau\stat

Si quelqu'un pouvait m'aider, cela m'éviterait d'avoir à les ouvrir les uns à la suite des autres...

Merci

 

[Bud.boundy]

Re : Ouvrir plusieurs fichiers en 1

Bonsoir,

En fait il s'agit de fichier que j'ai téléchargé sur internet grâce à un aspirateur... En fait je peux facilement les ouvrir avec excel... Mais dès lors que clique droit sur le fichier pour aller dans propriété, celle-ci affiche un fichier HTML... D'ailleurs le logo Internet explorer est afficher sur le fichier...

En espérant avoir été un peu plus clair...
Merci

 

[Bud.boundy]

Re : Ouvrir plusieurs fichiers en 1

Rebonsoir,

En fait, il est ecrit type de fichier : HTML Document
En gros, chacun de ces fichiers ne contient qu'une seule et unique page de données comprises entre les cellules A1 et H50...

J'aimerais mettre les données de ces 300 fichiers à la suite des unes des autres sur une même feuille de telle faon qu'elle aillent de la cellule A1 à H100000... Bref à l'infini...

Est ce possible ???

Merci et désolé pour mes explications un peu floues

 

[Bud.boundy]

Re : Ouvrir plusieurs fichiers en 1

bonjour,

pardon pour le retard

merci pour le coup de main

 

[MichelXld]

Re : Ouvrir plusieurs fichiers en 1

bonjour

tu peux tester cette procedure, en supposant que les tableaux ont tous la même structure dans les pages htm
ça risque d'être un peu long pour 300 fichiers ...

Sub ExtraireDonneesTableaux_Htm()
'
'activez la référence Microsoft HTML Objects Library
'activez la référence Microsoft Internet Controls
'
Dim Fichier As String, Chemin As String
Dim IE As InternetExplorer
Dim maPageHtml As HTMLDocument
Dim Htable As IHTMLElementCollection
Dim maTable As IHTMLTable
Dim j As Integer, i As Integer
Dim x As Long
 
'Définit le repertoire et le type de fichier à rechercher
Chemin = "C:\Documents and Settings\mimi\dossier\general\excel\dossier"
Fichier = Dir(Chemin & "\*.htm")
 
'boucle sur les fichiers du répertoire
Do While Fichier <> ""
 
    'Creation instance InternetExplorer
    Set IE = CreateObject("InternetExplorer.Application")
    ' IE reste masqué pendans l'opération
    IE.Visible = False
 
    'ouverture des fichier .htm
    IE.navigate Chemin & "\" & Fichier
        Do Until IE.readyState = READYSTATE_COMPLETE
            DoEvents
        Loop 'attend la fin du chargement avant de poursuivre
 
    Set maPageHtml = IE.document
    'objet type table
    Set Htable = maPageHtml.getElementsByTagName("table")
    'spécifie le premier tableau dans la page htm
    Set maTable = Htable(0)
 
    'boucle sur les lignes du tableau contenant des données
    '
    'à adapter en fonction de la structure des tableaux
    '
    For i = 4 To maTable.Rows.Length - 5
    x = x + 1
 
    'boucle sur les cellules dans chaque ligne
        For j = 1 To maTable.Rows(i - 1).Cells.Length
            Cells(x, j) = maTable.Rows(i - 1).Cells(j - 1).innerText
        Next j
    Next i
 
    'Fermeture Internet Explorer
    IE.Quit
    Set IE = Nothing
 
    Fichier = Dir
Loop
MsgBox "Opération terminée."
End Sub

bon apres midi
MichelXld

 

[Bud.boundy]

Re : Ouvrir plusieurs fichiers en 1

Merci Michel

J'ai un petit pb puisque cela ne marche pas... Qd j'ai mis le code puis lancer la macro, celle-ci bug et me renvoie directement à Dim IE As InternetExplorer... pourriez vous s'il vous plaît me dire quoi modifier ou tout simplment me joindre un fichier ce qui serait peut etre plus simple pour un debutant comme moi...

Merci beaucoup

 

[MichelXld]

Re : Ouvrir plusieurs fichiers en 1

rebonjour à vous 2

il est précisé en début de procédure:

'activez la référence Microsoft HTML Objects Library
'activez la référence Microsoft Internet Controls

Dans l'éditeur de macros,
Menu Outils
Références
Coche les 2 lignes citées plus haut
Clique sur OK pour valider

bonne journée
MichelXld

 

[Bud.boundy]

Re : Ouvrir plusieurs fichiers en 1

Merci beaucoup ca marche,

Mon pb maintenant est que j'aimerais en fait ne prendre que les informations des fichiers dont le nom se termine soit par 1, soit par 2, soit par 3 soit par 4 ou soit par 5... (ex : allum3)

Y a t-il quelque chose à faire ???

Sinon merci encore et bravo à vous