XL 2019 NB.SI

litchoutsou · 17 Octobre 2024

Bonjour à tous et Merci pour le soutien que vous m'apportez car je suis novice
J'aimerai recevoir une formule qui pourrait m'aidé, je pense que c'est une formule NB.SI ou NBVAL
Je joins le fichier qui parlera mieux que moi.
Encore Merci

mapomme · 21 Octobre 2024

Bonjour à tous ,

litchoutsou à dit:
je rencontre une autre difficulté c'est qu'en début septembre ils sont tous inactif;
serait il possible de trouver une formule ou une Vba qui démarerait le 1er septembre et prendrait en compte les 6 mois à partir du 1er septembre à aujourd'hui?

Une autre formule qui tient compte du mois courant.

Cette formule est paramétrable : En BO2 saisir un nombre. Ce nombre est le seuil désiré de mois consécutifs d'absence ( 6 correspond à un seuil de 6 mois). Juste saisir le nombre -> un format personnalisé l'affiche avec le texte.

La formule en BO3 (à recopier vers le bas) est :

VB:

=SI(ESTNUM(CHERCHE(REPT(0;$BO$2);GAUCHE(JOINDRE.TEXTE("";FAUX;SI(C$2:BJ$2="A...

fanfan38 · 17 Octobre 2024

Bonjour
En BO3 je mettrai

VB:

=SI(NB.SI(AG3:BJ3;"=OUI")=0;"OUI";"NON")

A+ François

wDog66 · 17 Octobre 2024

Bonjour litchoutsou, fanfan38

Pour savoir ça sur 6 mois consécutifs, je pense qu'il faut un petit code VBA (ou une formule Lambda pour ceux qui savent faire)

Sinon si c'est simplement sur 6 mois

VB:

=SI(NB.SI.ENS($C$2:$BN$2;"A Participé ";C3:BN3;"OUI")<6;"INACTIF";"")

A+

job75 · 17 Octobre 2024

Bonsoir à tous,

Je comprends que la période à tester est celle des 6 derniers mois donc en BO3 :

Code:

=REPT("INACTIF";NB.SI(DECALER(BO3;;-5;;-30);"Oui")=0)

A+

litchoutsou · 17 Octobre 2024

Merci fanfan d'avoir répondu si vite, je me suis surement mal exprimé, si je comprend votre formule cela veut dire que le 1er pois commence au mois de mars, mais s'il commence en janvier a juin, ou sur une autre ligne de septembre à fevrier la formule change, n'est-ce pas?

litchoutsou · 17 Octobre 2024

job75 à dit:
Bonsoir à tous,

Je comprends que la période à tester est celle des 6 derniers mois donc en BO3 :

Code:

=REPT("INACTIF";NB.SI(DECALER(BO3;;-5;;-30);"Oui")=0)

A+

non ce n'est pas les 6 derniers mois, mais 6 mois consécutifs, je 1er mois peut très bien commencer en septembre ou en Janvier

litchoutsou · 17 Octobre 2024

la formule de wdog66 est bonne Merci j'ai juste modifier <6 en =6
merci a tout le forum et particulièrement a ce qui m'on repondu aussi vite aujourd'hui.

litchoutsou · 17 Octobre 2024

Excusez moi mais j'ai fais des essais et j'ai constaté une anomalie car elle compte les mois ou il n'y a pas eu de participation dans l'année, s'ils sont égale à 6 elle écrit dans la cellule BU "Inactif", mais c'est pas ce que je désire, j'aimerai quelle inscrive "Inactif" si durant 6 mois consécutifs il n'y a pas eu de participation, et pas sur 6 mois alléatoire dans l'année.
Merci encore de votre soutient.

wDog66 · 18 Octobre 2024

Re,

litchoutsou à dit:
Excusez moi mais j'ai fais des essais et j'ai constaté une anomalie car elle compte les mois ou il n'y a pas eu de participation dans l'année, s'ils sont égale à 6 elle écrit dans la cellule BU "Inactif", mais c'est pas ce que je désire, j'aimerai quelle inscrive "Inactif" si durant 6 mois consécutifs il n'y a pas eu de participation, et pas sur 6 mois alléatoire dans l'année.
Merci encore de votre soutient.

Je pense que vous ne savez pas bien lire ce qu'on vous indique et j'en suis navré
Ma formule était au cas où ce serait simplement sur 6 mois dans l'année

J'ai donc mis à disposition un fichier ".xlsm" qui contient du VBA avec une fonction personnalisée qui permet de compter 6 mois consécutifs, d'où ma phrase....

Pour savoir ça sur 6 mois consécutifs, je pense qu'il faut un petit code VBA

TooFatBoy · 18 Octobre 2024

Bonjour,

Je te propose cette magnifique formule :

Code:

=SI(SIERREUR(CHERCHE("000000";--(C3="oui") & --(H3="oui") & --(M3="oui") & --(R3="oui") & --(W3="oui") & --(AB3="oui") & --(AG3="oui") & --(AL3="oui") & --(AQ3="oui") & --(AV3="oui") & --(BA3="oui") & --(BF3="oui"));0);"INACTIF";"")

Si au lieu de laisser vide quand la personne ne participe pas, tu mettais un "x", ça donnerait ceci :

Code:

=SI(SIERREUR(CHERCHE("xxxxxx";C3&H3&M3&R3&W3&AB3&AG3&AL3&AQ3&AV3&BA3&BF3);0);"INACTIF";"")

litchoutsou · 18 Octobre 2024

wDog66 à dit:
Re,

Je pense que vous ne savez pas bien lire ce qu'on vous indique et j'en suis navré
Ma formule était au cas où ce serait simplement sur 6 mois dans l'année

J'ai donc mis à disposition un fichier ".xlsm" qui contient du VBA avec une fonction personnalisée qui permet de compter 6 mois consécutifs, d'où ma phrase....

Merci j'avais pas fait gafe au fichier, c'est bon ça fonctionne Merci

job75 · 18 Octobre 2024

Bonjour litchoutsou, le forum,

Pas besoin de VBA avec cette formule matricielle en BO3 :

Code:

=REPT("INACTIF";ESTNUM(EQUIV(VRAI;NB.SI(DECALER(A3;;SI(A3:DECALER(BO3;;-31)="Oui";COLONNE(A3:DECALER(BO3;;-31)));;30);"Oui")=0;0)))

à valider par Ctrl+Maj+Entrée et tirer vers le bas.

C'est quand même un peu compliqué.

Edit: petite explication : DECALER(BO3;;-31) évite les références circulaires.

A+

job75 · 19 Octobre 2024

Bonjour litchoutsou, le forum,

Deux compléments.

Fichier(1) il est plus simple de chercher directement la valeur 0 dans la matrice renvoyée par NB.SI :

Code:

=REPT("INACTIF";ESTNUM(EQUIV(0;NB.SI(DECALER(A3;;SI(A3:DECALER(BO3;;-31)="Oui";COLONNE(A3:DECALER(BO3;;-31)));;30);"Oui");0)))

Fichier(2) SOMMEPROD évite la validation matricielle :

Code:

=REPT("INACTIF";SIGNE(SOMMEPROD(--NON(NB.SI(DECALER(A3;;(A3:DECALER(BO3;;-31)="Oui")*COLONNE(A3:DECALER(BO3;;-31));;30);"Oui")))))

Différence entre ces 2 solutions si l'on entre =1/0 en D3 :

- le résultat de la 1ère n'est pas modifié

- le résultat de la 2ème est #DIV/0!

A+

job75 · 20 Octobre 2024

Bonjour litchoutsou, le forum,

On remarquera que la formule en BO3 est évolutive : elle ne dépend pas du nombre de mois.

Il faut aussi rendre évolutives les formules des colonnes Total et Moyenne.

Voyez le fichier joint qui utilise les fonctions SOMME.SI et MOYENNE.SI.

Nota 1 : il y avait des espaces superflus en ligne 2, j'ai remplacé "Cours " par "Cours".

Nota 2 : les valeurs zéro sont masquées en colonnes Total par les formats Standard;; et [h]:mm;;

A+

litchoutsou · 21 Octobre 2024

MERCI à tous ce qui m'ont déja aider Job75 et wdog66 et les autres.
Cette formule
=REPT("INACTIF";SIGNE(SOMMEPROD(--NON(NB.SI(DECALER(A3;;(A3ECALER(BO3;;-31)="Oui")*COLONNE(A3ECALER(BO3;;-31));;30);"Oui")))))
fonctionne très bien, mais je rencontre une autre difficulté c'est qu'en début septembre ils sont tous inactif;
serait il possible de trouver une formule ou une Vba qui démarerait le 1er septembre et prendrait en compte les 6 mois à partir du 1er septembre à aujourd'hui?

XL 2019 NB.SI

litchoutsou

XLDnaute Junior

Pièces jointes

mapomme

fanfan38

XLDnaute Barbatruc

wDog66

XLDnaute Occasionnel

Pièces jointes

job75

XLDnaute Barbatruc

litchoutsou

XLDnaute Junior

litchoutsou

XLDnaute Junior

litchoutsou

XLDnaute Junior

litchoutsou

XLDnaute Junior

wDog66

XLDnaute Occasionnel

TooFatBoy

XLDnaute Barbatruc

litchoutsou

XLDnaute Junior

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

job75

XLDnaute Barbatruc

Pièces jointes

litchoutsou

XLDnaute Junior

Discussions similaires