Index / EquiV

[bloublou]

Bonjour à tous,

J'ai un peu de difficulté pour construire une formule avec des données qui ne sont pas dans le même sens de lecture et avec une fonction de recherche.

Je pense qu'il faudrait utiliser un index avec 3 equiv ou une formule matricielle mais j'ai toujours du mal à les construire. 😕

Est-ce que vous pourriez m'aider ?

Merci

BlouBlou

 

[R@chid]

Re : Index / EquiV

Bonjour,
en D2,

=SOMMEPROD((base!A$2:A$13=A2)*(base!B$2:B$13=B2)*(base!C$1:AE$1=C2);base!C$2:AE$13)

@ tirer vers le bas
@ + +

 

[JHA]

Re : Index / EquiV

Bonjour à tous,

peut être comme ceci:

=INDEX(base!$C$2:$AE$13;EQUIV(Resultat!$A2&Resultat!$B2;base!$A$2:$A$13&base!$B$2:$B$13;0);EQUIV(Resultat!$C2;base!$C$1:$AE$1;0))

Formule matricielle
A tirer vers le bas

Edit: Bonjour Rachid, effectivement avec sommeprod() aussi, bien vu.

JHA

 

[Guest]

Re : Index / EquiV

Re bonjour,

=SOMMEPROD(($A2=base!$A$2:$A$13)*(Resultat!$B2=base!$B$2:$B$13)*DECALER(base!$B$2:$B$13;0;EQUIV(Resultat!$C2;base!$C$1:$AE$1;0)))

A+

[edition] à la bourre l'hasco...arf🙂

Complément: sur la feuille 'base' selectionner une cellule du tableau puis onglet 'insertion' bouton 'tableau' valider la source de données.
Je l'ai fait et renommé le tableau: 'tBase' et la formule peut devenir:

=SOMMEPROD(($A2=tBase[Produit])*($B2=tBase[Mois])*(INDIRECT("tbase["&C2&"]")))

 

[R@chid]

Re : Index / EquiV

Bonjour @ tous,
Salut les amis,
pour éviter les matricielles,

=RECHERCHEV(B2;DECALER(base!B$1:AE$1;EQUIV(A2;base!A:A;0)-1;;NB.SI(base!A:A;A2));EQUIV(C2;base!B$1:AE$1;0);0)

@ tirer vers le bas
@ + +

 

[bloublou]

Re : Index / EquiV

Bonsoir R@chid, JHA, HAsco,

Merci pour toutes vos réponses, ça marche nickel 🙂

D'une manière générale quand on a plusieurs critères comme c'était le cas içi présent, on utilise SOMMEPROD ?

Merci en tout cas 🙂 🙂 🙂

BlouBlou

 

[Guest]

Re : Index / EquiV

Re,

Sommeprod ou somme.si.ens avec les version >=2007

A+
Bonsoir Rachid, JHA