Moyenne entre deux dates choisies

[SERHY]

bonjour
Je bloque sur la formule pour le calcul d'une moyenne entre deux dates
Je souhaiterais effectuer une moyenne de chiffres mensuels répertoriés dans un tableau en fonction de critères dates à choisir
Colonne A dates mensuelles (données sur plusieurs années)
Colonne B chiffres

Choix date début
Choix date fin
Moyenne des chiffres entre ces deux dates ?????

merci de votre

 

[ralph45]

Re : Moyenne entre deux dates choisies

Bonjour SERHY et bienvenue sur le forum,

Pas sûr d'avoir compris, mais tente cette formule en E4 :

=SOMMEPROD((A1:A132>=E2)*(A1:A132<E3)*(B1:B132))/JOURS360(E2;E3;VRAI)

A+

 

[JHA]

Re : Moyenne entre deux dates choisies

Bonjour à tous,

A essayer

=SOMMEPROD((($A$1:$A$132>=E2)*($A$1:$A$132<=E3)*(B1:B132))/SOMMEPROD(($A$1:$A$132>=E2)*($A$1:$A$132<=E3)*(B1:B132<>"")))

JHA

 

[R@chid]

Re : Moyenne entre deux dates choisies

Bonjour @ tous,
Peut etre on peut faire plus simple si j'ai bien compris :

=MOYENNE(SI((A1:A132>=E2)*(A1:A132<=E3);B1:B132))

@ valider par Ctrl+Maj+Entree
Amicalement

Edit :
A partir de la version 2007 :

=MOYENNE.SI.ENS(B1:B132;A1:A132;">="&E2;A1:A132;"<="&E3)

@ valider par simple Entree du fait que la formule n'est pas matricielle.

 

[SERHY]

Re : Moyenne entre deux dates choisies

Super merci c parfait
Cordialement

 

[remy8966]

Re : Moyenne entre deux dates choisies

ca devrait faire l'affaire
des si en 3°colonne et moyenne pour le resultat
EN CELLULE C1
=SI(ET(A1>=$E$2;A1<=$E$3);B1;"")
ensuite moyenne de la colonne C EN CELLULE E4
=MOYENNE(C1:C132)

 

[SERHY]

Re : Moyenne entre deux dates choisies

merci à tous pour votre aide
a+

 

[R@chid]

Re : Moyenne entre deux dates choisies

ca devrait faire l'affaire
des si en 3°colonne et moyenne pour le resultat
EN CELLULE C1
=SI(ET(A1>=$E$2;A1<=$E$3);B1;"")
ensuite moyenne de la colonne C EN CELLULE E4
=MOYENNE(C1:C132)

Re,
Et pourquoi une 3eme colonne???
Amicalement

 

[JHA]

Re : Moyenne entre deux dates choisies

Bonjour Rachid_0661

En effet beaucoup plus simple avec

=MOYENNE.SI.ENS(B1:B132;A1:A132;">="&E2;A1:A132;"<="&E3)

mais celle-ci semble ne pas donner le bon résultat si il y a des vides dans la plage choisie

=MOYENNE(SI((A1:A132>=E2)*(A1:A132<=E3);B1:B132))

JHA

 

[R@chid]

Re : Moyenne entre deux dates choisies

Bonjour @ tous,
Bonjour JHA, les 2 formules renvoies le meme resultat meme en cas de cellules vides, parceque la fonction MOYENNE() ne prend pas en compte les cellules vides et les cellules contenant des textes.
Voir PJ.
Amicalement

 

[JHA]

Re : Moyenne entre deux dates choisies

Re,

Pas tout à fait certain.

amicalement,

JHA

 

[R@chid]

Re : Moyenne entre deux dates choisies

Bonjour JHA,
Oui c'est Vrai.
Comme ca c'est bon :

=MOYENNE(SI((A1:A132>=E2)*(A1:A132<=E3)*(B1:B132<>"");B1:B132))

 

[rneptune]

Re : Moyenne entre deux dates choisies

Bonjour,

J'ignore ce qu'il ne va pas avec ma formule. D'ailleurs à chaque fois que je fais une formule avec une date, je me plante 😉

Pourriez-vous m'aider svp ?

=MOYENNE.SI.ENS(T_Data13[Temps Affec vs Réal];T_Data13[Date affect.];">=01/11/2014")

J'aimerais qu'Excel me calcule la moyenne de tous ce qui dépasse le 01/11/2014.

Merci d'avance.

 

[R@chid]

Re : Moyenne entre deux dates choisies

Bonjour,
je viens de voir la question sur un post daté de 2011.
merci de joindre un fichier exemple.


@ + +

 

[rneptune]

Re : Moyenne entre deux dates choisies

Bonjour,
je viens de voir la question sur un post daté de 2011.
merci de joindre un fichier exemple.


@ + +

Bonjour Rachid,

Tu trouveras ci-joint le fichier en question.

Ce que j'aimerais parvenir à faire c'est :

- Calculer une moyenne générale par critère de bordure (entre >=0 et <550)
- Calculer une moyenne de la colonne AN par critère de date de la colonne I (>=01/11/2014)
- Convertir cette moyenne en jour et mois

Tu observeras facilement que j'ai tenté une ou deux formules en AN229, AN232 et AN233, bien sur sans succès.

Merci bcp pour ton aide