Microsoft 365 Logique de formule

[Nain porte quoi]

Hello,

je bute bêtement sur un problème de logique de formule.
Dans l'exemple joins je dois saisir 4 valeurs (obligatoirement) dans chaque colonne. La somme des valeurs de chaque colonne (en ligne 5) doit être égale à "H1"
Si je saisie trop ou pas assez de valeur un format perso ("manque "0;"trop "0;"OK") me dit combien il en manque ou combien il y en a en trop, voire (et c'est la le pb) OK si la somme égale à H1
Dans l'exemple fourni la colonne E affiche OK alors que 2 cellules ne contiennent rien (la somme de rien = 0)

Je voudrais continuer à afficher combien de valeurs manquent ou sont en trop mais je voudrais être sur que les 4 valeurs sont saisies, donc ma formule =$H$1-SOMME(E1:E4) est forcément fausse quand il manque des valeurs.

J'ai trop cherché et du coup je suis certainement à coté de la solution, mais je n'y vois plus clair et du coup je ne sais même pas si c'est possible

Merci d'avance

 

[Phil69970]

Bonjour @Nain porte quoi

Je te propose cette formule

=SI(NBVAL(E1:E4)<4;"Somme="&SOMME(E1:E4)&" et il manque "&(4-NBVAL(E1:E4))&" saisie(s)";"Somme="&SOMME(E1:E4)&" et écart en trop ="&(SOMME(E1:E4)-H1))

Merci de ton retour

 

[Xl60PassionFr]

Salut @Nain porte quoi

En E5, tu peux essayer

=4-NBVAL(E1:E4)+($H$1-SOMME(E1:E4))

A+

 

[dysorthographie]

bonjour,
je suis sur mon téléphone donc j'ai pas vérifié mais un truc genre

=SWITCH(VRAI();
    SOMME(E1:E4)=$H$1;"OK";
    SOMME(E1:E4)>$H$1;"trop "&SOMME(E1:E4)-$H$1;
    SOMME(E1:E4)<$H$1;"trop peu "&$H$1-SOMME(E1:E4)
)

 

[sylvanu]

Bonjour,
Un petit essai avec :

=SI(NBVAL(B1:B4)<4;"Incomplet";SI(SOMME(B1:B4)=$H$1;"OK";SI(SOMME(B1:B4)<$H$1;"Manque "&$H$1-SOMME(B1:B4);"Trop "&SOMME(B1:B4)-$H$1)))

 

[dysorthographie]

sur 365

=LAMBDA(plage, cible,
    SWITCH(VRAI(),
        SOMME(plage)=cible, "OK",
        SOMME(plage)>cible, "trop "&SOMME(plage)-cible,
        SOMME(plage)<cible, "trop peu "&cible-SOMME(plage)
    )
)(E1:E4, $H$1)

 

[Piment]

sur 365

=LAMBDA(plage, cible,
    SWITCH(VRAI(),
        SOMME(plage)=cible, "OK",
        SOMME(plage)>cible, "trop "&SOMME(plage)-cible,
        SOMME(plage)<cible, "trop peu "&cible-SOMME(plage)
    )
)(E1:E4, $H$1)

Bonjour à tous: essayez ça : "
=SI(NBVAL(E1:E4)<4;
"Somme="&SOMME(E1:E4)&" et il manque "&(4-NBVAL(E1:E4))&" saisie(s)";SI(SOMME(E1:E4)=H1;"OK";"Somme="&SOMME(E1:E4)&" et écart en trop = "&(SOMME(E1:E4)-H1)))

 

[Piment]

re: ou encore peut-être, pour gérer "pas assez et trop : "
=SI(NBVAL(E1:E4)<4;"Il manque "&(4-NBVAL(E1:E4))&" saisie(s)";SI(SOMME(E1:E4)=H1;"OK";SI(SOMME(E1:E4)>H1;"Trop "&(SOMME(E1:E4)-H1);"Manque "&(H1-SOMME(E1:E4)))))

 

[dysorthographie]

je vois aucun rapport avec ma proposition !

 

[Cousinhub]

Hello,
Merci pour ce remue-méninges 😉

=LET(a;$H$1-SOMME(E1:E4);b;NBVAL(E1:E4);c;SI(b<4;"manque "&4-b&" saisie(s)";"Ok pour le nombre");d;SI.CONDITIONS(a=0;"Ok pour la somme";a<0;"trop "&ABS(a);a>0;"manque "&a);c&CAR(10)&d)