Macro suppression de ligne avec un 0

L

laetitia90

XLDnaute Barbatruc

• 28 Mai 2011

• #2

Re : Macro suppression de ligne avec un 0

bonjour David066
suppose les 2 premieres colonnes a adapter

Code:

Sub es()
Dim i As Long
Application.ScreenUpdating = False
For i = Cells(Rows.Count, 1).End(xlUp).Row To 1 Step -1
If Cells(i, 1) = 0 And Cells(i, 2) = 0 Then Rows(i).Delete
Next i
End Sub

 

Vote positif 0 Vote négatif

D

David066

Guest

• 28 Mai 2011

• #3

Re : Macro suppression de ligne avec un 0

Merci je vais l'essayer de suite.

 

Vote positif 0 Vote négatif

D

David066

Guest

• 28 Mai 2011

• #4

Re : Macro suppression de ligne avec un 0

J'imagine que je dois apparaitre pour un nul 🙂
Peux-tu me dire comment adapter la macro a mon
fichier qui présente deux colonnes A et B allant de
la ligne 2 jusqu'à la ligne 198001.
Désolé...

 

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 28 Mai 2011

• #5

Re : Macro suppression de ligne avec un 0

Bonjour le fil, David066, laetitia90 😉


Une autre façon en passant par le filtre automatique
(qui a l'avantage d'éviter de boucler)

VB:

Sub Macro1()
Dim r As Range, rf As Range
With ActiveSheet
    Set r = _
        .[A1].CurrentRegion: r.AutoFilter 1, "0": r.AutoFilter 2, "0"
    
    Set rf = _
        .[_FilterDataBase]: rf.Offset(1, 0).Resize(rf.Rows.Count - 1).SpecialCells(12).Delete Shift:=xlUp
    .AutoFilterMode = False
End With
End Sub

PS: code fonctionnel dans les conditions de test décrites ci-dessous:
Les colonnes A et B seulement contiennent des données et il n'y a pas de cellules vides dans ces colonnes.

 

Dernière édition: 28 Mai 2011

Vote positif 0 Vote négatif

D

David066

Guest

• 28 Mai 2011

• #6

Re : Macro suppression de ligne avec un 0

Staple1600 t'a macro fonctionne à merveille 🙂.
Merci à tous les deux vous pour vos conseils et votre
rapidité de réponse.

Salutations

 

Vote positif 0 Vote négatif

L

laetitia90

XLDnaute Barbatruc

• 28 Mai 2011

• #7

Re : Macro suppression de ligne avec un 0

re, bonjour l'ami Staple🙂🙂🙂🙂🙂🙂🙂🙂🙂

j'ai pas le reflexe d'utiliser les filtres bien plus simple & plus rapide bien vu😱😱
peut tu me dire a quoi correspond le 12😕😕

Code:

        .[_FilterDataBase]: rf.Offset(1, 0).Resize(rf.Rows.Count - 1).SpecialCells(12).Delete Shift:=xlUp

 

Vote positif 0 Vote négatif

Staple1600

XLDnaute Barbatruc

• 28 Mai 2011

• #8

Re : Macro suppression de ligne avec un 0

Re

laetitia90
Pour répondre à ta question 😉
(Extrait de l'aide VBA*)

Const xlCellTypeVisible = 12
Membre de Excel.XlCellType

Cliquez pour agrandir...

*: accessible par ALT+F11+F1

(Tous les jours, je caresse cette touche au point que l'inscription est effacée 😉 )

 

Dernière édition: 28 Mai 2011

Vote positif 0 Vote négatif

L

laetitia90

XLDnaute Barbatruc

• 28 Mai 2011

• #9

Re : Macro suppression de ligne avec un 0

re,
merci & passe une bonne journée🙂🙂
a+ leti

 

Vote positif 0 Vote négatif

D

david84

XLDnaute Barbatruc

• 28 Mai 2011

• #10

Re : Macro suppression de ligne avec un 0

Bonjour tout le monde,
une autre possibilité en passant par des tableaux VBA (code moins compact mais je pense que la vitesse d'exécution est également rapide) :

Code:

Sub test2()
Dim tabl, DerLigne&, Plage, Nb&, i&, j&
With ActiveSheet
    Set Plage = .Range("A1:B" & Range("B" & Rows.Count).End(xlUp).Row)
    tabl = Plage.Value
    j = 0
        For i = 1 To Plage.Rows.Count
            If tabl(i, 1) + tabl(i, 2) <> 0 Then
                Dim tabl2()
                ReDim Preserve tabl2(Plage.Rows.Count, Plage.Columns.Count - 1)
                tabl2(j, 0) = tabl(i, 1)
                tabl2(j, 1) = tabl(i, 2)
                j = j + 1
            End If
        Next i
    .[A1].Resize(Plage.Rows.Count, Plage.Columns.Count) = tabl2
End With
End Sub

A+

 

Dernière édition: 28 Mai 2011

Vote positif 0 Vote négatif

L

laetitia90

XLDnaute Barbatruc

• 29 Mai 2011

• #11

Re : Macro suppression de ligne avec un 0

re , attention david84 si donnees sur les autres colonnes dans ce cas la tu supprime seulement sur colonne a & b

 

Vote positif 0 Vote négatif

D

david84

XLDnaute Barbatruc

• 29 Mai 2011

• #12

Re : Macro suppression de ligne avec un 0

Re

attention david84 si donnees sur les autres colonnes dans ce cas la tu supprime seulement sur colonne a & b

Cliquez pour agrandir...

Oui mais là ce n'est qu'un exemple à adapter à la configuration du fichier réel.
Je n'ai fait que colle aux indications fournies :

Peux-tu me dire comment adapter la macro a mon
fichier qui présente deux colonnes A et B allant de
la ligne 2 jusqu'à la ligne 198001.

Cliquez pour agrandir...

A moins que tu veuilles me faire comprendre autre chose...
A+ Laetitia

 

Vote positif 0 Vote négatif

L

laetitia90

XLDnaute Barbatruc

• 29 Mai 2011

• #13

Re : Macro suppression de ligne avec un 0

re,
milles excuses DAVID j'etais reste bêtement sur le titre

macro suppression de lignes

Cliquez pour agrandir...

il precise qu'il a seulement 2 colonnes
je me sens un peu idiote🙁🙁
j'espére que tu m'en voudras pas trop je vais me cacher

a+ leti

 

Vote positif 0 Vote négatif

D

david84

XLDnaute Barbatruc

• 29 Mai 2011

• #14

Re : Macro suppression de ligne avec un 0

Re
Pas de soucis 🙂, j'aurais pu louper un épisode. Continue d'être vigilante sur les propositions que je peux faire, cela me rend service😎.
A+

 

Vote positif 0 Vote négatif