XL 2016 Lire valeur celulle determiner avec somme prod

[ZZ59264]

Bonjour à tous,

Je joins mon fichier et les explications pour lesquelles je bute pour avoir une formule qui convienne,

Merci d'avance,

Cordialement,

 

[sylvanu]

Bonsoir ZZ,
Essayez cela :

En I4 :
=ADRESSE(SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*(LIGNE(INDIRECT(H4&"!A2:T1001"))));SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*COLONNE(Feuil3!A1:T1))+1)
et tirer.

En I8 :
=INDIRECT(H4&"!"&I4)
et tirer

ou directement en I4 :
=INDIRECT(H4&"!"&ADRESSE(SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*(LIGNE(INDIRECT(H4&"!A2:T1001"))));SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*COLONNE(Feuil3!A1:T1))+1))

Fonction INDIRECT - Support Microsoft

Comment utiliser la fonction INDIRECT dans Excel pour modifier la référence à une cellule dans une formule sans modifier la formule elle-même.

support.microsoft.com

 

[ZZ59264]

=INDIRECT(H4&"!"&ADRESSE(SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*(LIGNE(INDIRECT(H4&"!A2:T1001"))));SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*COLONNE(Feuil3!A1:T1))+1))

Bonsoir Sylvanu,

Merci beaucoup, j'ai testé et c'est parfait, cependant j'ai une question :

Pourquoi en fin de formule il y a "COLONNE(Feuil3!A1:T1))+1)) , la feuil 3 est indiqué alors que je cherche l'AVIS sur la feuille 2 ,?

Et lorsque je descends la formule cela me donne à la fin de la formule : COLONNE(Feuil3!A2:T2))+1)) en I5 et COLONNE(Feuil3!A3:T3))+1)) en I6

Merci d'avance pour vos précisions,

Cordialement,

 

[sylvanu]

Parce que c'est un raté !

=INDIRECT(H4&"!"&ADRESSE(SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*(LIGNE(INDIRECT(H4&"!A2:T1001"))));SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*COLONNE(INDIRECT(H4&"!A1:T1")))+1))

😚

 

[ZZ59264]

Parce que c'est un raté !

=INDIRECT(H4&"!"&ADRESSE(SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*(LIGNE(INDIRECT(H4&"!A2:T1001"))));SOMMEPROD((INDIRECT(H4&"!A2:T1001")="AVIS :")*COLONNE(INDIRECT(H4&"!A1:T1")))+1))

😚

Merci Sylvanu,

Merci beaucoup et ce n'était pas une critique n'ayant pas trouvé moi même,

Bonne soirée à vous,

Cordialement,

 

[ZZ59264]

Bonsoir Sylvanu,

Sur mon fichier de travail j'ai une autre problématique à la quelle je n'ai pas pensé a soumettre des le départ,

Je rejoins mon fichier avec votre solution, qui ne fonctionne plus malheureusement,

Merci d'avance,

Cordialement,

 

[sylvanu]

Si dans une feuille vous faites = puis cliquez sur une cellule d'une autre feuille, vous obtenez :

Si Feuil2  :    =Feuil2!G5
Si Feuil 2 :    ='Feuil 2'!G5

Vous remarquerez la présence des ' , je pense pour délimiter le nom de la feuille.
Il "suffit" alors remplacer :

INDIRECT(H4&"!
par
INDIRECT("'"&H4&"'!

On obtient alors :

=INDIRECT("'"&H5&"'!"&ADRESSE(SOMMEPROD((INDIRECT("'"&H5&"'!A2:T1001")="AVIS :")*(LIGNE(INDIRECT("'"&H5&"'!A2:T1001"))));SOMMEPROD((INDIRECT("'"&H5&"'!A2:T1001")="AVIS :")*COLONNE(INDIRECT("'"&H5&"'!A1:T1")))+1))

et on arrive à la limite de la compréhension. 😂😂😂😂

 

[ZZ59264]

Si dans une feuille vous faites = puis cliquez sur une cellule d'une autre feuille, vous obtenez :

Si Feuil2  :    =Feuil2!G5
Si Feuil 2 :    ='Feuil 2'!G5

Vous remarquerez la présence des ' , je pense pour délimiter le nom de la feuille.
Il "suffit" alors remplacer :

INDIRECT(H4&"!
par
INDIRECT("'"&H4&"'!

On obtient alors :

=INDIRECT("'"&H5&"'!"&ADRESSE(SOMMEPROD((INDIRECT("'"&H5&"'!A2:T1001")="AVIS :")*(LIGNE(INDIRECT("'"&H5&"'!A2:T1001"))));SOMMEPROD((INDIRECT("'"&H5&"'!A2:T1001")="AVIS :")*COLONNE(INDIRECT("'"&H5&"'!A1:T1")))+1))

et on arrive à la limite de la compréhension. 😂😂😂😂

Bonsoir,

Merci beaucoup pour votre réponse qui correspond nickel à ce qu eje souhaite,

Alors oui mais cette formule ne sera pas modifié, et elle me sera bien utile,

Merci encore,

Bonne soirée à vous,

Cordialement,