Formule SI : Mais pourquoi ca ne marche pas !

[quinox31]

Je n'arrive pas a faire fonctionner une formule sur le fichier ci joint

Merci de votre aide

 

[Softmama]

Re : Formule SI : Mais pourquoi ca ne marche pas !

Edit : A côté de la plaque moi

 

[quinox31]

Re : Formule SI : Mais pourquoi ca ne marche pas !

ok merci mais pourquoi il me donne 0.5 comme note aulieu de 2 ?

 

[Efgé]

Re : Formule SI : Mais pourquoi ca ne marche pas !

BONJOUR quinox31, Bonjour Softmama,
Je ne suis pas très compétent en formule mais, une proposition:
La fonction SI imbriquée s'arrète dés que la condition est vérifiiée. Donc en commencant par

=SI(((C16/C18)*100)<49;-0,5;SI(((C16/C18)*100)>49;0,5;

Tu ne retrouvera que 0.5 ou - 0.5 puisque tout chiffre est inférieur ou supérieur à 49 (oublions le résultat = à 49 )
Je propose :
1 - que tu liseLien supprimé
2 - la formule suivante

=SI((C16/C18)*100>100;4;SI((C16/C18)*100>88;3;SI((C16/C18)*100>75;2;SI((C16/C18)*100>65;1;SI((C16/C18)*100>48;1;-0,5)))))

Cordialement

 

[_Sasha_]

Re : Formule SI : Mais pourquoi ca ne marche pas !

Salut Quinox,

Voici l'erreur que tu faisais,

=SI(((C16/C18)*100)<49;-0,5;SI(((C16/C18)*100)>49;0,5;SI(((C16/C18)*100)>65;1;SI(((C16/C18)*100)>75;2;SI(((C16/C18)*100)>88;3;SI(((C16/C18)*100)>100;4)))))

À partir de SI(((C16/C18)*100)>49, toutes les valeurs que tu aurais mis sur tes cellules C16 et C18 allait te mettre 0,5 car à partir du moment que la valeur donnait >49, ta formule SI s'arrête! J'ai donc rajouté des balises pour qu'entre 49 et 65, ta valeur donne 0,5 et ainsi de suite pour le reste...

Voici mes changements:

=SI(((C16/C18)*100)<=49;-0,5;SI(ET(((C16/C18)*100)>49;(C16/C18)*100<=65);0,5;SI(ET(((C16/C18)*100)>65;(C16/C18)*100<=75);1;SI(ET(((C16/C18)*100)>75;(C16/C18)*100<=88);2;SI(ET(((C16/C18)*100)>88;(C16/C18)*100<=100);3;SI(((C16/C18)*100)>100;4)))))

J'espère que j'ai été clair dans mes explications, mais là, ta formule devrait marcher!

Bonne journée,

 

[nyko283]

Re : Formule SI : Mais pourquoi ca ne marche pas !

Bonjour,

dans ta formule :"SI(((C16/C18)*100)<49;-0,5;SI((65>(C16/C18)*100)>49;0.5;...
tu indique que pour toutes les valeurs supérieur à 49 alors c'est egale à 0.5 et cela ignore donc le reste de la formule...

je te propose donc en remplacement cette formule qui permet d'avoir deux critère, la borne inferieur et la borne supérieure, en association la fonction "ET".


=SI(((C16/C18)*100)<49;-0,5;SI(ET(((C16/C18)*100)>=49;((C16/C18)*100)<65);0,5;SI(ET(((C16/C18)*100)>=65;((C16/C18)*100)<75);1;SI(ET(((C16/C18)*100)>=75;((C16/C18)*100)<88);2;SI(ET(((C16/C18)*100)>=88;((C16/C18)*100)<100);3;4)))))

Edit :

je vois qu'avec Sasha nous avons t'avons proposer la même solution mais afin de ne pas exclure le 49, 65,75,... car dans la formule nous avons le cas inférieur ou supérieur mais dans le cas ou l'opération soit egale à 49 que ce passe t'il ? d'ou l'ajout du signe "=" apres ">"

re edit :
Désolé Sasha j'avais pas vue que tu avait deja prevu le cas ....

 

[Tibo]

Re : Formule SI : Mais pourquoi ca ne marche pas !

Bonjour le fil,

A essayer :

=INDEX({-0.5;0.5;1;2;3;4};EQUIV(C16/C18;{0;0.49;0.65;0.75;0.88;1}))

Si les données sont susceptibles de varier, on peut les mettre dans des cellules auxquelles on fait ensuite référence dans la formule. Ainsi, en cas de modification, un seul changement à faire.

@+

 

[kjin]

Re : Formule SI : Mais pourquoi ca ne marche pas !

Bonsoir,
En aucun cas tu trouveras 3 mais plutôt 2 !

=SI(C16/C18*100>100;4;SI(C16/C18*100>88;3;SI(C16/C18*100>75;2;SI(C16/C18*100>65;1;SI(C16/C18*100>49;0,5;-0,5)))))

A+
kjin

 

[quinox31]

Re : Formule SI : Mais pourquoi ca ne marche pas !

dsl oui c'est 2

merci pour toutes ces réponses rapides