Fournisseurs moins disant ou égaux

[capalain]

Bonjour à tous,

je suis allé voir la FAQ mais je n'ai pas trouvé mon bonheur.

j'ai des tableaux avec une dizaine de fournisseurs et des milliers de lignes. Je voudrais avoir en bout de ligne le prix mini et surtout le nom du fournisseur, donc ça j'ai trouvé mais là où ça se complique pour moi c'est quand plusieurs fournisseurs ont le même prix mini, je voudrais pouvoir afficher le nom de tous les fournisseurs ayant le prix mini. alors à moins d'aller à 5 chiffres après la virgule je ne trouve pas!

Merci de votre aide!
Je joins un exemple

 

[Dugenou]

Re : Fournisseurs moins disant ou égaux

Bonjour,
Une possibilité avec formule matricielle (à rallonge) prévue ici pour 3 ex aequo maximum :

=INDEX($A$1:$E$1;;PETITE.VALEUR(SI($A2:$E2=$F2;COLONNE(A$2:E$2));1))&SI(NB.SI($A2:$E2;$F2)>1;"; "&INDEX($A$1:$E$1;;PETITE.VALEUR(SI($A2:$E2=$F2;COLONNE(A$2:E$2));2));"")&SI(NB.SI($A2:$E2;$F2)>2;"; "&INDEX($A$1:$E$1;;PETITE.VALEUR(SI($A2:$E2=$F2;COLONNE(A$2:E$2));3));"")

voir en pj

 

[capalain]

Re : Fournisseurs moins disant ou égaux

Merci je vais essayer mais c'est un peu hard !!

Meuh pour toi ça a l'air facile mais moi je nage , j'ai mis une partie du fichier, peux tu y jeter un oeil !!

Merci beaucoup!

 

[Dugenou]

Re : Fournisseurs moins disant ou égaux

Meuh non !
c'est toujours le même genre de formule :

INDEX($A$1:$E$1;;PETITE.VALEUR(SI($A2:$E2=$F2;COLONNE(A$2:E$2));1))

pour le premier
dans laquelle : SI($A2:$E2=$F2;COLONNE(A$2:E$2)) crée une matrice composée de N° de colonnes où la condition est vérifiée
ensuite on appelle les différents résultats avec petite.valeur(...;1) puis petite.valeur(...;2) etc
et index (plage;;colonne) pour afficher le fournisseur


ensuite on ajoute (copier coller)

&SI(NB.SI($A2:$E2;$F2)>1;"; "&INDEX($A$1:$E$1;;PETITE.VALEUR(SI($A2:$E2=$F2;COLONNE(A$2:E$2));2));"")

et ensuite on colle la même chose en changeant le >1 en >2 et le ;2 en ;3 etc

ne pas oublier de valider par ctrl+maj+enter à la fin !!!!

 

[Si...]

Re : Fournisseurs moins disant ou égaux

salut

et avec une petite macro ?

 

[Dugenou]

Re : Fournisseurs moins disant ou égaux

Re,
Voir en pj la formule adaptée pour 2 résultats ex aequo :

INDEX($A$1:$L$1;1;PETITE.VALEUR(SI(F5:L5=M5;COLONNE(F5:L5));1)-2)

avec tes cellules fusionnées en ligne1 : la colonne du prix F5:L5=M5 n'est plus celle du fournisseur : d'où le -2
ensuite on reprend le principe petite.valeur(..;2) si nb.si () >1.
Si tu voulais afficher 3 ex aequo il faudra ajouter :
&SI(NB.SI(F5:L5;M5)>2;"; "&INDEX($A$1:$L$1;1;PETITE.VALEUR(SI(F5:L5=M5;COLONNE(F5:L5));3)-2);"")entre les deux dernières parenthèses de la formule

Cordialement