nombre et somme multicritères variables

F

fredl

XLDnaute Impliqué

• 11 Décembre 2014

• #2

Re : nombre et somme multicritères variables

en D21 :
=SOMMEPROD(($C$2:$L$2>=$B$14)*($C$2:$L$2<=$B$15)*($A$3:$A$6=$B$13)*($C$3:$L$6<>O5)*($C$3:$L$6<>O4)*($C$3:$L$6<>O3)*($C$3:$L$6<>O2))
je me penche pour le reste...
obligatoirement sans macro?
cdt
Fred

 

Vote positif 0 Vote négatif

M

medcheriflala

XLDnaute Nouveau

• 11 Décembre 2014

• #3

Re : nombre et somme multicritères variables

oui ça marche même si le petit fichier essai est une version bcp plus simple que celui sur lequel je bosse (il y a en tous 11 situations congé, suspendu, férié...etc.) mais ça marche en tt cas même si la formule sera assez longue

non pas de macro svp.

 

Vote positif 0 Vote négatif

F

fredl

XLDnaute Impliqué

• 11 Décembre 2014

• #4

Re : nombre et somme multicritères variables

nb d'heures :
=SOMMEPROD($C$3:$L$6;($C$2:$L$2>=$B$14)*($C$2:$L$2<=$B$15)*($A$3:$A$6=$B$13)*($C$3:$L$6<>O5)*($C$3:$L$6<>O4)*($C$3:$L$6<>O3)*($C$3:$L$6<>O2))

ça le fait?
Merci, tu m'as appris qqe chose!
Cdt
Fred

 

Vote positif 0 Vote négatif

M

medcheriflala

XLDnaute Nouveau

• 11 Décembre 2014

• #5

Re : nombre et somme multicritères variables

ça maaaaaaaaaaaarche !!!!!!!!! merci bcp

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 11 Décembre 2014

• #6

Re : nombre et somme multicritères variables

Bonjour,

Avec le test ESTNUM c'est plus simple, en D21 et D22 :

Code:

=SOMMEPROD(($C$2:$L$2>=$B$14)*($C$2:$L$2<=$B$15)*($A$3:$A$6=$B$13)*ESTNUM($C$3:$L$6))

Code:

=SOMMEPROD(($C$2:$L$2>=$B$14)*($C$2:$L$2<=$B$15)*($A$3:$A$6=$B$13);$C$3:$L$6)

A+

 

Vote positif 0 Vote négatif

M

medcheriflala

XLDnaute Nouveau

• 14 Décembre 2014

• #7

Re : nombre et somme multicritères variables

effectivement bcp plus simple on en apprend chaque jour

9a m'arrange d'autant plus que mon tableau est beaucoup plus complexe

merci beaucoup pour votre aide et bon weekend à tous

 

Vote positif 0 Vote négatif

M

Monique

Nous a quitté

Repose en paix

• 14 Décembre 2014

• #8

Re : nombre et somme multicritères variables

Bonjour,

Si on n’est pas allergique à la validation matricielle,
en D21 :

=NB(SI(($C$2:$L$2>=$B$14)*($C$2:$L$2<=$B$15)*($A$3:$A$6=$B$13);$C$3:$L$6))
à valider par ctrl, maj et entrée

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

• 14 Décembre 2014

• #9

Re : nombre et somme multicritères variables

Bonjour @ tous,
Un salut spécial à Job75 ,
du fait que vous cherchez le plus simple, alors je peux peut-être intervenir,

en D21 :

Code:

=NB(DECALER(B2;EQUIV(B13;A3:A6;0);EQUIV(B14;C2:L2;0);;B15-B14+1))

en D22 :

Code:

=SOMME(DECALER(B2;EQUIV(B13;A3:A6;0);EQUIV(B14;C2:L2;0);;B15-B14+1))

@ + +


Edit : Salut Monique

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

• 14 Décembre 2014

• #10

Re : nombre et somme multicritères variables

Re,
Pour les formules de la plage D17: D20, on peut aussi simplifier si tu veux, en D17 :

Code:

=NB.SI(DECALER(B$2;EQUIV(B$13;A$3:A$6;0);EQUIV(B$14;C$2:L$2;0);;B$15-B$14+1);O2)

@ tirer vers le bas

Noter que tu peux toute fois remplacer la cellule O2 par GAUCHE(A17)&"*" comme ça tu n'auras pas besoin de la colonne O masquée.



@ + +

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 14 Décembre 2014

• #11

Re : nombre et somme multicritères variables

Bonjour medcheriflala, hello Monique, R@chid

En D21 les formules de Monique et R@chid "pèsent" toutes deux 75 octets en mémoire, la mienne 67 octets.

En D22 celle de R@chid "pèse" 75 octets, la mienne 63 octets

A+

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

• 14 Décembre 2014

• #12

Re : nombre et somme multicritères variables

Re,
Mais les tiennes sont des matricielles alors que les miennes sont des formules classiques, apparemment ils vont être plus rapides que les tiennes sur une grande base de données.
le problème de poids vient de la fonction DECALER()


@ + +

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 14 Décembre 2014

• #13

Re : nombre et somme multicritères variables

Re R@chid,

Tu as tout à fait raison, simplement sur le fichier du post #1 :

- tes formules en D21 => 23,4 µs et en D22 => 23,1 µs

- mes formules en D21 => 56,7 µs et en D22 => 48,9 µs.

A+

 

Vote positif 0 Vote négatif

R@chid

XLDnaute Barbatruc

• 16 Décembre 2014

• #14

Re : nombre et somme multicritères variables

Bonsoir @ tous,
Je viens d'apprendre une triste nouvelle, notre amie Monique est venue nous dire au revoir par la formule en post #8, c’était son dernier post sur le forum, malheureusement Monique est décédée .

A dieu Monique, tu vas nous manquer trop


@ + +

 

Vote positif 0 Vote négatif

job75

XLDnaute Barbatruc

• 16 Décembre 2014

• #15

Re : nombre et somme multicritères variables

Bonsoir à tous,

Quelle bien triste nouvelle, nous aimions tant Monique, et elle était une maitresse de ce forum.

Toutes mes condoléances à sa famille.

 

Vote positif 0 Vote négatif