XL 2013 Formule qui isole 1 donnée d'une cellule

[onyirimba]

Bonjour,

est ce que je pourrai obtenir une formule qui permette d'isoler une donnée d'une cellule ? Par exemple, ci-dessous qui isole la donnée qui se termine par -FY (quelque soit la position qui se termine par -FY dans la cellule)
J'ai joint un fichier Excel illustratif

Merci d'avance

Cordialement

 

[mromain]

Bonjour onyirimba,

Une solution en formule matricielle (à valider avec <Ctrl> + <Maj> + <Entrée>) :

=DROITE(GAUCHE(F5;TROUVE("-FY";F5)-1);NBCAR(GAUCHE(F5;TROUVE("-FY";F5)-1))-MAX(SI(STXT(GAUCHE(F5;TROUVE("-FY";F5)-1);LIGNE(INDIRECT("A1:A"&NBCAR(GAUCHE(F5;TROUVE("-FY";F5)-1))));1)=CAR(10);LIGNE(INDIRECT("A1:A"&NBCAR(GAUCHE(F5;TROUVE("-FY";F5)-1))));0)))&"-FY"

Il y a probablement plus simple.

A+

 

[mapomme]

Bonjour @onyirimba🙂, @mromain😉,

Un autre formule matricielle : =SIERREUR(SUPPRESPACE(DROITE(SUBSTITUE(GAUCHE(F5;CHERCHE("-FY";F5)+2);CAR(10);REPT(" ";255));255));"")

 

[Hecatonchire]

Bonjour à tous,

Je propose :

=FILTRE.XML("<root><node>" & SUBSTITUE(SUBSTITUE(F5;CAR(10);"-");"-";"</node><node>") &
            "</node></root>";"/root/node[text()='FY']/preceding-sibling::node[1]")&"-FY"

 

[onyirimba]

Bonjour @onyirimba🙂, @mromain😉,

Un autre formule matricielle : =SIERREUR(SUPPRESPACE(DROITE(SUBSTITUE(GAUCHE(F5;CHERCHE("-FY";F5)+2);CAR(10);REPT(" ";255));255));"")

merci cela fonctionne