ouvrir l'explorateur chemin et fichier dans variable

[sri75]

Bonjour, j'utilise une macro pour ouvrir un rpertoire et choisir un fichier mais je voudrais stocker le chemin et le mon du fichier dans deux variables différentes ( rep et nomfic ).

le code ci-dessous stocke le chemin et le nom du fichier, pouriiez vous m'aider pour séparer les deux ?

Merci d'avance

Sub ouvre()

origine:



MsgBox ("Choisissez votre répertoire de travail à l'aide de l'explorateur")

With Application.FileDialog(msoFileDialogFolderPicker)
.InitialFileName = ActiveWorkbook.Path & "\"
.Show
If .SelectedItems.Count > 0 Then
rep = .SelectedItems(1)
Else

Exit Sub
End If
End With

MsgBox ("Choisissez votre fichier à l'aide de l'explorateur")

With Application.FileDialog(msoFileDialogFilePicker)
.InitialFileName = ActiveWorkbook.Path
.Show
If .SelectedItems.Count > 0 Then
nomfic = .SelectedItems(1)

Else

Exit Sub
End If
End With


' Workbooks.Open Filename:=nomfic
Workbooks.Open Filename:=rep & nomfic

end sub

 

[kiki29]

Re : ouvrir l'explorateur chemin et fichier dans variable

Salut,une possibilité,à adapter

Option Explicit

Sub Tst()
Dim sNomFichier As String
Dim sDossier As String
    With Application.FileDialog(msoFileDialogFilePicker)
        .InitialFileName = ThisWorkbook.Path
        .AllowMultiSelect = False
        .Show
        If .SelectedItems.Count > 0 Then
            sNomFichier = Dir$(.SelectedItems(1))
            sDossier = Left$(.SelectedItems(1), Len(.SelectedItems(1)) - Len(sNomFichier))
            Debug.Print sDossier, sNomFichier
        End If
    End With
End Sub

 

[sri75]

Re : ouvrir l'explorateur chemin et fichier dans variable

ca a l'air de très bien fonctionner; serait il possible de faire d'abord choisir le répertoire, de fermer l'explorateur, puis de réouvrir l'explorateur pour choisr le fichier ?

Merci