Formule matricielle pour compter

[mroux]

Bonjour à tous,

Voici ma problématique.
J'ai ma table de données et souhaite compter celles ci suivant différents critères.
Voici la formule que j'ai créé :

=SOMME(SI((Population!$A$2:$A$2184=Consolidation!$B$30)*(Population!$K$2:$K$2184=Consolidation!C$30)*(Population!$J$2:$J$2184=Consolidation!$B31)*SI(B29="";1;INDIRECT("Population!$B$2:$B$"&K2)&"="&INDIRECT(B29));1;0))

Les premiers critères fonctionnent très bien. Ce qui me pose problème c'est le critère suivant :

SI(B29="";1;INDIRECT("Population!$B$2:$B$"&K2)&"="&INDIRECT(B29));1;0)

En fonction de la valeur de la cellule B29, si celle ci est vide, ce critère est toujours vrai sinon je ne veux compter ma population que lorsque ma colonne B est égal à ma cellule qui contient mon critère.
Le critère fonctionne très bien dans le cas où ma cellule est vide; mais pas dans l'autre cas ...

Pouvez vous m'aider à réaliser cette formule?

Merci par avance.

Cordialement

Mathieu

 

[hoerwind]

Re : Formule matricielle pour compter

Bonjour et bienvenu sur le forum,

Pas facile sans avoir le fichier sous les yeux !

Essaie toutefois ceci, cela me semble plus logique :

SI(B29="";1;INDIRECT("Population!$B$2:$B$"&K2)=INDIRECT(B29))

Si ce n'est pas cela, joint un petit exemple.

 

[Tibo]

Re : Formule matricielle pour compter

Bonjour,

Pour nous permettre de t'aider, l'idéal serati que tu nous joignes un extrait de ton fichier. Ca nous évite de devoir le reconstituer et surtout, on peut travailler avec la même base que toi.

La taille limite des fichiers oints est de 48.8 ko. Pas besoin de joindre le fichier complet, un extrait significatif doit suffire. Le cas échéant, ne pas hésiter à zipper le fichier.

A te (re)lire avec ton fichier exemple

@+

Edit : Bing ! Salut hoerwind 🙂

@+

 

[mroux]

Re : Formule matricielle pour compter

Voici un fichier en exemple.
Toujours en espérant que vous pouvez m'aider ...

PS : J'ai déjà essayer ta solution hoerwind mais sans succès!!


Mathieu

 

[Compte Supprimé 979]

Re : Formule matricielle pour compter

Bonjour Mroux,

Dans ton fichier en C8

=SOMMEPROD((Population!$B$2:$B$38=$B$5)*(Population!$K$2:$K$38=C$7)*(Population!$J$2:$J$38=$B8))

Recopie vers le bas et la droite

A+

 

[mroux]

Re : Formule matricielle pour compter

Salut BrunoM45,

Merci pour cette solution. Je ne connaissais pas cette utilisation de SOMMEPROD!!

Par contre j'ai encore un petit problème.

En effet lorsque j'ai une région de renseigner dans la cellule B5 cela fonctionne correctement.

Par contre lorsque je souhaite consolider l'information de toutes les régions ma nouvelle formule me renvoi 0...

Voici la formule modifiée en C8:

=SOMMEPROD((SI($B$5="";1;INDIRECT("Population!$B$2:$B$38")=$B$5))*(Population!$K$2:$K$38=C$7)*(Population!$J$2:$J$38=$B8)*(Population!$A$2:$A$38=Consolidation!$B$6))

Merci encore pour vos retours.

Mathieu

 

[Compte Supprimé 979]

Re : Formule matricielle pour compter

Salut MRoux,

La condition doit se faire à l'exterieur de SOMMEPROD()
De plus si on veut tout consolider, la condition ne s'applique plus sur la région, elle est donc supprimer

En C8 + recopie vers le bas et à droite

=SI($B$5="";SOMMEPROD((Population!$K$2:$K$38=C$7)*(Population!$J$2:$J$38=$B8));SOMMEPROD((Population!$B$2:$B$38=$B$5)*(Population!$K$2:$K$38=C$7)*(Population!$J$2:$J$38=$B8)))

A+

 

[mroux]

Re : Formule matricielle pour compter

Merci BrunoM45,

Cela fonctionne tout pil poil.
Je n'avais pas pensé à sortir la condition ...


Merci encore à tous.

Mathieu