XL 2021 Lien Hypertexte et feuilles masquées

job75 à dit:

Bonjour Tacine, Eric KERGRESSE, le forum,

Pour faire ce que vous voulez faire il faut que les liens soient de vrais liens hypertextes.

Les liens créés par la fonction LIEN_HYPERTEXTE n'en sont pas.

Voyez donc le fichier joint et ces 3 macros dans le code de la feuille "Accueil" :

VB:

Private Sub Worksheet_Change(ByVal Target As Range)
If Intersect(Target, [I14]) Is Nothing Then Exit Sub
Dim r As Range, x As Variant
Application.ScreenUpdating = False
Application.EnableEvents = False
Set r = [J15:J83]
r.Hyperlinks.Delete 'RAZ
For Each r In r
    x = Application.VLookup(r(1, 0), Range("B:D"), 3, 0)
    If Not IsError(x) Then Hyperlinks.Add r, "", "'" & x & "'!A1", TextToDisplay:=x 'crée le lien
Next
Application.EnableEvents = True
End Sub

Private Sub Worksheet_Followhyperlink(ByVal h As Hyperlink)
Evaluate(h.SubAddress).Parent.Visible = xlSheetVisible
Application.Goto Evaluate(h.SubAddress)
End Sub

Private Sub Worksheet_Activate()
Dim s As Object
For Each s In Sheets
    If s.Name <> Me.Name Then s.Visible = xlSheetHidden 'masque les feuilles
Next
End Sub

A+

Cliquez pour agrandir...

Eric KERGRESSE à dit:

Bonjour,

Une autre solution que par les liens hypertextes.

Cliquez pour agrandir...