Moyenne

sangarmatha · 19 Septembre 2014

Dans le tableau ci-joint, je souhaite calculerdans la colonne E, la moyenne des valeurs colonne D par mois (colonne C) sans succés à cette heure....
Le hic étant éventuellement que j'utilise la colonne C pour le mois dans 2 champs avec MOYENNE.ENS.SI
Il y aura autant de moyenne que de fois ou il y a de date même si certaines se répètent.
Merci d'avance de votre aide.

CHALET53 · 19 Septembre 2014

Re : Moyenne

Bonjour,

Peut-être :

=SOMMEPROD((MOIS($C$2:$C$8)=MOIS(C2))*($D$2:$D$8))/SOMMEPROD((MOIS($C$2:$C$8)=MOIS(C2))*($D$2:$D$8<>""))

en E2

sur la même ligne et sans espace entre les guillemets

ROGER2327 · 19 Septembre 2014

Re : Moyenne

Bonjour à tous.

Quatre autres formules :

Si on ne prend pas l'année en compte :

Code:

=SOMME($D$2:$D$8*(MOIS($C$2:$C$8)=MOIS(C2)))/SOMME(--(MOIS($C$2:$C$8)=MOIS(C2)))

Si on prend l'année en compte :

Code:

=SOMME($D$2:$D$8*(ANNEE($C$2:$C$8)=ANNEE(C2))*(MOIS($C$2:$C$8)=MOIS(C2)))/SOMME((ANNEE($C$2:$C$8)=ANNEE(C2))*(MOIS($C$2:$C$8)=MOIS(C2)))

Si on veut afficher les moyennes une seule fois sans prendre l'année en compte :

Code:

=SI(SOMME(--(MOIS($C$2:$C2)=MOIS(C2)))>1;"";SOMME($D$2:$D$8*(MOIS($C$2:$C$8)=MOIS(C2)))/SOMME(--(MOIS($C$2:$C$8)=MOIS(C2))))

Si on veut afficher les moyennes une seule fois en prenant l'année en compte :

Code:

=SI(SOMME((ANNEE($C$2:$C2)=ANNEE(C2))*(MOIS($C$2:$C2)=MOIS(C2)))>1;"";SOMME($D$2:$D$8*(ANNEE($C$2:$C$8)=ANNEE(C2))*(MOIS($C$2:$C$8)=MOIS(C2)))/SOMME((ANNEE($C$2:$C$8)=ANNEE(C2))*(MOIS($C$2:$C$8)=MOIS(C2))))

Toutes ces formules doivent être validées par Ctrl Maj Entrée.

On peut remplacer partout SOMME par SOMMEPROD et valider par Entrée.

Bonne journée.

ℝOGER2327
#7556

Jeudi 12 Absolu 142 (Vide - Vacuation)
3ème Sanculottide An CCXXII, 5,6054h - fête du Travail
2014-W38-5T13:27:11Z

sangarmatha · 19 Septembre 2014

Re : Moyenne

Bravo à tous les 2, efficace et rapide. J'ai testé avec celle de CHALET53 et la première de ROGER2327....parfait.
Merci à vous 2.

Moyenne

sangarmatha

Guest

Pièces jointes

CHALET53

XLDnaute Barbatruc

ROGER2327

XLDnaute Barbatruc

sangarmatha

Guest

Discussions similaires

Moyenne

sangarmatha

Guest

Pièces jointes

CHALET53

XLDnaute Barbatruc

ROGER2327

XLDnaute Barbatruc

sangarmatha

Guest

Discussions similaires

Privacy & Transparency

Privacy & Transparency