Ouverture fichier nom différent à chaque fois

[Ken Hutchinson]

Bonjour à tous,

Je voudrais faire une macro pour faire un raccourci dans Excel pour ouvrir un fichier sans avoir à le rechercher dans les méandres du réseau informatique de ma boite.

Le fichier est toujours au même endroit mais change de nom à chaque fois. En fait dans le nom du fichier il y a la date de création. et c'est le seul dans le répertoire.

Comment faire pour ouvrir ce fichier par macro ?

 

[tototiti2008]

Re : Ouverture fichier nom différent à chaque fois

Bonjour Ken,

il faut faire une recherche de fichier dans ce dossier. Si tu dispose d'Excel 2002 ou plus, tu peux utiliser un objet FileSearch, sinon tu peux faire une boucle avec l'instruction Dir

 

[skoobi]

Re : Ouverture fichier nom différent à chaque fois

Bonjour Ken,
salut tototiti,

pour connaitre la date du fichier, utilises FileDateTime.
Quel est le format de la date dans le nom du fichier?
jjmmaa, jjmmaaaa?
Si tu nous donne le chemin vers le fichier, on pourra te montrer un exemple.

 

[Ken Hutchinson]

Re : Ouverture fichier nom différent à chaque fois

Voilà le code que j'utilise. on pourrait peut être chercher le fichier le plus récent sinon ?

Sub Ouvrir_MIC()


    ChDir _
        "M:\dataservices\Ventes\IP"
    Workbooks.Open Filename:= _
        "M:\dataservices\Ventes\IP\Photo ventes du 10-10-2008.xls" _
        , UpdateLinks:=0, Notify:=False
        
        
        
 Workbooks("Ouvrir Fichiers.xls").Close

End Sub

 

[skoobi]

Re : Ouverture fichier nom différent à chaque fois

Re,

si il n'y a qu'un seul fichier dans le répertoire (comme tu l'as signalé dans le premier message), ceci suffit:

......
NomFichier = Dir("M:\dataservices\Ventes\IP\")
Workbooks.Open Filename:= _
        "M:\dataservices\Ventes\IP\" & NomFichier _
        , UpdateLinks:=0, Notify:=False
......

 

[Staple1600]

Re : Ouverture fichier nom différent à chaque fois

Bonjour Ken , skoobi, le fil, le forum


A tester
(adapter le nom du chemin)

Sub Ouvrir_Fichier_Date_Dans_nom()
Dim Str As String
Str = Format(Date, "ddmmyyyy")
With Application.FileSearch
    .NewSearch
    .LookIn = "c:\temp"
    .FileType = msoFileTypeExcelWorkbooks
    .Filename = "*" & Str & "*.xls"
        If .Execute > 0 Then
        For i = 1 To .FoundFiles.Count
        Workbooks.Open (.FoundFiles(i))
        Next
    End If
End With
End Sub

Et pour ouvrir le plus récent

Sub Ouvrir_PlusRécent_II()
Dim y As Integer
With Application.FileSearch
    .NewSearch
    .LookIn = "c:\temp"
    .Filename = "*.xls"
        If .Execute(SortBy:=msoSortByLastModified, _
        SortOrder:=msoSortOrderDescending) > 0 Then
        x = Split(.FoundFiles(1), "\"): y = UBound(x)
        MsgBox "Classeur le plus récent : " _
        & x(y) & Chr(13) & Chr(13) & _
        "Créé le :  " & FileDateTime(.FoundFiles(1)), _
        vbInformation, "Résultats"
    Workbooks.Open (.FoundFiles(1))
    End If
End With
End Sub

 

[Staple1600]

Re : Ouverture fichier nom différent à chaque fois

Re



Une autre façon (code plus court)

Sub Ouvrir_Fichier_Date_Dans_Nom_II()
Dim Chemin
Dim Str As String
Chemin = "C:\Temp\"
Str = Format(Date, "ddmmyyyy")
Dim Classeur As String
Classeur = Dir(Chemin & "*" & Str & "*.xls")
    Do Until Len(Classeur) = 0
        Workbooks.Open (Chemin & Classeur)
        Classeur = Dir
    Loop
End Sub