Formule pour trouver l'intersection d'une ligne et d'une colonne

[zombe]

Salut le forum

Après de multiples recherches infructueuses, je viens vers vous pour solliciter votre aide.
En effet, j'ai un tableau comportant des données (taux d'assurances).
J'ai déjà pu réaliser un premier travail.
Tout ce qui me reste serait de trouver la formule qui me permettra de trouver l'intersection entre la valeur de la cellule non vide de SIMULATION!C4:L4 et SIMULATION!B5:B12.
Voici un exemple tiré de mon tableau:
dans ma plage SIMULATION!C4:L4, c'est D4 qui n'est pas vide.
dans la 2è plage SIMULATION!B5:B12, c'est B5 qui n'est pas vide.
L'intersection de D4 et B5 est D5
Commenbt faire pour conjuguer cette formule.
Je reste à votre disposition pour les éclaircissements svp.

 

[Modeste geedee]

Re : Formule pour trouver l'intersection d'une ligne et d'une colonne

Bonsour®
la formule magique :
=plage1 plage2

bien remarquer l'espace entre les 2 plages

si l'intersection comporte un résultat sur plusieures cellules alors #VALEUR
il faut alors mettre une fonction mathématique ne renoyant qu'une valeur
=MOYENNE(Plage1 plage2)

 

[zombe]

Re : Formule pour trouver l'intersection d'une ligne et d'une colonne

Salut Modeste geedee et le forum

Merci de vous interesser à mon problème.
J'ai essayé d'apprécier votre solution mais j'ai du mal.
1- je ne l'ai pas bien comprise
2- je constate que ca ne résoud pas mon problème
Je vais apporter des éclaircissements:
- dans DONNE!B22, je saisis la date de naissance du client
une des formules entrées dans la plage SIMULATION!C4:L4 doit répondre à la condition donc l'age du client s'y affichera.
- dans DONNE!B32, je saisis la durée du prêt.
une des formules entrées dans la plage SIMULATION!B5:B12 doit satisfaire à la condition donc la durée s'y affichera.
Dans mes 2 plages, une des cellules de chaque plage contient une valeur et les autres vides.
Comment trouver l'intersection de ces 2 valeurs?
N.B :le fichier du post#1 reste inchangé
Merci

 

[ODVJ]

Re : Formule pour trouver l'intersection d'une ligne et d'une colonne

Bonsoir à tous,

1) Je te propose une légère modification de ta table : remplacer les "Néant" par 0 en mettant un format personnalisé 0.00;"erreur saisie";"Néant".
Ta table ne change pas de look mais elle devient numériquement exploitable avec cette formule à positionner dans la cellule de ton choix :

=PRODUITMAT(PRODUITMAT(TRANSPOSE((B5:B12<>"")*1),C5:L12),TRANSPOSE((C4:L4<>"")*1))

à valider par CTRL+MAJ+ENTER puisque c'est un produit matriciel (même si le résultat est un scalaire).

2) Une autre façon de faire, sans modifier la table :

=SIERREUR(INDEX($C$5:$L$12,SOMMEPROD(LIGNE(INDIRECT("1:9"))*FREQUENCE(B5:B12,5*LIGNE(INDIRECT("6:13"))-{0;0;0;0;0;0;0;1})),SOMMEPROD(LIGNE(INDIRECT("1:11"))*FREQUENCE(C4:L4,12*LIGNE(INDIRECT("1:10"))))),-1)

3) avec des MAX(), en matriciel :

=SIERREUR(INDEX($A$1:$L$12,MAX(SI($B$5:$B$12<>"",LIGNE($B$5:$B$12))),MAX(SI($C$4:$L$4<>"",COLONNE($C$4:$L$4)))),-1)

Je m'arrête là, mais je suis sûr qu'on peut faire pire!

Remarque : il faut mettre des ";" à la place de mes "," dans les formules

Cordialement