Nombre de valeurs sans doublons et celulles vides

[roidurif]

Bonjour,

Je souhaite compter le nombre de valeurs sans doublons avec la condition suivante, toute valeur superieur à la date saisie (ex : 02/01/2009).
Sachant que dans la colonne des valeur, il y a des celulles vides.

La fonction utilisée
=SOMMEPROD(1/NB.SI(A2:A22;A2:A22)*(B1:B22>E2))

Alt+MAJ+ENTREE

Celle-ci ne fonctionne pas lorqu'il ya des cellules vides.

Comment adapter cette fonction pour mon cas?

Je vous joins mon fichier d'exemple

merci d'avance

 

[Tibo]

Re : Nombre de valeurs sans doublons et celulles vides

Bonjour,

Un début de piste qui permet de compter le nombre d'occurences en ignorant les cellules vides :

=SOMME(SI(ESTVIDE(B1:B22);0;1/NB.SI(B1:B22;B1:B22)))

Matricielle, donc CTRL + MAJ + ENTREE

Je ne parviens pas pour le moment à intégrer la date dans cette formule.

@+

 

[job75]

Re : Nombre de valeurs sans doublons et celulles vides

Bonjour roidurif, Tibo,

Si j'ai bien compris, voir cette formule matricielle :

Désolé, formule enlevée, j'avais oublié les doublons...

A+

 

[Tibo]

Re : Nombre de valeurs sans doublons et celulles vides

Salut Job,

Si j'ai bien compris la question de notre ami, il s'agit de compter le nombre de valeurs de la colonne B en faisant abstraction des doublons.

J'y parviens avec la formule proposée un peu plus haut (mais sans prendre en compte le critère Date)

@+

 

[job75]

Re : Nombre de valeurs sans doublons et celulles vides

Re,

Bon, je refais mon post, cette fois en tenant compte des doublons.

La formule matricielle :

=SOMME((Plage1<>"")*(Plage1>E2)*SI(Plage2<>"";EQUIV(Plage2;Plage2;0)=LIGNE(Plage2)))

Et le fichier.

Edit : ce n'était pas le bon fichier 😱

A+

 

[roidurif]

Re : Nombre de valeurs sans doublons et celulles vides

Bonjour Tibo et job75,

Merci à vous deux, je viens tester la formule proposée par JOB 75

=SOMME((Plage1<>"")*(Plage1>E2)*SI(Plage2<>"";EQUIV(Plage2;Plage2;0)=LIGNE(Plage2)))

Je ne comprend pas quand j'indique en condition toutes les dates > à 15/01/2009, j'ai un resultat de 1 alors que j'en compte 2.

Merci encore de votre aide

 

[job75]

Re : Nombre de valeurs sans doublons et celulles vides

Re,

Exact roidurif, et c'est normal avec cette formule : le 1er FC est considéré comme un doublon, car il était apparu antérieurement. Donc il n'est pas compté.

Je regarde si l'on peut résoudre ça, mais pas sûr du tout.

A+

 

[Tibo]

Re : Nombre de valeurs sans doublons et celulles vides

Bonjour,

Une adaptation d'une formule trouvée dans ce cpost :

https://www.excel-downloads.com/threads/nbre-de-valeur-differentes.107330/

et qui fait appel à la fonction FREQUENCE :

=NB(1/FREQUENCE(SI(A1:A22>E2;SI(B1:B22<>"";EQUIV(B1:B22;B1:B22;0)));
SI(A1:A22>E2;SI(B1:B22<>"";EQUIV(B1:B22;B1:B22;0)))))

Matricielle

à tester

@+

 

[job75]

Re : Nombre de valeurs sans doublons et celulles vides

Re,

Bon j'ai pu adapter ma formule, il fallait définir autrement les plages :

Plage1 => =INDIRECT("A"&EQUIV($E$2;DECALER($A:$A;;;D))+1&":A"&D)

Plage2 => =INDIRECT("B"&EQUIV($E$2;DECALER($A:$A;;;D))+1&":B"&D)

La formule matricielle :

=SOMME((Plage1<>"")*(Plage1>E2)*SI(Plage2<>"";EQUIV(Plage2;Plage2;0)+EQUIV($E$2;DECALER($A:$A;;;D))=LIGNE(Plage2)))

Fichier joint.

Edit : j'ai du mal avec mes fichiers...

A+

 

[Monique]

Re : Nombre de valeurs sans doublons et celulles vides

Bonjour,

A essayer :
=SOMME((FREQUENCE(SI((Plage1>E$2)*(Plage2<>"");EQUIV(Plage2;Plage2;0));LIGNE(Plage1))>0)*1)

(à valider par ctrl, maj et entrée)

 

[roidurif]

Re : Nombre de valeurs sans doublons et celulles vides

Bonjour,


Merci beaucoup à vous tous JOB75, Tibo, Monique.

 

[roidurif]

Re : Nombre de valeurs sans doublons et celulles vides

Re,

Je suis géné de revenir vers vous, car j'ai du rajouter une 3ème condition à la formule.
Du coup, cela complique les choses.

J'ai essayé d'adapter la formule comme ceci, mais j'ai du louper qq chose

{=SOMME((Plage1<>"")*(Plage1>$F$2))*SI(Plage2<>"";EQUIV(Plage2;Plage2;0)+EQUIV($F$2;DECALER($A:$A;;;D))=LIGNE(Plage2)*(Plage3="910"))}

Je suis navré.

Merci de l'aide

 

[job75]

Re : Nombre de valeurs sans doublons et celulles vides

Bonsoir roidurif,

J'ai bien regardé, mais avec une 3ème condition je ne suis pas parvenu aux résultats corrects.

Ah ces doublons, pas faciles.

A+

 

[roidurif]

Re : Nombre de valeurs sans doublons et celulles vides

Bonsoir,

Merci JOB75, pas evident,

dois-je penser autrement, à créer à une macro pour avoir une 3ème condition?

A bientôt

 

[Monique]

Re : Nombre de valeurs sans doublons et celulles vides

Bonjour,

Regarde si ça te va