Formule excel - gras et onglet

[VBA_DEAD]

Bonjour

j`espere que vous allez bien

j`ai un eptit pb de formule (pas grave j`espere)

je cherche a sommer du gras comme expliquer ds mon file attache

Merci pour votre

VBA _DEAD

 

[Gorfael]

Re : Formule excel - gras et onglet

Bonjour

j`espere que vous allez bien

j`ai un eptit pb de formule (pas grave j`espere)

je cherche a sommer du gras comme expliquer ds mon file attache

Merci pour votre

VBA _DEAD

Salut

Dim F_T As Worksheet
Dim X As Long
Dim Y As Integer
Dim Tab_Tot() As Double
Y = 1
ReDim Tab_Tot(1 To Worksheets.Count - 1)
For Each F_T In Sheets
    If F_T.Name <> "Total" Then
        For X = F_T.UsedRange.Cells.Count To 1 Step -1
            If F_T.UsedRange.Cells(X).Font.Bold = True Then
                Tab_Tot(Y) = F_T.UsedRange.Cells(X)
                Y = Y + 1
                Exit For
            End If
        Next X
    End If
Next
Sheets("Total").Select
Range("c1").Activate
For Y = 1 To UBound(Tab_Tot, 1)
    ActiveCell.Offset(Y, 0) = Tab_Tot(Y)
Next Y
End Sub

t'as une trame pour travailler :il serait peut-être judicieux de contrôler que la cellule en gras contient bien un nombre
au lieu du tableau, on peut avoir une variable unique et la sommer; mais là ça permet, dans un premier temps de vérifier le code
A+

 

[_Thierry]

Re : Formule excel - gras et onglet

Bonjour VBA (is not) Dead, Bonjour Gorfael, le Forum

Une solution voisine de celle de Gorfael... Avec le contrôle du numérique...

Option Explicit
Sub TheBoldFinder()
Dim WSTotal As Worksheet
Dim WS As Worksheet
Dim Cell As Range
Dim Ligne As Integer
Set WSTotal = ThisWorkbook.Worksheets("Total")
Ligne = WSTotal.Range("A500").End(xlUp).Row
    For Each WS In ThisWorkbook.Worksheets
        If Not WS.Name = WSTotal.Name Then
            For Each Cell In WS.Range(WS.Range("D2"), WS.Range("D500").End(xlUp))
                If IsNumeric(Cell.Value) Then
                    If Cell.Font.Bold = True Then
                        With WSTotal
                            .Cells(Ligne, 1) = WS.Name
                            .Cells(Ligne, 4) = Cell.Value
                        End With
                        Exit For
                    End If
                End If
            Next Cell
        End If
    Ligne = Ligne + 1
    Next WS
    
End Sub

Bon App

@+Thierry


​

 

[VBA_DEAD]

Re : Formule excel - gras et onglet

Bonjour Gorfael et Thierry

merci pour votre aide

je vais essayer vos solutions. je pensais que l`on pouvait passer par une formule excel mais VBA me va tres bien

J`essaie et je vouv reviens si je bloque

Merci, a tout a l`heure (en fin de soiree)

merci beaucoup

BVA _DEAD

 

[VBA_DEAD]

Re : Formule excel - gras et onglet

Re bonjour

ca marche nickel!

Petite question supplementaire

Euh si je veux copier les valeurs de la meme ligne (valeur en gras aussi) mais de la colonne F et G, j`ajoute ou le code
J`essaie mais ca veut pas!

Encore Merci
VBA DEAD

 

[VBA_DEAD]

Re : Formule excel - gras et onglet

Finalement c`est bon
j`avais oublie un morceau

je me disais aussi

Merci bcp

A+

J`ai pleins de pb en ce moment niveau file a traiter dont un super hard donc je repasserai peut etre.

merci a tous les 2 en tout cas pour votre aide bien precieuse pdt cette periode estivale

VBA DEAD