XL 2013 Modifications de macro -Incrémentation par BeforeDoubleClick [RESOLU]

[elisium]

Bonjour à tous,

Je souhaiterais modifier une macro qui m'avait été proposée sur le forum lors de ma derniere demande,
mais j'ai beau effectuer des tentatives, ça bloque toujours.

Avec la macro actuelle: lorsque je double-clic en colonne A:
en colonne A = Ça indique la date du jour
en colonne B = Ça incrémente de +1 par rapport à la cellule du dessus

Avec la modification,Je souhaiterais que lorsque je double-clic en colonne A:
en colonne A = Ça incrémente de +1 par rapport à la cellule du dessus
en colonne C = Ça indique la date du jour

je joins un fichier pour exemple

Merci par avance pour votre assistance.
Cdt.

 

[Pierrot93]

Re : Modifications de macro (Incrémentation par BeforeDoubleClick)

Re,

essaye peut être comme suit :

Private Sub Worksheet_BeforeDoubleClick(ByVal Target As Range, Cancel As Boolean)
Dim chaine As String, nb As Integer, vchaine As String, maval As Integer
    If Target.Column = 1 Then
        Target.Offset(0, 2).Value = Date
        Cancel = True
        chaine = Target.Offset(-1)
        If chaine = "" Then MsgBox "Erreur": Exit Sub
        nb = InStr(1, chaine, "-")
        vchaine = Left(chaine, nb)
        maval = Right(chaine, Len(chaine) - nb)
        Target = vchaine & CInt(maval) + 1
    End If
End Sub

A noter tous les codes sont déjà dans ta macro...

bon après midi
@+

 

[elisium]

Re : Modifications de macro (Incrémentation par BeforeDoubleClick)

C'est vrai, mais ne comprenant pas toutes les lignes de codes, j'avais du mal à effectuer les bonnes modifs.
Ton aide va me permettre de comparer les 2 afin de comprendre par moi même les changements.

Je te remercie pour ton aide et j'aurais une dernière question:

Je me rend compte que la ligne de code

If chaine = "" Then MsgBox "Erreur": Exit Sub

bloque l'incrémentation dès qu'il y a une ligne vide.
Serait-il possible d’insérer un code permettant de continuer l’incrémentation à la ligne du dessous malgré une ligne vide, ou bien est-ce compliqué ?

encore merci.

Cdt.

J-L

 

[ROGER2327]

Re : Modifications de macro (Incrémentation par BeforeDoubleClick)

Bonjour elisium, Pierrot93.

Un autre essai :​

Private Sub Worksheet_BeforeDoubleClick(ByVal Cible As Range, Contremander As Boolean)
Dim i&, p$, n$, v()
  With Cible
    If .Column = 1 Then
      For i = 1 To .Row - 1
        p = .Offset(-i).Value
        If p Like "*-[0-9]*" Then Exit For
      Next
      If i < .Row Then
        n = Mid$(p, InStrRev(p, "-") + 1, 99)
        If IsNumeric(n) Then
          v = .Resize(1, 3).Value
          v(1, 1) = Split(p, "-")(0) & "-" & 1 + n
          v(1, 3) = Date
          .Resize(1, 3).Value = v
        End If
      End If
      Contremander = True
    End If
  End With
End Sub

Bonne soirée.


ℝOGER2327
#8014

Dimanche 15 Phalle 142 (Mort de Dionysos, surhomme - fête Suprême Tierce)
8 Fructidor An CCXXIII, 6,4517h - apocyn
2015-W35-2T15:29:03Z

 

[elisium]

Re : Modifications de macro -Incrémentation par BeforeDoubleClick [RESOLU]

Génial,

Je me rend compte en regardant ton second code qu'il est possible d'arriver au même résultat mais par des codes complètement différents. (Ça n'arrange pas ma compréhension, tout ça !!!!!)

Encore merci pour toute ton aide, et bonne soirée également.

Je transforme mon post en RÉSOLU.

Cdt.

JL