masquer ligne si

[eastwick]

Bonjour à toutes et tous,

J'aimerais masquer les lignes d'un tableau dont les cellules de la colonne I porte la mention "x". Cette mention est le résultat d'une formule. Il s'agirait que cela se fasse automatiquement. Attention, j'ai déjà un code dans cette feuille.

Je vous remercie.

 

[job75]

Re : masquer ligne si

Bonjour eastwick,

Deux macros possibles dans le code de la feuille.

1) Dans tous les cas de figure :

Private Sub Worksheet_Calculate()
Dim r As Range
Set r = Intersect([I:I], Me.UsedRange)
If Not r Is Nothing Then
  Application.EnableEvents = False
  For Each r In r
    If LCase(r) = "x" Then r.EntireRow.Hidden = True
  Next
  Application.EnableEvents = True
End If
End Sub

Peut prendre du temps s'il y a beaucoup de lignes.

2) Si la valeur "x" est déterminée uniquement par des cellules de la même ligne :

Private Sub Worksheet_Change(ByVal Target As Range)
Dim r As Range
Set r = Intersect(Target, Me.UsedRange)
If Not r Is Nothing Then
  For Each r In r
    If LCase(r(1, 10 - r.Column)) = "x" Then r.EntireRow.Hidden = True
  Next
End If
End Sub

Evidemment bien plus rapide.

A+

 

[eastwick]

Re : masquer ligne si

Merci beaucoup. j'ai du prendre la 1ère option, ça rame un peu malgré un nombre peu élevé de lignes, mais bon, ça me va !!!!

 

[job75]

Re : masquer ligne si

Re,

Merci de nous expliquer pourquoi vous prenez la 1ère et pas la 2ème.

A+

 

[job75]

Re : masquer ligne si

Re,

ça rame un peu malgré un nombre peu élevé de lignes(...)

Vous avez probablement des formules utilisant des fonctions volatiles comme DECALER.

Alors utilisez cette macro :

Private Sub Worksheet_Calculate()
Dim r As Range
Set r = Intersect([I:I], Me.UsedRange)
If Not r Is Nothing Then
  Application.EnableEvents = False
  Application.Calculation = xlCalculationManual
  For Each r In r
    If LCase(r) = "x" Then _
      If Not r.EntireRow.Hidden Then r.EntireRow.Hidden = True
  Next
  Application.Calculation = xlCalculationAutomatic
  Application.EnableEvents = True
End If
End Sub

A+

 

[eastwick]

Re : masquer ligne si

Merci, ça roule mieux !!!!

 

[eastwick]

Re : masquer ligne si

Néanmoins, les lignes non marquées d'un x n'apparaissent pas automatiquement... Peut-on y remédier ? Merci !

 

[job75]

Re : masquer ligne si

Re,

Ah oui bien sûr, utilisez donc :

Private Sub Worksheet_Calculate()
Dim r As Range
Set r = Intersect([I:I], Me.UsedRange)
If Not r Is Nothing Then
  Application.EnableEvents = False
  Application.Calculation = xlCalculationManual
  For Each r In r
    r.EntireRow.Hidden = LCase(r) = "x"
  Next
  Application.Calculation = xlCalculationAutomatic
  Application.EnableEvents = True
End If
End Sub

Bonne nuit.

 

[eastwick]

Re : masquer ligne si

Merci beaucoup... !