Liste deroulante en cascade avec doublons

[C@thy]

Bonjour le forum,

j'ai une liste de personnes, et leurs données, mais... j'ai deux personnes différentes avec le même nom de famille..🙄

donc lorsque dans le liste déroulante des noms j'affiche un nom qui n'est pas unique je voudrais en face choisir son prénom parmi les 2 posssibles, et afficher les infos de la bonne personne,sinon faire un recherchev qui de donnera les infos lorsque le nom est unique..

je joins mon fichier pour que ce soit plus clair..


Si vous avez une idée de la façon de procéder, par formules uniquement, cela me comblera de bonheur🙂🙂🙂

Merci

C@thy

 

[gilbert_RGI]

Re : Liste deroulante en cascade avec doublons

Bonjour,

il devrait y avoir quelque chose pour vous aider sur ce site Listes en cascade

 

[C@thy]

Re : Liste deroulante en cascade avec doublons

Merci gilbert_RGI,
mon problème n'est pas les liste en cascade puisque j'ai utilisé ce principe dans le fichier que j'ai mis en ligne,
mais comment récupérer les données lorsqu'on a des doublons dans le nom???

Edit : il est vrai que j'aurais sans doute pu encore optimiser, mais cela fonctionne...

C@thy

 

[mutzik]

Re : Liste deroulante en cascade avec doublons

Bonjour Cathy,

Au niveau des macros, tu peux utiliser un certificat personnel propre à ton entreprise lors de la validation du classeur
FAQ Excel

Biz

 

[C@thy]

Re : Liste deroulante en cascade avec doublons

Merci mutzik mais il ne faut pas de macro...🙁

C@thy

 

[job75]

Re : Liste deroulante en cascade avec doublons

Bonjour C@thy, gilbert_RGI, [Edit] mutzik,

En B2 de la feuille Modèle, sur toutes versions, formule matricielle à tirer vers le bas :

=DECALER(ListeNoms;PETITE.VALEUR(SI(ListeNoms=A2;LIGNE(ListeNoms));NB.SI(A$1:A2;A2))-1;1)

A valider par Ctrl+Maj+Entrée.

Les valeurs d'erreur sont à masquer par MFC.

A partir d'Excel 2007 on peut bien sûr utiliser :

=SIERREUR(DECALER(ListeNoms;PETITE.VALEUR(SI(ListeNoms=A2;LIGNE(ListeNoms));NB.SI(A$1:A2;A2))-1;1);"")

A+

 

[C@thy]

Re : Liste deroulante en cascade avec doublons

Merci Gérard,

ça marche très bien... sauf en B11😕

C@thy

 

[C@thy]

Re : Liste deroulante en cascade avec doublons

Je veux parler de la 2ème formule car la 1ère n'est pas compatible avec ma MFC.

Bizz

C@thy

 

[job75]

Re : Liste deroulante en cascade avec doublons

Re,

Autre méthode, sans doute préférable, toujours en matriciel, en B2 :

=DECALER(ListeNoms;PETITE.VALEUR(SI(ListeNoms=A2;LIGNE(ListeNoms));MOD(NB.SI(A$1:A2;A2)-1;NB.SI(ListeNoms;A2))+1)-1;1)

Les prénoms se répètent de manière cyclique grâce à la fonction MOD.

Il n'y a plus de valeurs d'erreur 😎

A+

 

[C@thy]

Re : Liste deroulante en cascade avec doublons

Yaisse... ça le fait... Merci...

Le but est de remplir aussi (si possible😱) les colonnes C,D,E à partir des données en feuil12...

Merci

C@thy

 

[job75]

Re : Liste deroulante en cascade avec doublons

Re,

Le but est de remplir aussi (si possible😱) les colonnes C,D,E à partir des données en feuil12...

Dans ce cas pourquoi as-tu mis dans ces colonnes des listes de validation 😕

Maintenant si tu veux des formules commence par nommer "Base" le tableau en Feuil12 :

=DECALER(Feuil12!$A$1;;;NBVAL(Feuil12!$A:$A);5)

Puis formules matricielles en C2, D2 et E2, à tirer vers le bas :

=INDEX(Base;EQUIV($A2&$B2;INDEX(Base;;1)&INDEX(Base;;2);0);4)

=INDEX(Base;EQUIV($A2&$B2;INDEX(Base;;1)&INDEX(Base;;2);0);5)

=INDEX(Base;EQUIV($A2&$B2;INDEX(Base;;1)&INDEX(Base;;2);0);3)

A toi de voir si tu veux éviter les doublons par MFC.

A+

 

[C@thy]

Re : Liste deroulante en cascade avec doublons

Dans ce cas pourquoi as-tu mis dans ces colonnes des listes de validation 😕

Au cas où on ne puisse pas par formule...

je teste

C@thy

 

[C@thy]

Re : Liste deroulante en cascade avec doublons

OK ça maaaarche!!!

Mille mercis, maestro!

Bises

C@thy