importation de donnees

[bennisay]

Bonjour le forum
j ai une demande svp
j aimerai importer des donnees d une feuille excel a une autre feuille relativement a un variable
j ai mis un fichier pour illustrer ma demande
et merci

 

[Softmama]

Bonjour,

une proposition en PJ, par macro.

Private Sub Worksheet_Change(ByVal Target As Range)
Dim TableauDépart()
Dim TableauArrivée(1 To 10000, 1 To 6)
Dim t As Long, x As Long

x = 1
If Target.Address = "$C$2" Then
  Range("A4").CurrentRegion.Offset(1).ClearContents
  TableauDépart = Feuil2.Range("A3:K" & Feuil2.Range("A100000").End(xlUp).Row).Value
  For t = 1 To UBound(TableauDépart, 1)
    If TableauDépart(t, 2) = Target.Value Then
      TableauArrivée(x, 1) = TableauDépart(t, 1) 'Nom client
      TableauArrivée(x, 2) = TableauDépart(t, 4) 'Réf
      TableauArrivée(x, 3) = TableauDépart(t, 5) 'Désignation
      TableauArrivée(x, 4) = TableauDépart(t, 8) 'Dépôt
      TableauArrivée(x, 5) = TableauDépart(t, 9) 'Quantité
      TableauArrivée(x, 6) = TableauDépart(t, 11) 'Bon livr
      x = x + 1
    End If
  Next t
Feuil6.Range("A5").Resize(UBound(TableauArrivée, 1), 6) = TableauArrivée
End If

End Sub

 

[bennisay]

bonjour
je vous remercie softmama profondément pour votre aide
merci le forum