MFC

[Caninge]

Bonjour à tous

Comment peut-on faire pour éviter de faire à chaque fois une MFC ligne par
par ligne.

Etant donné qu'il y a 12 lignes et que je veux faire apparaitre le nombre mini et maxi de chaque ligne.

cela me demande beaucoup de travail.

Existe t-il une astuce ou doit-on utiliser une macro.

Merci et bon dimanche

Caninge

 

[Monique]

Bonjour,

En sélectionnant le tableau à partir de D7,
Cond 1 :
=D7=MAX($D7:$I7)
Cond 2 :
=D7=MIN($D7:$I7)

 

[Caninge]

Bonjour Monique

Merci c'est parfait.

C'est quand même plus rapide !!

A bientôt

Caninge

 

[Caninge]

Rebonjour Monique

Je n'arrive pas à faire fonctionner la MFC.

je pense que cela vient des formules.

Tu devrais pouvoir m'arranger ça !

Caninge

 

[Monique]

Re,

Ta MFC est en place
(comme c'est une colonne sur 3, il faut utiliser la fonction Mod(Colonne();3)

Je crois que tu peux simplifier tes formules (je n'ai pas essayé, tu as des liaisons)

 

[Monique]

Re,

Non, j'ai tout faux, et la MEFC et les formules proposées.
Dans le classeur joint, tu as des plages nommées et des données bidon,
je crois que ça fonctionne.

 

[Caninge]

Bonjour Monique

je viens de regarder le fichier proposé.
le tableau ressemble un peu au drapeau français n'est-ce pas ?

Oui au fait j'ai remarqué sur les lignes Novembre et décembre que les nombres MINI n'étaient pas affichés !!!

J'essaie bien de modifier la formule conditionnelle mais.....

Merci

 

[Monique]

Bonjour,

Il y a une erreur dans la formule du format conditionnel, un 8 à la place d'un 5 sur la 1ère ligne, même décalage sur les autres.
En sélectionnant à partir de G5, tu remplaces R8 par R5
Condition 1 :
=ET(G5>0;MOD(COLONNE();3)=1;G5=MAX(SI(MOD(COLONNE($G5:$R5);3)=1;SI($G5:$R5>0;$G5:$R5))))
Condition 2 :
=ET(G5>0;MOD(COLONNE();3)=1;G5=MIN(SI(MOD(COLONNE($G5:$R5);3)=1;SI($G5:$R5>0;$G5:$R5))))

 

[Caninge]

Bonjour Monique

J'ai changé les formules

Ca à l'air de marcher.

Ca roule aussi bien que les R5 et les R8 (Lol)

Merci

 

[Caninge]

Bonjour Monique

Me revoici

J'ai voulu bidouiller le fichier pour afficher une autre colonne nommé"Clients"
que je voudrais insérer entre les autres colonnes.
A la place de Caisses j'ai mis Clients et pourtant ça ne marche pas

Pourquoi !

merci

 

[Monique]

Bonjour,

Les 2 plages nommées "Clients2002" et "Clients2003" n'avaient pas la même longueur que les autres.
Sinon, si tu insères une colonne en 2002 et en 2003, il faut aussi en insérer une en 2004 et en 2005,
parce que la formule de la MFC se base sur Mod(Colonne();4),
donc le reste de la division par 4 du n° de colonne.
La formule ne prend en compte qu'1 colonne sur 4, celles dont Mod(etc) = 3 (G K O S)

 

[Caninge]

Bonjour Monique

Je ne suis vraiment pas malin, je tourne en rond depuis 1 heure pour essayer de faire fonctionner cette MEFC.

Alors que la solution est facile .

Merci Monique.

 

[Monique]

Bonjour,

Tu as enlevé toutes les cellules auxquelles les formules font référence !
En mettant des données bidon dans les colonnes FGH, JKL, NOP, RST, ces formules de MEFC fonctionnent :
=ET(F6>0;MOD(COLONNE();4)=2;F6=MAX(SI(MOD(COLONNE($F6:$U6);4)=2;SI($F6:$U6>0;$F6:$U6))))
=ET(F6>0;MOD(COLONNE();4)=2;F6=MIN(SI(MOD(COLONNE($F6:$U6);4)=2;SI($F6:$U6>0;$F6:$U6))))

MOD(COLONNE();4)=2 pour que la formule ne prenne en compte que les colonnes F, J, N et R
Colonne F = Colonne n° 6
MOD(6;4)=2
Colonne J = Colonne n° 10
MOD(10;4)=2
etc

 

[Caninge]

Bonjour Monique

J'ai compris et ça marche. Par contre il y a un chiffre que je ne comprends pas sa signification.

Pourquoi 2 à la place de 1.


ET(F6>0;MOD(COLONNE();4)=2

Merci Monique.

 

[Monique]

Bonjour,

Parce que ta MFC ne se fait que dans les colonnes F, J, N et R, toutes les 4 colonnes.
Colonne F = Colonne n° 6
Colonne J = Colonne n° 10
Colonne N = Colonne n° 14
Colonne R = Colonne n° 18
Elles ont toutes un point commun :
le reste de la division par 4 de leur n° est égal à 2
Le reste en question, on l'obtient par =MOD ( nombre ; diviseur)

=MOD(COLONNE(A1);4) = 1 Idem : =MOD(1;4) = 1
=MOD(COLONNE(B1);4) = 2 Idem : =MOD(2;4) = 2
=MOD(COLONNE(C1);4) = 3 Idem : =MOD(3;4) = 3
=MOD(COLONNE(D1);4) = 0 Idem : =MOD(4;4) = 0
=MOD(COLONNE(E1);4) = 1 Idem : =MOD(5;4) = 1
=MOD(COLONNE(F1);4) = 2 Idem : =MOD(6;4) = 2