XL 2016 Mettre le mois actif en clignotement

Créer une discussion
Répondre

Boostez vos compétences Excel avec notre communauté !

Rejoignez Excel Downloads, le rendez-vous des passionnés où l'entraide fait la force. Apprenez, échangez, progressez – et tout ça gratuitement ! 👉 Inscrivez-vous maintenant !

S'inscrire
Dennnisss

Dennnisss

XLDnaute Occasionnel
Bonjour j'ai modifier mon user au minimum , lorsque j'entre mes données de vélo j'aimerais que le mois actif dans ce cas ici c'est avril , j'ai mit 12 la valeur par defaut j'ai mit a intérieur de mon user un petit test trouver sur le site mais vue que c'est une boucle il tourne en rond , alors besoin de votre aide svp ,, mon besoin est que le mois clignote selon la date(mois) ou je suis rendu durant mon année ,,, merci de votre aide
 

Pièces jointes

Trier par date Trier par votes
Salut Dennnisss,

Si j'ai bien compris, voici le fichier avec le code qu'il faut 😉
Dans l'USF
VB: 
Private Sub UserForm_Activate()
  Dim IndLbl As Integer
  IndLbl = 325 + Month(Date)
  Call FaireClignoter(Me.Controls("Label" & IndLbl), 3) ' Clignoter pendant 3 secondes
End Sub

Dans le module
Code: 
Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As LongPtr)

Sub FaireClignoter(Lb As MSForms.Label, dureeEnSecondes As Integer)
  Dim tempsDebut As Single
  Dim clignotes As Boolean
  clignotes = False
  tempsDebut = Timer
 
  Do While Timer < tempsDebut + dureeEnSecondes
    If clignotes Then
      Lb.Visible = True
    Else
      Lb.Visible = False
    End If
    clignotes = Not clignotes
    DoEvents
    Sleep 300                                    ' Delai en millisecondes (300 ms)
  Loop
  Lb.Visible = True                              ' S'assurer que le Label reste visible à la fin
End Sub

A+
 

Pièces jointes

Vote positif 0 Vote négatif
Bonjour, grillé sur le fil : à rajouter à l'userform ( comme @Xl60PassionFr )
VB: 
Option Compare Text
Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub UserForm_Activate()
Dim Ctl As Control, N As Integer
    For Each Ctl In Me.Controls
        If MonthName(Month(Now)) Like Ctl.Caption & "*" Then
            For N = 1 To 10 ' nombre de clignotements
                Ctl.Visible = Not Ctl.Visible
                Me.Repaint ' C'est l'userform entier qui est reconstruit sinon il n'est pas affiché
                Sleep 600  ' durée d'affichage en milisecondes
            Next
            Ctl.Visible = True
            Exit For
        End If
    Next
End Sub
 
Dernière édition:
Vote positif 0 Vote négatif
Xl60PassionFr à dit:
Salut Dennnisss,

Si j'ai bien compris, voici le fichier avec le code qu'il faut 😉
Dans l'USF
VB: 
Private Sub UserForm_Activate()
  Dim IndLbl As Integer
  IndLbl = 325 + Month(Date)
  Call FaireClignoter(Me.Controls("Label" & IndLbl), 3) ' Clignoter pendant 3 secondes
End Sub

Dans le module
Code: 
Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As LongPtr)

Sub FaireClignoter(Lb As MSForms.Label, dureeEnSecondes As Integer)
  Dim tempsDebut As Single
  Dim clignotes As Boolean
  clignotes = False
  tempsDebut = Timer
 
  Do While Timer < tempsDebut + dureeEnSecondes
    If clignotes Then
      Lb.Visible = True
    Else
      Lb.Visible = False
    End If
    clignotes = Not clignotes
    DoEvents
    Sleep 300                                    ' Delai en millisecondes (300 ms)
  Loop
  Lb.Visible = True                              ' S'assurer que le Label reste visible à la fin
End Sub

A+
Cliquez pour agrandir...
Bonjour Mrs X160 passion Fr ,,,, merci pour ton aide oui sa va très bien moi j'ai juste modifier la vitesse des micros seconde a 600 et le nombre de clignotement a 20 environ ,,,, juste comme ca voici le code dont je me pose la question ( Call FaireClignoter(Me.Controls("Label" & IndLbl), 20),,,, si je veut qu'il clignote sans arrêt que dois-je mettre a la place de 20 cligno ,,,,, merci pour ton code et bonne journée a toi dennnisss
 
Vote positif 0 Vote négatif
Bonsoir.
Si ça doit clignoter indéfiniment, pour ne pas empêcher l'UserForm de fonctionner, utilisez un objet Rythmeur du classeur joint. Initialisez le dans Sub UserForm_Initialyze et lancez le dans la Sub Userform_Activate. Implantez dans le projet VBA de votre classeur le module de classe Rythmeur et aussi le module standard de service interne XRythmeur.
 

Pièces jointes

Vote positif 0 Vote négatif
Notez que pour faire clignoter 2 fois plus rapidement le label du nom de mois en cours vous pouvez écrire la Sub UserForm_Activate comme ça :
VB: 
Private Sub UserForm_Activate()
   Set CTrl = Me("Label" & Month(Date) + 325)
   RythClign.Lancer 4
   End Sub
 
Vote positif 0 Vote négatif
fanch55 à dit:
Bonjour, grillé sur le fil : à rajouter à l'userform ( comme @Xl60PassionFr )
VB: 
Option Compare Text
Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub UserForm_Activate()
Dim Ctl As Control, N As Integer
    For Each Ctl In Me.Controls
        If MonthName(Month(Now)) Like Ctl.Caption & "*" Then
            For N = 1 To 10 ' nombre de clignotements
                Ctl.Visible = Not Ctl.Visible
                Me.Repaint ' C'est l'userform entier qui est reconstruit sinon il n'est pas affiché
                Sleep 600  ' durée d'affichage en milisecondes
            Next
            Ctl.Visible = True
            Exit For
        End If
    Next
End Sub
Cliquez pour agrandir...

fanch55 à dit:
Bonjour, grillé sur le fil : à rajouter à l'userform ( comme @Xl60PassionFr )
VB: 
Option Compare Text
Private Declare PtrSafe Sub Sleep Lib "kernel32" (ByVal dwMilliseconds As Long)
Private Sub UserForm_Activate()
Dim Ctl As Control, N As Integer
    For Each Ctl In Me.Controls
        If MonthName(Month(Now)) Like Ctl.Caption & "*" Then
            For N = 1 To 10 ' nombre de clignotements
                Ctl.Visible = Not Ctl.Visible
                Me.Repaint ' C'est l'userform entier qui est reconstruit sinon il n'est pas affiché
                Sleep 600  ' durée d'affichage en milisecondes
            Next
            Ctl.Visible = True
            Exit For
        End If
    Next
End Sub
Cliquez pour agrandir...
Merci a toi fanch55 dossier résolu merci beaucoup de votre aide elle est très apprécié bonne soirée
 
Vote positif 0 Vote négatif
Dennnisss à dit:
Merci a toi fanch55 dossier résolu merci beaucoup de votre aide elle est très apprécié bonne soirée
Cliquez pour agrandir...
Salut,
A noter qu'avec le code de fanch55 :
1 - On ne peut pas fermer le formulaire pendant le clignotement.
2 - Il repeint tout le formulaire ce qui peut faire un effet de "scintillement" sur celui-ci
Voici un code qui :
1 - Ne repeint que le mois qui clignote
2 - Permet de fermer le formulaire pendant le clignotement.
VB: 
Private Sub UserForm_Activate()
Dim Ctl As Control, N As Integer
    For Each Ctl In Me.Controls
        If MonthName(Month(Now)) Like Ctl.Caption & "*" Then
            For N = 1 To 10 ' nombre de clignotements
                Ctl.Visible = Not Ctl.Visible
                DoEvents
                Sleep 600  ' durée d'affichage en milisecondes
            Next
            Ctl.Visible = True
            Exit For
        End If
    Next
End Sub
J'ai remplacé le Me.repaint par un DoEvents. Celui-ci a deux actions :
1 - Il permet de prendre en compte les actions sur le formulaire dans la boucle.
2 - Il repeint le contrôle mois car la propriété visible de celui-ci a été modifiée donc génére un rafraichissement.

Le code de Dranreb fonctionne bien aussi.

Nullosse
 
Vote positif 0 Vote négatif
Bonjour le forum,

Pas besoin d'une API Windows ou d'un Rythmeur, de simples boucles d'attente sur le Timer suffisent :
VB: 
Private Sub CommandButton1_Click()
Dim delai, c As Control, dat, t
delai = 0.5 'délai d'attente en seconde
With Ouverture
    .Show 0 'non modal
    For Each c In .Controls
        If c.Name Like "Label*" And Val(c) = 0 Then _
            dat = "1/" & c: If Month(dat) = Month(Date) Then Exit For
    Next c
End With
While UserForms.Count 'tant que l'UserForm est ouvert
    If UserForms.Count Then c.Visible = False
    t = Timer + delai
    While Timer < t And t < 86400: DoEvents: Wend 'attente
    If UserForms.Count Then c.Visible = True
    t = Timer + delai
    While Timer < t And t < 86400: DoEvents: Wend 'attente
Wend
End Sub
Nota : j'ai ajouté les accents sur les Labels de Fév, Août, Déc.

A+
 

Pièces jointes

Dernière édition:
Vote positif 0 Vote négatif
bonjour,
dysorthographie

Autres Publié dans la discussion 'Séquenceur (Timer) dans autre instance d'Excel'

Bonjour,
Perso j'utilise ça
Code: 
VERSION 1.0 CLASS
BEGIN
  MultiUse = -1  'True
END
Attribute VB_Name = "MyTimer"
Attribute VB_GlobalNameSpace = False
Attribute VB_Creatable = False
Attribute VB_PredeclaredId = False
Attribute VB_Exposed = False
Option Explicit

#If VBA7 Then
    Private Declare PtrSafe Function SetTimer Lib "user32" (ByVal HWnd As LongPtr, ByVal nIDEvent As LongPtr, _
        ByVal uElapse As Long, ByVal lpTimerFunc As LongPtr) As LongPtr
    Private Declare PtrSafe Function KillTimer Lib "user32" (ByVal HWnd As LongPtr, _
        ByVal nIDEvent As LongPtr) As LongPtr...
  • J'aime
 
Vote positif 0 Vote négatif
job75 à dit:
Bonjour le forum,

Pas besoin d'une API Windows ou d'un Rythmeur, de simples boucles d'attente sur le Timer suffisent :
Code: 
Do
    c.Visible = False
    t = Timer + delai
    While Timer < t And t < 86400: DoEvents: Wend 'attente
    c.Visible = True
    t = Timer + delai
    While Timer < t And t < 86400: DoEvents: Wend 'attente
Loop
Cliquez pour agrandir...
Salut,
c'est bien gentil de ne pas utiliser les API, mais tes boucles sont énergivores. Sur ma machine quand le clignotement est actif, Excel consomme 8% de CPU ce qui correspond à 80% sur un Core du CPU. Dans la version fanch55 avec le sleep , Excel est entre 0 et 1% pendant le clignotement.
Nullosse
 
Vote positif 0 Vote négatif
Rejoins nos membres "Supporter XLD" et booste ton expérience Excel !
- Navigue sans publicité
- Accède à Cléa, notre assistante IA experte Excel... et pas que...
- Profite de fonctionnalités exclusives
Ton soutien permet à Excel Downloads de rester 100% gratuit et de continuer à rassembler les passionnés d'Excel.
Je deviens Supporter XLD

Discussions similaires

Dennnisss
  • Question Question
Microsoft 365 Comment additionner le nombre de mois identique
Réponses
7
Affichages
231
Dennnisss
Dennnisss
O
  • Résolu(e)
XL 2013 Formule qui permet d'extraire le mois une date au format en jour/mois/année
Réponses
4
Affichages
511
onyirimba
O
AIXELS
  • Résolu(e)
XL 2021 Colorer le mois en cours et le TextBox correspondant
Réponses
7
Affichages
544
AIXELS
AIXELS
M
  • Question Question
Microsoft 365 compter le nombre de mois identiques
Réponses
7
Affichages
559
Efgé
Efgé
A
  • Question Question
XL 2021 Calculer le prorata d'un objectif en fonction de l'arrivée ou du départ du salarié
Réponses
4
Affichages
404
job75
job75
E
  • Question Question
Microsoft 365 Problème de conversion des mois en périodes dans Excel avec VBA
Réponses
2
Affichages
811
RyuAutodidacte
RyuAutodidacte
E
  • Résolu(e)
Microsoft 365 Remplacer données dans TS
Réponses
9
Affichages
606
TooFatBoy
TooFatBoy
Jelose
  • Question Question
XL 2021 Dupliquer un tableau sur différents onglets pour un mois donné
Réponses
2
Affichages
735
Jelose
Jelose
chaelie2015
  • Question Question
XL 2013 (RESOLU) Automatisation d'affichage d'images en fonction du mois
Réponses
9
Affichages
995
chaelie2015
chaelie2015
D
  • Résolu(e)
Power Query [DAX] Calculer le nombre de ligne en fonction du nombre de valeurs sélectionnées dans le dashboard
Réponses
3
Affichages
786
Dam71
D
M
  • Question Question
XL 2010 Compter le nombre de mois en fonction de plusieur critéres
Réponses
2
Affichages
590
Marylgb
M
N
  • Question Question
XL 2019 Mettre en gras éléments du graphique avec macro
Réponses
4
Affichages
896
Nasseuz
N
R
  • Résolu(e)
XL 2019 Equivalent de sommeprod
Réponses
13
Affichages
913
Rabeto
R
N
  • Question Question
Autres planning automatisé aide connexion tableaux semaines mois
Réponses
5
Affichages
867
fanfan38
fanfan38
F
  • Résolu(e)
Autres Date automatique en fonction du mois et de l'année sans dimanche
Réponses
6
Affichages
878
Fitgy
F
I
  • Question Question
Microsoft 365 Choix du répertoire d'enregistrement en fonction du nom du fichier
Réponses
3
Affichages
882
ivan27
I
T
  • Résolu(e)
Microsoft 365 Calendriers et planning automatiques avec Excel (modification des plages selon le salarié, le mois et l'année)
Réponses
8
Affichages
1 K
nassimaaad
N
Eleutheros
  • Question Question
XL 2016 Afficher les lignes du mois courant sauf avec critères "En cours" macro VBA excel
Réponses
3
Affichages
816
Wayki
Wayki
T
  • Question Question
Microsoft 365 Bouton automatiser sur le choix du mois pour affichage en haut de la page
2
Réponses
15
Affichages
1 K
TAL
T
D
  • Résolu(e)
Microsoft 365 Macro choix du mois pour MàJ TCD
Réponses
8
Affichages
1 K
chris
chris
Retour