macro : renommer fichier .xlsm, sans en connaitre le nom, et avec la date du jour

[flantafafouille]

Bonjour,

J'ai un fichier .xlsm qui se trouve dans le dossier F:\AAA\MAJ date.xlsm
C'est le seul fichier .xlsm se trouvant dans ce dossier mais il peut avoir un nom inconnu (en réalité, fonction de dates précédentes)

J'aimerai par une macro VBA le renommer (sans le sauver nécessairement) en tant que : MAJ dateDuJour.xlsm (donc dans ce même dossier)

Idéalement, il n'y aurait pas de nouvelle copie distincte du fichier, il serait juste renommer.

Pourriez-vous svp me fournir le code de ma demande ? Merci beaucoup

 

[Herdet]

Re : macro : renommer fichier .xlsm, sans en connaitre le nom, et avec la date du jou

Bonsoir
Sub Move_Rename_One_File()
'renommer un fichier
Name "F:\AAA\MAJ date.xlsm" As "MAJ " & Format(Now, "dd-mm-yyyy") & ".xlsm"
End Sub

Cordialement
Robert

 

[Herdet]

Re : macro : renommer fichier .xlsm, sans en connaitre le nom, et avec la date du jou

si l'on ne connait pas le nom du fichier unique

Sub Move_Rename_One_File()
'rennomer un fichier
rep = "F:\AAA\"
fic = Dir(rep & "*.xlsm")
Name rep & fic As rep & "MAJ " & Format(Now, "dd-mm-yyyy") & ".xlsm"
End Sub

 

[flantafafouille]

Re : macro : renommer fichier .xlsm, sans en connaitre le nom, et avec la date du jou

Bonsoir et merci pour votre accueil.

J'avais arpenté un chemin quasi identique à celui suggéré. Toujours un message d'erreur.
En réalité, j'ai mal formulé mon objectif, qui consiste à "renommer" le fichier ouvert et pas un fichier tiers (alors votre solution fonctionne parfaitement)

Mes neurones en place, voici donc la solution choisie :
ancienfichier = ThisWorkbook.FullName
nouveaufichier = "F:\AAA\" & "MAJ " & Format(Now, "dd-mm-yyyy") & ".xlsm"
ThisWorkbook.SaveAs Filename:=nouveaufichier
Kill ancienfichier

 

[ROGER2327]

Re : macro : renommer fichier .xlsm, sans en connaitre le nom, et avec la date du jou

Bonsoir à tous

Pour renommer sans le déplacer le seul fichier (supposé fermé) de type xlsm du dossier F:\AAA\ :​

Sub Renommer()
Dim chemin$, typ$, fic$
    chemin = "F:\AAA\"
    typ = ".xlsm"
    fic = Dir(chemin & "*" & typ)
    If fic = "" Then
        MsgBox "Il n'y a aucun fichier accessible de type " & typ & " dans " & vbLf & chemin
    ElseIf Dir = "" Then
        On Error GoTo E
        Name chemin & fic As chemin & "MAJ " & Format(Date, "yyyymmdd") & typ
        On Error GoTo 0
    Else
        MsgBox "Il y a plusieurs fichiers de type " & typ & " dans " & vbLf & chemin
    End If
Exit Sub
E:
    MsgBox "Impossible de renommer " & chemin & fic
    Resume Next
End Sub

ROGER2327
#6420

Samedi 7 Gueules 140 (Saint Gueule, abbé - fête Suprême Quarte)
13 Pluviôse An CCXXI, 0,2668h - laurier
2013-W05-5T00:38:25Z