Microsoft 365 Nombre de valeurs différentes suivant 2 critères

[raf26]

Bonjour,

Je fais suite à une de mes précédentes demande

https://excel-downloads.com/threads/nombre-de-valeurs-differentes-suivant-2-criteres.20064510/

et ait une pensée pour Hasco 😢, qui avait solutionné mon problème avec cette formule :

=SIERREUR(LIGNES(UNIQUE(FILTRE(T_Ventes[CLIENT];(T_Ventes[MOIS]=$L2)*INDEX(T_Ventes;;EQUIV(O$1;T_Ventes[#En-têtes];0)))));0)

Toujours sur le même modèle, j'aimerais cette fois pouvoir compter le nombre de revendeurs suivant un double critère d'équivalence pomme OU fraise

soit dans mon tableau O$1 (déjà dans la formule EQUIV(O$1😉. OU N$1

Je vous joins un fichier test.

Merci d'avance et bonne soirée

 

[merinos-BernardEtang]

Bonsoir @raf26 ,

voici plusieurs pistes:

 

[raf26]

Bonjour mérinos,

Merci pour ton retour.

Cependant je ne trouve pas la formule de calcul que je recherche

 

[R@chid]

Bonjour @ tous,
en P2 :

=NB(1/FILTRE(D$2:D$13&E$2:E$13;(A$2:A$13=L2)*(D$2:D$13+E$2:E$13)))

@ tirer vers le bas

Cordialement

 

[raf26]

Bonjour R@chid

Merci pour ton retour,

Toutefois, si je duplique durant sur janvier (ligne 2 T_ventes), cela ne devrait pas incrémenter mon résultat sur janvier même si ce revendeur a 2 ordres.

Le résultat devrait être 3 : les revendeurs durant / machin / laurent ont passé des ordres sur les produits recherchés

Je n'ai peut-être pas été assez claire dans ma demande :

Je cherche la dn cumulée pour les pommes ou les fraises pour un mois donné et éventuellement pour l'année compléte

Je joins le fichier test.

Cordialement

 

[R@chid]

Bonjour,
Ce n'est pas encore clair, au lieu de me dire si tu dupliques, merci de dupliquer quelques lignes dans le tableau T_Ventes et les mettre en couleur pour qu'on puisse les voir, après tu donnes le résultat escompté.
Est-ce que la quantité des fruits sera prise en considération ou non ?
Merci de donner un tableau qui représente les différents cas de figure.

Cordialement

 

[raf26]

Re R@chid,

Je cherche le nombre de revendeurs différents (par mois et annuel) qui ont passé des ordres sur les pommes OU les fraises

Pas de calcul de quantités, juste le nombre de revendeurs (colonne nom) différents qui ont des chiffres soit en colonne pommes (colonne D) SOIT en colonne fraises (colonne E)

Si un revendeur s'affiche 3 fois en janvier, le résultat attendu est 1
Exemple dans la capture ci-dessous, durant apparait sur 3 lignes, mais cela fait 1 revendeur

En janvier, j'ai 3 donc revendeurs différents qui ont passé ordre sur pommes ou fraises :

durant (3 fois) + machin + laurent

Avec a formule d'Hasco (voir mon message en ouverture de ce post), le calcul ne se fait que sur 1 produit (formule dans cellule K21 qui me calcule le nombre de revendeurs différents sur les fraises).

Là je complique puisque je souhaite que 2 produits soient pris en compte.

Fichier test en pièce jointe.

Cordialement

 

[R@chid]

Bonjour,
en L21 :

=LET(Rng;ASSEMB.H(B$2:B$19;D$2:E$19);RngFl;FILTRE(Rng;A$2:A$19=H21);RngPm;INDEX(RngFl;;2);RngFr;INDEX(RngFl;;3);SIERREUR(NBVAL(UNIQUE(PRENDRE(FILTRE(RngFl;RngPm+RngFr);;1)))/SIGNE(NB.SI(A$2:A$19;H21));))

@ tirer vers le bas

Cordialement

 

[raf26]

Re R@chid,

Excellent, bravo !

Et pour calculer le nombre de revendeurs différents sur l'année complète, je remplace H21 par quoi ?

 

[R@chid]

Re,
En L21 :

=SIERREUR(NBVAL(UNIQUE(FILTRE(B$2:B$19;(A$2:A$19=H21)*((D$2:D$19<>"")+(E$2:E$19<>"")))))/SIGNE(NB.SI(A$2:A$19;H21));"")

@ tirer vers le bas

Et pour calculer le nombre de revendeurs différents sur l'année complète, je remplace H21 par quoi ?

En L33 :

=NBVAL(UNIQUE(FILTRE(B2:B19;(D2:D19<>"")+(E2:E19<>""))))

Cordialement

 

[raf26]

Bonjour R@chid,

Je te remercie vivement, tu as parfaitement répondu à mon problème.

Un grand merci pour ton temps passé et la qualité de tes réponses.

Bonne journée

Cordialement