formule d'excel

[titi]

Bonjour,
est ce que quelqu'un pourrait me dire quelle formule je pourrais utiliser pour calculer la somme des 6 plus grandes valeurs d'une plage cellule.
Merci

 

[dg62]

Bonjour Titi


le plus simple, tu fais un tri décroissant de ta plage de cellules et ensuite tu fais la somme des 6 premires cellules.

 

[titi]

ouais merci pour la réponse mais le problème c'est que les données sont rangées par ordres de dates et que je ne peut pas les changer, et donc pas les trier.

 

[PascalXLD]

Bonjour

tu dois avoir plus simple mais

=GRANDE.VALEUR(A1:A10;1)+GRANDE.VALEUR(A1:A10;2)+GRANDE.VALEUR(A1:A10;3)+
GRANDE.VALEUR(A1:A10;4)+GRANDE.VALEUR(A1:A10;5)+GRANDE.VALEUR(A1:A10;6)

Bon courage

 

[Jocelyn]

Bonjour le Forum,
Bonjour titi, dg62,

il doit y avoir une formule plus simple mais celle-ci fonctionne


=GRANDE.VALEUR(A1:A10;1)+GRANDE.VALEUR(A1:A10;2)+GRANDE.VALEUR(A1:A10;3)+GRANDE.VALEUR(A1:A10;4)+GRANDE.VALEUR(A1:A10;5)+GRANDE.VALEUR(A1:A10;6)

Espérant t'avoir aidé

A+
Jocelyn

 

[PascalXLD]

Alors là Jocelyn Trop fort

On donne la même réponse dans la même minute avec comme exemple la même plage de données et la même reflexion qu'on peut faire plus simple

🙂 🙂 🙂 🙂

Message édité par: Pascal76, à: 14/03/2005 11:56

 

[Jocelyn]

re bonjour,
bonjour Pascal76,

oup's désolé pour la collision

A+
Jocelyn

 

[Jocelyn]

re bonjour a tous,

eh eh voila une formule plus courte,

=SOMMEPROD((A1:A10>=GRANDE.VALEUR(A1:A10;6))*A1:A10)

A+
Jocelyn

 

[JeanMarie]

Bonjour

Une autre formule, prenant en compte la gestion d'erreur #Ref! retournée par la fonction DECALER, et évite de cumuler x fois une même valeur.
=SI(NB(A4:A100)=0;0;SOMMEPROD(GRANDE.VALEUR(A4:A100;LIGNE(DECALER(A1;;;MIN(6;NB(A4:A100))))*1)))

@+Jean-Marie

PS : il n'y a pas besoin de la multiplication par *1

=SI(NB(A4:A100)=0;0;SOMMEPROD(GRANDE.VALEUR(A4:A100;LIGNE(DECALER(A1;;;MIN(6;NB(A4:A100)))))))

Message édité par: JeanMarie, à: 14/03/2005 13:03

 

[MichelXld]

bonjour à tous

encore une autre possibilité
( valider par Ctrl+Maj+Entree )

=SOMME(A1:A10*(A1:A10>=GRANDE.VALEUR(A1:A10;6)))


bon apres midi
MichelXld

 

[Pitou]

Bonjour à tous,

Je pense que ce mail est pour Michel, car si il peut en qques mots expliqué ce qu'est CTRL + MAJ + ENTER
Il mets des {} ???

Merci

Pitou :huh:

 

[titi]

je tenais a tous vous remercier pour vos réponses super rapides.
J'ai trouvé mon bonheur avec :
=GRANDE.VALEUR(A1:A10;1)+GRANDE.VALEUR(A1:A10;2)+GRANDE.VALEUR(A1:A10;3)+GRANDE.VALEUR(A1:A10;4)+GRA NDE.VALEUR(A1:A10;5)+GRANDE.VALEUR(A1:A10;6)

a+

 

[MichelXld]

bonjour Pitou

il faut valider la formule en appuyant simultanément sur les touches CTRL + MAJ + ENTER , car il s'agit d'une formule matricielle
Ensuite , dans la barre de formule , apparaitra une accolade à chaque extrémité de la formule: {=MaFormule}


bonne soiree
MichelXld