incrementation

corsu2a · 22 Janvier 2018

Bonjour
ne pratiquant plus depuis longtemps,j'ai perdu beaucoup de code et de vocabulaire excel. J'ai un projet de suivi quotidien de personnel dans sur plusieurs service.
J'ai crée un tableau mensuel sur une feuille par service et je souhaiterais sur une autre feuille, un indicateur journalier qui se met à jour en fonction de la date ou, que le résultat sur la colonne du mensuel se décale d'une colonne automatiquement.

Je ne sais pas si je suis assez clair, je vais pour ça joindre un fichier.

merci pour tout

job75 · 22 Janvier 2018

Bonjour corsu2a,

Feuille 'indicateur jour', formule en D1 à tirer sur D2 :

Code:

=INDEX('Tableau mensuel informatique'!$46:$46;EQUIV(JOUR(A$2);'Tableau mensuel informatique'!$5:$5;0)+LIGNES(D$1:D1)-1)

Sur votre fichier, pour tester, entrez 01/01/2018 en A2.

A+

Dugenou · 22 Janvier 2018

Bonjour Corsu et Job
Pour ma part j'ai compris qu'on voulait la somme à la date du jour.
Je propose donc un somme.si.ens et un petit décalage pour les cellules fusionnées
en E1 :
=SOMME.SI.ENS('Tableau mensuel informatique'!$F$46:$BN$46;'Tableau mensuel informatique'!$F$5:$BN$5;"<="&JOUR('Indicateur jour'!$A$2);'Tableau mensuel informatique'!$F$6:$BN$6;"J")
en E2
=SOMME.SI.ENS('Tableau mensuel informatique'!$G$46:$BO$46;'Tableau mensuel informatique'!$F$5:$BN$5;"<="&JOUR('Indicateur jour'!$A$2);'Tableau mensuel informatique'!$G$6:$BO$6;"N")
Voir pj
Cordialement

corsu2a · 22 Janvier 2018

Merci Top !!!!!!!

JOB 75 😉

corsu2a · 22 Janvier 2018

Dugenou à dit:
Bonjour Corsu et Job
Pour ma part j'ai compris qu'on voulait la somme à la date du jour.
Je propose donc un somme.si.ens et un petit décalage pour les cellules fusionnées
en E1 :
=SOMME.SI.ENS('Tableau mensuel informatique'!$F$46:$BN$46;'Tableau mensuel informatique'!$F$5:$BN$5;"<="&JOUR('Indicateur jour'!$A$2);'Tableau mensuel informatique'!$F$6:$BN$6;"J")
en E2
=SOMME.SI.ENS('Tableau mensuel informatique'!$G$46:$BO$46;'Tableau mensuel informatique'!$F$5:$BN$5;"<="&JOUR('Indicateur jour'!$A$2);'Tableau mensuel informatique'!$G$6:$BO$6;"N")
Voir pj
Cordialement

Merci, la formule de JOB 75 fonctionne au top, merci quand même

corsu2a · 22 Janvier 2018

job75 à dit:
Bonjour corsu2a,

Feuille 'indicateur jour', formule en D1 à tirer sur D2 :

Code:

=INDEX('Tableau mensuel informatique'!$46:$46;EQUIV(JOUR(A$2);'Tableau mensuel informatique'!$5:$5;0)+LIGNES(D$1:D1)-1)

Sur votre fichier, pour tester, entrez 01/01/2018 en A2.

A+

Merci !!!!!! top

corsu2a · 24 Janvier 2018

Bonjour Job75
je sais que je t'ai déjà sollicité dernièrement mais pourrais tu me dépanner à nouveau sur le même fichier ?
c'est à dire que maintenant je souhaite récupérer les données sur la feuille "Indicateur_mois" dont les valeurs sont en colonne et plus en ligne comme précédemment.
Merci encore mille fois pour ta dispo !!!!!

job75 · 24 Janvier 2018

Bonjour corsu2a, Dugenou, le forum,

Ils servent à quoi tous ces objets en colonne C de la feuille Indicateur_mois ???

Pour l'instant à rien mais il faut alterner "Jour" et Nuit" dans les cellules de la plage C8:C45.

En cellule D2 (à tirer sur D3) de la feuille Indicateur_jour il y a ces 2 solutions possibles.

1) Fichier (1) avec cette formule volatile à cause de la fonction DECALER :

Code:

=SOMMEPROD((Indicateur_mois!C$8:C$45=DROITE(C2;4))*(DECALER(Indicateur_mois!C$8:C$45;;EQUIV(A$2;Indicateur_mois!D$5:BM$5;0))<>""))

2) Fichier (2) avec cette formule non volatile mais dont le calcul est beaucoup moins rapide :

Code:

=SOMMEPROD((Indicateur_mois!C$8:C$45=DROITE(C2;4))*(Indicateur_mois!D$5:BM$5=A$2)*(Indicateur_mois!D$8:BM$45<>""))

A+

job75 · 24 Janvier 2018

Re,

En faisant les totaux en lignes 46 47 48 de la feuille Indicateur_mois la formule en D2 est très simple:

Code:

=INDEX(Indicateur_mois!D46:BM46;EQUIV(Indicateur_jour!A$2;Indicateur_mois!D$5:BM$5;0))

Edit : dans Indicateur_mois j'ai supprimé les objets en colonne C, c'est plus clair.

Fichier (3).

A+

corsu2a · 24 Janvier 2018

Bonsoir Job
merci encore pour ta patience et surtout ton efficacité, c'est magique les gens comme toi. Je peu très bien me passer des étiquettes, c’était pour faire du style..... 😉

Pour le fichier, je me suis mal exprimé en fait en "D8" c'est une simple liaison avec le résultat de la cellule "F46" de la feuille, "Tableau mensuel informatique", il s'agit donc de valeur numérique, j'ai vraiment besoin de faire une lecture en ligne par service. Penses tu que tes dernières formules vont changer ???
Merci pour ton aide, tes formules sont au top !!!!!

job75 · 24 Janvier 2018

Re,

corsu2a à dit:
Pour le fichier, je me suis mal exprimé en fait en "D8" c'est une simple liaison avec le résultat de la cellule "F46" de la feuille, "Tableau mensuel informatique", il s'agit donc de valeur numérique, j'ai vraiment besoin de faire une lecture en ligne par service. Penses tu que tes dernières formules vont changer ???

Non elles ne changent pas, simplement dans Indicateur_mois, formule en D8 à copier sur D8:BM9 :

Code:

=INDEX('Tableau mensuel informatique'!$F$46:$BO$46;COLONNES($D8:D8)+($C8=$A$2))

et en D46 à copier sur D46:BM47 :

Code:

=SOMME.SI($C$8:$C$45;$A1;D$8:D$45)

Fichier (4).

A+

job75 · 25 Janvier 2018

Bonjour corsu2a, le forum,

En complément voyez ce fichier (4 bis) qui fonctionne quels que soient le mois et l'année.

J'ai ajouté une liste de validation en Indicateur_jour!A2.

Bonne journée.

corsu2a · 25 Janvier 2018

Bonjour Job
je suis désole de vous embêter à nouveau mais ce que vous m'avez gentiment envoyé s'éloigne un peu de ce dont j'ai besoin.
Je vous envoie un dernier fichier qui reflète peut être plus mon besoin. La seule différence avec l'actuel, c'est que je voudrais, non pas créer la liaison sur les différents "tableaux mensuel" mais tout simplement avec le tableau "indicateur mois" ce qui m’éviterait surement des erreurs quand les tableaux mensuels n'ont pas le même nombre de ligne par rapport aux effectifs bien sûr.
J'espère qu'on va trouver, sinon je resterais avec tes précédentes formules qui marchent très bien.
Merci encore pour ton aide.

job75 · 25 Janvier 2018

Re,

corsu2a à dit:
mais ce que vous m'avez gentiment envoyé s'éloigne un peu de ce dont j'ai besoin.

Pas du tout, à partir du fichier (4) on obtient facilement ce fichier (5) avec en Indicateur_jour!D2 :

Code:

=INDEX(Indicateur_mois!$D$8:$BM$45;EQUIV(D$1&"*";Indicateur_mois!$A$8:$A$45;0)+LIGNES(D$2:D2)-1;EQUIV($A$2;Indicateur_mois!$D$5:$BM$5;0))

à tirer sur D3 puis vers la droite.

A+

corsu2a · 25 Janvier 2018

Encore top !!!!
Merci

incrementation

XLDnaute Occasionnel

Pièces jointes

XLDnaute Barbatruc

XLDnaute Barbatruc

Pièces jointes

XLDnaute Occasionnel

XLDnaute Occasionnel

XLDnaute Occasionnel

XLDnaute Occasionnel

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Occasionnel

XLDnaute Barbatruc

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Occasionnel

Pièces jointes

XLDnaute Barbatruc

Pièces jointes

XLDnaute Occasionnel

Discussions similaires

Privacy & Transparency

Privacy & Transparency