[Formules] Extraire années uniques

[Efgé]

Bonjour à tous
Je me mets aux formules et je bloque sur une extraction.
Sur la feuille "GENERAL" j'ai des dates en colonne C en format jj/mm/aaaa.
Sur la feuille "Calculs" je voudrais extraire une liste des années sans doublons (qui sert à la liste de validation de la cellule M1 de la feuille extraction).
J'arrive à retrouver les années, mais en trois colonnes
Pouvez vous me dire comment le faire en une seule formule ?
Cordialement

 

[Jocelyn]

Re : [Formules] Extraire années uniques

Bonjour le Forum,
Bonjour Efgé,

une formule a mettre en F3 et a étirée vers le bas, plus besoin des colonnes C et D, formule matricielle

=SIERREUR(INDEX(ANNEE(GENERAL!$C$3:$C$19);EQUIV(PETITE.VALEUR(SI(NB.SI(Calculs!F$2:F2;ANNEE(GENERAL!$C$3:$C$19))=0;ANNEE(GENERAL!$C$3:$C$19));1);ANNEE(GENERAL!$C$3:$C$19);0));"")

Amicalement

 

[Efgé]

Re : [Formules] Extraire années uniques

Bonjour Jocelyn
Merci d'avoir regardé mon problème.
Ne me reste plus qu'a comprendre le "comment ça marche"

Cordialement

 

[Jocelyn]

Re : [Formules] Extraire années uniques

re,

Etant donné que les données que tu veux extraire sont numérique on peut se passer de la partie index la formule est un peu plus courte.

=SIERREUR(PETITE.VALEUR(SI(NB.SI($F$2:F2;ANNEE(GENERAL!$C$3:$C$19))=0;ANNEE(GENERAL!$C$3:$C$19));1);"")

voila

 

[Efgé]

Re : [Formules] Extraire années uniques

Re
Re Merci Jocelyn
Je me creuse les méninges sur les matricielles...
Cordialement

 

[david84]

Re : [Formules] Extraire années uniques

Bonsoir Efgé, Jocelyn,

une autre possibilité :

=PETITE.VALEUR(SI(EQUIV(ANNEE(GENERAL!$C$3:$C$19);ANNEE(GENERAL!$C$3:$C$19);0)=LIGNE(INDIRECT("1:"&LIGNES(GENERAL!$C$3:$C$19)));ANNEE(GENERAL!$C$3:$C$19));LIGNE(1:1))

Vue comme cela et comparée à la formule proposée par Jocelyn, elle n'a éventuellement qu'un seul avantage : celui de ne pas avoir besoin de laisser la 1ère ligne vide (donc dans ton cas, on s'en fiche un peu).

Par contre, elle a un avantage que je trouve non négligeable par rapport au NB.SI(Plage;Critère)=0 : tu sais sans doute que le problème des matricielles sur des plages importantes est le temps de traitement.

Or l'avantage de cette formule est qu'en la modifiant légèrement comme ceci

=SIERREUR(PETITE.VALEUR(SI(EQUIV(ANNEE(GENERAL!$C$3:$C$19);ANNEE(GENERAL!$C$3:$C$19);0)=LIGNE(INDIRECT("1:"&LIGNES(GENERAL!$C$3:$C$19)));ANNEE(GENERAL!$C$3:$C$19));LIGNE(INDIRECT("1:"&LIGNES(GENERAL!$C$3:$C$19))));"")

, tu as la possibilité de sélectionner une plage de longueur équivalente à ta plage de traitement, de rentrer ta formule et de la valider.

Contrairement à l'utilisation du NB.SI(Plage;Critère)=0 où le recalcul se fait à chaque cellule, là tu crées une matrice unique. Le temps de calcul en est donc grandement amélioré sur des plages importantes.
Si tu veux des précisions, n'hésite pas.
A+

 

[Efgé]

Re : [Formules] Extraire années uniques

Re, Bonjour david
Merci de ta proposition. Je vais décortiquer tout ça à tête reposée.
Je risque en effet de revenir avec des demandes d'eclairsissements
Cordialement

 

[david84]

Re : [Formules] Extraire années uniques

Re
Tu peux déjà regarder le fichier que j'avais produit ici afin de comprendre le principe de cette formule.
Même si la validation sur une seule matrice (ma 2ème proposition) n'est pas traitée, la structure de la formule est la même et expliquée étape par étape.
Concernant la 2ème proposition, regarde également ici sur le site de JB.
A+

 

[Efgé]

Re : [Formules] Extraire années uniques

Bonjour Jocelyn Bonjour David
J'ai fini par comprendre vos propositions... Le fichier donné en lien par David m'a beaucoup aidé.
Merci à vous deux
Amicalement

 

[poulie]

Re : [Formules] Extraire années uniques

Bonsoir Efgé, bonsoir Jocelyn,

Un grand merci à david84 pour le fichier produit "ici". Superbe démarche "par étape".

Bonne soirée