Insérer image dans une cellule

Re : Insérer image dans une cellule

bonjour jeff, le Forum,

Voici ce que j'ai trouvé dans mes archives, mais pas compétent pour t'aider davantage, désolé :


'2 macros pour insérer une image dans une cellule ou une plage de cellules auteur inconnu
' postées par STéphane, mpfe

Public Const GifImage As String = _
"C:\Program Files\Fichiers communs\Microsoft Shared\Papier à lettres\Christmas Trees.gif"

'Avec la macro ci-dessous, vous pouvez insérer une image dans n'importe
'quelle cellule d'une feuille. L'image peut être centrée horizontalement
'et/ou verticalement


Sub TestInsertPicture()
InsertPicture GifImage, Range("D10"), True, True
End Sub


Sub InsertPicture(PictureFileName As String, TargetCell As Range, _
CenterH As Boolean, CenterV As Boolean)
' inserts a picture at the top left position of TargetCell
' the picture can be centered horizontally and/or vertically
Dim p As Object, t As Double, l As Double, w As Double, h As Double
If TypeName(ActiveSheet) <> "Worksheet" Then Exit Sub
If Dir(PictureFileName) = "" Then Exit Sub
' import picture
Set p = ActiveSheet.Pictures.Insert(PictureFileName)
' determine positions
With TargetCell
t = .Top
l = .Left
If CenterH Then
w = .Offset(0, 1).Left - .Left
l = l + w / 2 - p.Width / 2
If l < 1 Then l = 1
End If
If CenterV Then
h = .Offset(1, 0).Top - .Top
t = t + h / 2 - p.Height / 2
If t < 1 Then t = 1
End If
End With
' position picture
With p
.Top = t
.Left = l
End With
Set p = Nothing
End Sub

Avec tous mes voeux

Re : Insérer image dans une cellule

Salut,jef1494,noviceAG

As tu fait une recherche sur le forum ? le sujet a été mainte fois débattue.

Cordialement