XL 2021 Le max toutes les 2 colonnes

[Retraite]

Bonjour,

Quelle est la formule pour avoir le MAX sur 52 semaines tous les 2 colonnes ?
Exemple joint

Merci d'avance

 

[Cousinhub]

Bonjour,
Un exemple
Dans la cellule B4 (à recopier vers le bas) :

=LET(tbl;DECALER($E$3;;;;NBVAL(3:3)-4);MAX.SI.ENS(DECALER(tbl;LIGNE()-3;0);tbl;"Valeur"))

Et en C4, recopie la formule, mais remplacer Max.Si.Ens par Min.Si.Ens
Bonne apm

 

[JHA]

Bonjour à tous,

A essayer

=MAX.SI.ENS($E4:$J4;$E$3:$J$3;"Valeur")

JHA

 

[JHA]

Bonjour à tous,

Si tu ajoutes des données, en "B4"

=MAX.SI.ENS(DECALER($E$3;LIGNES($1:1);;;NB.SI($3:$3;"Valeur")*2);DECALER($E$3;;;;NB.SI($3:$3;"Valeur")*2);"Valeur")

copier vers le bas

JHA

 

[gosselien]

Bonjour à tous...
Il y a peut être une (bonne) raison de présenter les données de cette manière mais avec 4 colonnes Date/Qté/Valeur/Action on peut faire un tcd plus facilement que des formules que tu auras oubliées dans quelques semaines 🙂 Mais ça n'enlève rien au talent des différents répondeurs spécialistes ( que je salue et admire) en formules 🙂

 

[Retraite]

Grand merci pour vos brillantes réponses. Bon dimanche

 

[job75]

Bonjour à tous,

La formule la plus simple, en B4 :

=MAX.SI.ENS(4:4;$3:$3;"Valeur")

J'ai vérifié : son recalcul ne prend pas plus de temps que la formule du post #4.

A+

 

[job75]

Bonjour le forum,

Je pensais que la durée du recalcul de la formule précédente dépendait du UsedRange mais ce n'est pas le cas :

- UsedRange A1:J6 => 0,24 ms

- UsedRange A1:XFD6 => 0,24 ms pour les formules en B4 B5 B6.

A+

 

[Retraite]

Bonjour je comprends pas la formule (qui marche pour moi) : Ok 4 c'est la 4ieme ligne mais $3 ?

=MAX.SI.ENS(4:4;$3:$3;"Valeur")

 

[job75]

Bonjour,

Ok 4 c'est la 4ieme ligne mais $3 ?

Bah $3:$3 c'est la 3ème ligne.

Edit : les caractères $ évitent que la plage se modifie quand on tire la formule vers le bas.

A+

 

[mapomme]

Bonsoir à tous,

Deux autres formules pour rigoler mais pas très originales (il faut bien l'avouer 🙁) :
pour le MAX en B4 : =MAX(SI($E$3:$BZ$3="Valeur";$E4:$BZ4)) à recopier vers le bas
pour le MIN en C4 : =MIN(SI($E$3:$BZ$3="Valeur";$E4:$BZ4)) à recopier vers le bas

 

[Retraite]

Bonsoir à tous,

Deux autres formules pour rigoler mais pas très originales (il faut bien l'avouer 🙁) :
pour le MAX en B4 : =MAX(SI($E$3:$BZ$3="Valeur";$E4:$BZ4)) à recopier vers le bas
pour le MIN en C4 : =MIN(SI($E$3:$BZ$3="Valeur";$E4:$BZ4)) à recopier vers le bas

Comprends toujours pas E3. En ligne c'est des titres de colonnes. En colonne, c'est pas la 3ieme car ça marche quand même si je décale en 6 colonnes (ci-joint)

 

[gosselien]

Comprends toujours pas E3. En ligne c'est des titres de colonnes. En colonne, c'est pas la 3ieme car ça marche quand même si je décale en 6 colonnes (ci-joint)

Parce que que le mot "valeur" est et reste en ligne 3; si tu déplaces tout le bloc G3:Q6 vers le bas , ça ne fonctionne plus

 

[Retraite]

Grand merci, j'ai enfin compris, puissant la formule ! Bonne journée

 

[danielco]

Bonjour,
Bah, aussi :

=MAX(EST.IMPAIR(COLONNE(D4:XFD4))*D4:XFD4)

Daniel