XL 2016 Nombre de lignes contenant du texte

[matmac]

Bonjour,
Je cherche une formule permettant de compter le nombre de lignes contenant du texte (peut importe ce qu'il y a d'écrit dans les cellules des lignes concernées et le nombre de cellules où il y a du texte), dans une plage de cellules définie.
La plage en question est C6 à F462, car dans les colonnes A et B il y aussi du texte, mais je ne veux qu'elles soient comptabilisées.
Merci par avance, car je ne vois quelle formule utiliser.

 

[WTF]

Bonjour Matmac.
Est ce que tu as essayé avec la fonction NBVAL() ?
Ca donnerais chez toi si je comprends bien ta demande : =NBVAL(C6:F462)

 

[Jacky67]

Bonjour,
Je cherche une formule permettant de compter le nombre de lignes contenant du texte (peut importe ce qu'il y a d'écrit dans les cellules des lignes concernées et le nombre de cellules où il y a du texte), dans une plage de cellules définie.
La plage en question est C6 à F462, car dans les colonnes A et B il y aussi du texte, mais je ne veux qu'elles soient comptabilisées.
Merci par avance, car je ne vois quelle formule utiliser.

Bonjour à tous
Ceci exclut les nombres
=SOMMEPROD((ESTTEXTE(C6:F462))*1)

 

[job75]

Bonjour matmac,WTF, Jacky67,

Compte le nombre de valeurs textes qui ne sont pas des textes vides "" :

=SOMMEPROD(ESTTEXTE(C6:F462)*(C6:F462<>""))

A+

 

[matmac]

Re,
NBVAL compte le nombre de cellules où il y a du texte.
Or, je voudrais compter non pas le nombre de cellules, mais le nombre de lignes dès qu'il y du texte dans une cellule.
Par exemple, j'ai du texte dans la cellule C7 puis des chiffres dans les cellules D7, E7 et F7 = compte pour 1. Si j'ai du texte en C8, D8, E8 et F8 = compte pour 1 également. Bref dès qu'il y a du texte dans une ou plusieurs cellules des lignes de la plage concernée...
J'ai essayé "SOMMEPROD((ESTTEXTE(C6:F462))*1)", mais j'obtiens un résultat qui ne correspond pas à la réalité.

 

[job75]

Or, je voudrais compter non pas le nombre de cellules, mais le nombre de lignes dès qu'il y du texte dans une cellule.

Utilisez cette formule matricielle, à valider par Ctrl+Maj+Entrée :

=SOMME(SIGNE(FREQUENCE(SI(ESTTEXTE(C6:F462);LIGNE(C6:F462));LIGNE(C6:F462))))

Les textes vides "" sont pris en compte, si on veut les ignorer utiliser :

=SOMME(SIGNE(FREQUENCE(SI(ESTTEXTE(C6:F462)*(C6:F462<>"");LIGNE(C6:F462));LIGNE(C6:F462))))

 

[matmac]

Re,
J'obtiens "#VALEUR!" avec les 2 formules ci-dessus, le problème semble venir de la fonction ESTTEXTE quand je fais évaluer l'erreur...
Je joint le fichier si ça peut aider, le résultat doit apparaitre en i464

 

[job75]

Donc vous ne savez pas encore ce qu'est une formule matricielle.

Clic dans la barre de formule, entrer la formule et valider comme je l'ai dit en appuyant simultanément sur les 3 touches Ctrl Maj Entrée.

Formules validées ainsi en J464 et K464 du fichier joint.

 

[Jocelyn]

Bonjour le Forum,
Bonjour matmac, WTF, Jacky67, job75,

avec cette formule

=SOMMEPROD((ESTERREUR(C6:C462&D6:D462&E6:E462&F6:F462*1))*1)

en I464 le résultat est 129 je ne sais pas si il est bon

Cordialement

 

[matmac]

Autant pour moi, je n'avais pas vu le CTRL+MAJ+Entrée. J'obtiens bien un chiffre, mais qui ne me semble pas représenter la réalité de ce que je dois compter, et d'ailleurs, c'est le même résultat avec les 2 formules, alors qu'il y a bien des cases vides

 

[Jocelyn]

re,

après vérification et pour tomber sur les même résultat que job 75 il faut modifer ma formule de cette façon

=SOMMEPROD((ESTERREUR((C6:C462*100&D6:D462*100&E6:E462*100&F6:F462*100)*1))*1)

cordialement

EDIT je mets le fichier avec la vérif pour démontrer que 203 est bien la bonne valeur

 

[job75]

Mais que racontez-vous donc ?

Il est facile de vérifier que le résultat (203) est correct en entrant en L6 la formule =SIGNE(SOMMEPROD(--ESTTEXTE(C6:F6)))

Tirez-la jusqu'à L462 et faites la somme des valeurs de la colonne L.

Dans C6:F462 il n'y a pas de textes vides "", les cellules vides sont vraiment vides.

Edit : salut Jocelyn

 

[matmac]

Oui. Alors autant pour moi, je n'avais pas compter "manuellement", mais 203 semble être le bon résultat... C'est que je suis étonné par ce chiffre !!!
Si je peux vous embêter encore un peu, il faudrait que je fasse ce calcul en différenciant selon que qu'il y a "F" ou"G" dans la colonne B...
Désolé, mais je ne voulais pas compliquer la formule dès le départ

 

[Jocelyn]

re

avec ma formule pour les filles

=SOMMEPROD((ESTERREUR((C6:C462*100&D6:D462*100&E6:E462*100&F6:F462*100)*1))*(B6:B462="f"))

pour les garçons

=SOMMEPROD((ESTERREUR((C6:C462*100&D6:D462*100&E6:E462*100&F6:F462*100)*1))*(B6:B462="g"))

attention la somme des 2 ne donne pas 203 mais dans la colonne B de la ligne 119 a 153 les g ou f ne sont pas indiqués il y en a peut etre d'autre a toi de vétrifier

Cordialement

 

[matmac]

Ca fonctionne, merci !!! C'est une erreur de ma part l'oubli des lignes 119 à 153...