XL 2021 Le max toutes les 2 colonnes

[Retraite]

Bonjour,

Quelle est la formule pour avoir le MAX sur 52 semaines tous les 2 colonnes ?
Exemple joint

Merci d'avance

 

[AtTheOne]

Bonjour à toutes & à tous, bonjour @Retraite

Ou encore, puisque tu as EXCEL2021, avec seulement 2 formules matricielles dynamiques en B4 et C4
(elles s'étendront automatiquement si tu ajoutes des lignes dans la colonne "Action") :

Pour le MAX en B4 :

=LET(nbl;NBVAL(A:A)-1;
     liste;DECALER($A$4;0;0;nbl;1);
     lib;DECALER($E$3;0;0;1;53*2);
MAX.SI.ENS(DECALER(lib;EQUIV(liste;liste;0);;);lib;"Valeur"))

Pour le MIN en C4 :

=LET(nbl;NBVAL(A:A)-1;
     liste;DECALER($A$4;0;0;nbl;1);
     lib;DECALER($E$3;0;0;1;53*2);
MIN.SI.ENS(DECALER(lib;EQUIV(liste;liste;0);;);lib;"Valeur"))

nbl : compte le nombre d'actions dans la colonne A (à condition qu'il y ait un entête, d'où le -1)
liste : la liste des libellés dans la colonne "Action"
lib : la liste des entêtes ("Valeur", "Montant") sur 53 semaines

Plus besoin de tirer les formules vers le bas, elles s'ajustent d'elles-même
Tu peux insérer des lignes en têtes de feuille et des colonnes à gauche de la colonne "Action", les 2 formules suivront.

nota : avec excel 2024 et 365 on peut uiliser les fonctions BYROW et LAMBDA, non disponibles en version 2021
À bientôt

 

[Retraite]

Bonjour, grâce à vous je sais retrouver à présent le plus haut cours de l'année mais comment afficher alors la date correspondante ?
Merci d'avance

 

[mapomme]

Bonjour @Retraite😉,

Bonjour, grâce à vous je sais retrouver à présent le plus haut cours de l'année mais comment afficher alors la date correspondante ?
Merci d'avance

Mettre la formule =MAX.SI.ENS($H$1:$BZ$1;$G4:$BY4;C4) en B4 puis copier la formule dans les autres cellules de la colonne B.
Mettre la formule =MAX.SI.ENS($H$1:$BZ$1;$G4:$BY4;E4) en D4 puis copier la formule dans les autres cellules de la colonne D.
Ces deux formules donnent la date la plus récente dans le cas où le maximum (minimum) serait atteint plusieurs fois.

Si on veut la date la plus ancienne, remplacez MAX.SI.ENS par MIN.SI.ENS.

 

[danielco]

Bonjour,

Un peu tard, mais pour le maximum :

=MAX(G4:R4/F4)

Pour la date la plus ancienne :

=INDEX($H$1:$S$1;EQUIVX(C4;G4:R4))

Pour la ppus récente :

=INDEX($H$1:$S$1;EQUIVX(C4;G4:R4;;-1))

Daniel

 

[job75]

Bonjour le forum,

Formule matricielle en B4 qui concatène les dates correspondant au maximum :

=JOINDRE.TEXTE("-";1;REPT(TEXTE($H$1:$R$1;"jj/mm");$G4:$Q4=C4))

Formule en D4 pour le minimum :

=JOINDRE.TEXTE("-";1;REPT(TEXTE($H$1:$R$1;"jj/mm");$G4:$Q4=E4))

A+

 

[danielco]

Bonjour à tous,
@job75 :
Il me semble que tes formules, comme les miennes donnent un résultat erroné quand la quantité de titres est égale à 1.
Daniel

 

[job75]

quand la quantité de titres est égale à 1.

En effet puisqu'alors les maxima et les minima se retrouvent dans les colonnes "Montant".

Donc utiliser en B4 et D4 :

=JOINDRE.TEXTE("-";1;REPT(TEXTE($H$1:$R$1;"jj/mm");($G$3:$Q$3="Valeur")*($G4:$Q4=C4)))

=JOINDRE.TEXTE("-";1;REPT(TEXTE($H$1:$R$1;"jj/mm");($G$3:$Q$3="Valeur")*($G4:$Q4=E4)))