formule avec si

[caline]

bonsoir
je devrais dans une formule calculer
(SI(OU((I6="m7,5");(J6="m7,5");(P6="m7,5");(Q6="m7,5");(W6="m7,5");(X6="m7,5");(AD6="m7,5");(AE6="m7,5");(AK6="m7,5");(AL6="m7,5"));"oui";"non"))

ok cela ne pose pas de problème mais le m devrait être suivi de toute les variantes allant de m1 à M2 etc jusqu'à m11 de se fait avec si la formule est trop longue, j'ai essayé avec "m*"mais cela ne va pas

quelqu'un a t-il une idée voir une solution


merci à vous tous
Caline

 

[Monique]

Re : formule avec si

Bonjour,

à essayer

=SI(SOMME(SI(ESTNUM(TROUVE("m";I$6:AL$6));(MOD(COLONNE(I$6:AL$6)-2;7)<2)*(SUBSTITUE(I$6:AL$6;"m";0)*1<=11)*(SUBSTITUE(I$6:AL$6;"m";0)*1>=1)));"oui";"non")

Formule matricielle, à valider par ctrl maj et entrée.

Edit
Tu enlèveras les espaces dans "COLONNE" et "SUBSTITUE"

 

[caline]

Re : formule avec si

Monique

bonsoir j'ai essayé mais cela ne fonctionne pas

merci a plus tard
car tes conseils m'ont déjà beaucoup aidés

 

[Monique]

Re : formule avec si

Re,

Tu peux joindre un petit bout de fichier, STP ?
Merci.

 

[caline]

Re : formule avec si

Monique , je pense que je vais utilisé le =(+(NB.SI($I9;"M*"))*1)+(+(NB.SI($J9;"M*"))*1)+(+(NB.SI($P9;"M*"))*1)+(+(NB.SI($Q9;"M*"))*1)+(+(NB.SI($W9;"M*"))*1)+(+(NB.SI($AD9;"M*"))*1)+(+(NB.SI($AK9;"M*"))*1)+(+(NB.SI($AL9;"M*"))*1)+(+(NB.SI($X9;"M*"))*1)+(+(NB.SI($AE9;"M*"))*1)


et ensuite j'adapterai

merci qu'en même
a plus

 

[Monique]

Re : formule avec si

Re,

Tu peux la raccourcir :
=NB.SI($I6;"M*")+NB.SI($J6;"M*")+NB.SI($P6;"M*")+NB.SI($Q6;"M*")+NB.SI($W6;"M*")+NB.SI($AD6;"M*")+NB.SI($AK6;"M*")+NB.SI($AL6;"M*")+NB.SI($X6;"M*")+NB.SI($AE6;"M*")

Celle-ci a le même résultat :
=SOMME(SI(ESTNUM(TROUVE("m";$I6:$AL6));(MOD(COLONNE($I6:$AL6)-2;7)<2)*(SUBSTITUE($I6:$AL6;"m";0)*1>0)))
(prend aussi en compte les m50 ou les m0,5 que tu n'as peut-être pas, d'ailleurs)
à valider par ctrl, maj et entrée

 

[Monique]

Re : formule avec si

Re,

Tout simplement (à valider seulement par "Entrée") :
=SOMMEPROD((MOD(COLONNE($I6:$AL6)-2;7)<2)*(ESTNUM(CHERCHE("m";$I6:$AL6))))
si on compte tous les "m", quel que soit le nombre qui suit le "m"

 

[caline]

Re : formule avec si

MERCI Monique
=SOMMEPROD((MOD(COLONNE($I6:$AL6)-2;7)<2)*(ESTNUM(CHERCHE("m";$I6:$AL6))))


pour mon info -2;7 cela signifie qu'elle prend en compte les 2 cell(i et J) et puis la 7 après ?

mais a quoi correcpond le <2


bien à toi

 

[Monique]

Re : formule avec si

Bonjour,

=MOD(COLONNE();7)
renvoie le reste de la division par 7 du n° de colonne
Mod(7;7) renvoie 0 - Mod(8;7) renvoie 1 - Etc jusqu'à Mod(13;7) qui renvoie 6 puis on repart à zéro

Tapée en colonne I (colonne 9), la formule COLONNE() renvoie 9
Tapée en colonne I (colonne 10), elle renvoie 10

Tapée en colonne I (colonne 9), la formule MOD(COLONNE();7) renvoie 2
Tapée en colonne J (colonne 10), elle renvoie 3

Pour raccourcir la formule, Colonne()-2 renvoie 7 et 8 en I et J
Mod(Colonne()-2;7) renvoie 0 et 1 en I et J
donc <2

D'où le MOD(COLONNE($I6:$AL6)-2;7)<2)
qui ne prend en compte que 2 colonnes sur 7

 

[caline]

Re : formule avec si

SUPER EXPLICATION

j'espère le retenir pour une prochaine utilisation sinon un coup de forum auprès de toi

ps ou avez-vous appris toutes ces "choses"

Caline